Draw 2 Circles with a 4 way divider
Wow....so complicated! [And even more so when you supply the missing sub-routine definition.] It can be something as simple as this:
(defun C:2C4QL (/ ctr c1); = 2 Circles, 4 Quadrants by Lines
(command
"_.circle" pause pause
"_.circle" "_non" (setq ctr (getpropertyvalue (setq c1 (entlast)) "Center")) pause
"_.line"
"_non" (vlax-curve-getStartPoint c1)
"_non" (vlax-curve-getStartPoint (entlast))
""
"_.array" (entlast) "" "_polar" "_non" ctr 4 "360" "_yes"
); command
(prin1)
)
It does not need to find all the quadrant points on both Circles, nor care about their radii, nor about the endpoints of the Lines other than the first one. You can specify the radii of the Circles either by screen pick or typing in numbers, and you can draw either the bigger or the smaller one first.
Regards @rpajounia
Try this codes...
;;;___
(defun c:AddC1 (/ p r1 r2 n p1 p2 p3 p4 lp1 lp2 lp3 lp4)
(setq
spm (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
)
(setq p (getpoint "\nPick Point Circles Center...:")
r1 (getreal "\nEnter Radius Circle Minor...:")
r2 (getreal "\nEnter Radius Circle Major...:")
)
(foreach n (list r1 r2)
(vla-addcircle spm (vlax-3d-point p) n)
(setq p1 (mapcar '+ p (mapcar '(lambda (j) (* n j)) '(1 0)))
lp1 (cons p1 lp1)
p2 (mapcar '+ p (mapcar '(lambda (j) (* n j)) '(0 1)))
lp2 (cons p2 lp2)
p3 (mapcar '+ p (mapcar '(lambda (j) (* n j)) '(-1 0)))
lp3 (cons p3 lp3)
p4 (mapcar '+ p (mapcar '(lambda (j) (* n j)) '(0 -1)))
lp4 (cons p4 lp4)
)
)
(foreach o (list lp1 lp2 lp3 lp4)
(vla-addline spm (vlax-3d-point (car o)) (vlax-3d-point (cadr o)))
)
)
;;;___
(defun c:AddC2 (/ p r1 r2 i c ln k)
(setq p (getpoint "\nPick Point Circles Center...:")
r1 (getreal "\nEnter Radius Circle Minor...:")
r2 (getreal "\nEnter Radius Circle Major...:")
)
(foreach i (list r1 r2)
(setq c (entmakex (list '(0 . "circle")
(cons 10 p)
(cons 40 i)
)
)
ln (cons c ln)
)
)
(foreach k (list 0 (/ pi 2) pi (* 1.5 pi))
(command "_line"
(vlax-curve-getpointatparam (car ln) k)
(vlax-curve-getpointatparam (cadr ln) k)
""
)
)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@rpajounia wrote:
....
(defun DoubleCircle ( p1 p2 / Circle1 Circle2 .... .... ;; Create circles (setq Circle1 (_circl p1)) (setq Circle2 (_circl p2)) ;; Get the center points and radii of the circles ....
And another thing.... Does that routine really work?
The p1 and p2 arguments would presumably be points, though we can't tell [nor can we try it out] without seeing the definition of the (_circl) function. It uses only one argument, so it's hard to imagine how it can draw a Circle -- it would need at least two, for center and radius. Does (_circl) ask for the one that is not supplied as an argument, requesting User input?
The p1 and p2 variables presumably must be different from each other, but what you're drawing needs their centers to be at the same place, so it seems p1 and p2 cannot be their center points. Are p1 and p2 their radii instead, the one thing about them that differs? But there's nothing to establish their common center point. If that's left to User input having (_circl) ask for the center, it's asking unnecessarily for the center for each of them, when it should be re-using the first center for the second Circle.
And there should be no "Get the center points and radii" [part of line 7 above] -- the centers are the same for both anyway, and they and the radii must already be known by then, either as p1 and p2 or as requested from the User in the (_circl) function.
