DOT IN INTESECTION

[eyal.ch]

Hi guys,

Could you help with a lisp that: 

after selecting two lines (it can be also lines from close polyline) it will create a point in the virtual intersection,

I mean the lines must not be parallel so the point will be in the intersection of the lines.(if we extend them)

Thank you

[ВeekeeCZ · Accepted solution]

If you bother to search you'll find THIS 

[eyal.ch]

Hi @ВeekeeCZ ,

Thank you, but sorry for ignorance- how do I operate the lisp?

;; Intersections  -  Lee Mac
;; Returns a list of all points of intersection between two objects
;; for the given intersection mode.
;; ob1,ob2 - [vla] VLA-Objects
;;     mod - [int] acextendoption enum of intersectwith method

(defun LM:intersections ( ob1 ob2 mod / lst rtn )
    (if (and (vlax-method-applicable-p ob1 'intersectwith)
             (vlax-method-applicable-p ob2 'intersectwith)
             (setq lst (vlax-invoke ob1 'intersectwith ob2 mod))
        )
        (repeat (/ (length lst) 3)
            (setq rtn (cons (list (car lst) (cadr lst) (caddr lst)) rtn)
                  lst (cdddr lst)
            )
        )
    )
    (reverse rtn)
)

[ВeekeeCZ]

That's just a subfunction. You need the main (test) function which will call that one.

[eyal.ch]

Can you please do that for me? and write the lisp so I can operate it.

I don't know how to do that.

[ВeekeeCZ]

Not sure what else you need from me. Just follow the link I gave you. There is all you need to make it work.

[eyal.ch]

How to call  a subfunction.  "You need the main (test) function which will call that one."

I don't know how to call it.

[CodeDing · Accepted solution]

@eyal.ch ,

What @ВeekeeCZ  is trying to say, is that Lee's website already shows you how to call the subfunction and everything.

If you are not comfortable enough with putting Lee's 2 pieces of information together, then perhaps you are trying to advance faster than you should be.

Do you know how to run a lisp file even by chance?

If not, look HERE.

Otherwise, save this text into a file with a '.lsp' extension (a lisp file):

;; Intersections  -  Lee Mac
;; Returns a list of all points of intersection between two objects
;; for the given intersection mode.
;; ob1,ob2 - [vla] VLA-Objects
;;     mod - [int] acextendoption enum of intersectwith method

(defun LM:intersections ( ob1 ob2 mod / lst rtn )
    (if (and (vlax-method-applicable-p ob1 'intersectwith)
             (vlax-method-applicable-p ob2 'intersectwith)
             (setq lst (vlax-invoke ob1 'intersectwith ob2 mod))
        )
        (repeat (/ (length lst) 3)
            (setq rtn (cons (list (car lst) (cadr lst) (caddr lst)) rtn)
                  lst (cdddr lst)
            )
        )
    )
    (reverse rtn)
)
(defun c:inter ( / obj1 obj2 )    
    (if (and (setq obj1 (car (entsel "\nSelect 1st Object: ")))
             (setq obj2 (car (entsel "\nSelect 2nd Object: ")))
        )
        (foreach pnt (LM:intersections (vlax-ename->vla-object obj1) (vlax-ename->vla-object obj2) acextendnone)
            (entmake (list '(0 . "POINT") (cons 10 pnt)))
        )
    )
    (princ)
)
(vl-load-com) (princ)

Then load the file into AutoCAD (as described in the link above).

Then run the INTER command (as defined in Lee's example lisp).

If you cannot perform these steps, then you will need to spend more time researching how to accomplish these basics.

Best,

~DD

[Kent1Cooper]

---

@eyal.ch wrote:

.... after selecting two lines (it can be also lines from close polyline) it will create a point in the virtual intersection,....

---

Am I missing something here?  It's just the APParent Intersection, which Object Snap will find for you:

POINT command

APP {Object Snap mode}

pick your two Lines/Polyline line segments.

If you need that built into an AutoLisp routine, that can be done easily enough, but do you really?

[eyal.ch]

Hi @CodeDing ,

I know how to run a lisp, I don't know how to get this option to work:

I want to select the 2 lines like the example , and it will draw a point in the entersection.

The lisp you wrote doesn't do this.

Thanks

[CodeDing · Accepted solution]

@eyal.ch ,

Change this

acextendnone

To this:

acextendboth

[eyal.ch]

EXCELENT!  THANK YOU.

[Kent1Cooper]

---

@eyal.ch wrote:

....

I want to select the 2 lines like the example , and it will draw a point in the entersection.

....

---

I repeat:  Is there some reason I don't understand that you don't just use the POINT command and APParent-intersection Object Snap?  I don't see the benefit of a specialty routine.