dimension convet to text lisp
One way:
(if (setq dimsel (entsel "\nSelect Dimension to override text with measured distance: "))
(progn
(setq
dim (car dimsel)
ddata (entget dim)
)
(entmod (subst (cons 1 (rtos (cdr (assoc 42 ddata)))) (assoc 1 ddata) ddata))
)
)
That uses current Units mode and precision settings, which may not be the same as those settings in the Dimension Style, so you may need to specify differently.
EDIT: By the way, that's just for the text equivalent of the measured-distance value. If you might have some already-supplied override text content as pre- or suffix to that, the code can be modified to include that.
@Kent1Cooper wrote:
.... If you might have some already-supplied override text content as pre- or suffix to that, the code can be modified to include that.
Such as this:
(defun C:DMTO ; = Dimension Measurement-Text Override
(/ dimsel dim ddata)
(if (setq dimsel (entsel "\nSelect Dimension to override text with measured distance: "))
(progn
(setq
dim (car dimsel)
ddata (entget dim)
); setq
(entmod
(subst
(cons 1
(cond
((member '(1 . "") ddata); text is only default [no override already]
(rtos (cdr (assoc 42 ddata))); text equivalent of measured distance
); default condition
((wcmatch (cdr (assoc 1 ddata)) "*<>*"); override including measured distance
(vl-string-subst (rtos (cdr (assoc 42 ddata))) "<>" (cdr (assoc 1 ddata)))
; replace measured-distance portion with equivalent text override
); measured-distance-included condition
((strcat (rtos (cdr (assoc 42 ddata))) " " (cdr (assoc 1 ddata))))
; none-of-the-above; add measured-distance text to beginning of override
); cond
); cons
(assoc 1 ddata)
ddata
); subst
); entmod
); progn
); if
(princ)
); defun
Note the third option, if there's an override that doesn't include the measured distance -- as written, it adds the measured distance [and a space] before the current override text, but you may want a different outcome if you might have that situation.
Other questions arise:
It seems like a potentially dangerous thing to do, with concerns such as potential liability implications. So I'd be very careful about using it only in very limited and thoughtfully-evaluated circumstances. You might even have it always include something like "N.T.S." [= Not To Scale] at the end.
This is only for distance Dimensions. What if you pick an angular Dimension? Would there ever be a need for that? I can't imagine one, but that could be accommodated if necessary, or it could be built to prevent use on angular Dimensions.
Not so sophisticated as the above solutions, but it does the trick.
(defun C:ed_dim ( / prec text_height e ent pt1 pt2 di)
(setq prec (getint "\nNumber precision for dimension text >" ))
(while
(setq
e (car (entsel "\nSelect dimension object: >"))
ent (entget e)
pt1 (getpoint "\nSelect dimension start : >")
pt2 (getpoint "\nSelect dimension end : >")
di (rtos (distance pt1 pt2) 2 prec)
ent (subst (cons 1 di) (assoc 1 ent) ent)
ent (entmod ent)
)
)
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@Gaganpatel wrote:
.... i am sending example file.
....
Since that is all reduced to separate Mtext and Line objects, I repeat @ВeekeeCZ's earlier question: Does EXPLODE not do what you want? In your earlier Example file.dwg, the result was still a Dimension object. What are you really trying to do?
How about just Plotting at a different scale, so that it fits on your sheet size without destroying the Dimensions?
Or, if you can't just EXPLODE and then STRETCH because the text doesn't reposition itself, can you not use the earlier routines on this thread, STRETCH as required, and then EXPLODE?
In your second drawing, you have a lot of shorter distances that make up the overall length. I'm trying to picture how you can STRETCH the overall length shorter without seriously distorting the relationship between, and maybe overlapping, some of the shorter intermediate lengths.... Before and after in the same drawing would help us understand what you're doing.
So it seems you're STRETCHing every section [except the shortest ones] separately, and apparently eye-balling them because the shortened distances are not proportional to the starting distances. Does it not work to apply one of the routines from earlier in this thread to make the text overrides [but leave them as Dimensions so that the text will re-position itself when they are STRETCHed], then do the STRETCHing, and then EXPLODE the Dimensions? If that doesn't work, explain further the steps you want to take to get from the full-length layout to the Shop Drawing layout.
