Detect duplicate Mtext entries
Hi,
Maybe you can get some inspiration from this:
(defun c:FINDDUPMTEXT (/ groupBy getDups ssList dups ss)
(defun groupBy (fun lst / key sub res)
(setq fun (eval fun))
(mapcar
'(lambda (l) (cons (car l) (reverse (cdr l))))
(foreach l lst
(setq res
(if (setq sub (assoc (setq key (fun l)) res))
(subst (vl-list* key l (cdr sub)) sub res)
(cons (list key l) res)
)
)
)
)
)
(defun getDups (mtexts)
(vl-remove-if
(function (lambda (l) (< (length (cdr l)) 2)))
(groupBy (function (lambda (x) (getpropertyvalue x "Text"))) mtexts)
)
)
(defun sslist (ss / i l)
(if (and ss (= (type ss) 'PICKSET))
(repeat (setq i (sslength ss))
(setq l (cons (ssname ss (setq i (1- i))) l))
)
)
)
(if (setq dups (getDups (sslist (ssget "_X" '((0 . "MTEXT"))))))
(progn
(setq ss (ssadd))
(foreach l dups
(prompt (strcat "\n" (car l) ": found " (itoa (length (cdr l))) " times"))
(foreach e (cdr l) (ssadd e ss))
)
(sssetfirst nil ss)
)
)
(princ)
)
@mickeforsberg wrote:
....
Is there a way to quickly find duplicate entries and highlight them...? For example if 1.100 is used twice in the drawing.
....
How 'bout this [minimally tested]:
(defun C:FDM (/ mss n mt mtc mtclist); = Find Duplicate Mtexts
(if (setq mss (ssget "_X" '((0 . "MTEXT"))))
(progn ; then
(setq dup (ssadd)); initially empty duplicates list;
; not localized, so you can do something with them
(repeat (setq n (sslength mss))
(setq
mt (ssname mss (setq n (1- n)))
mtc (cdr (assoc 1 (entget mt)))
); setq
(if (member mtc mtclist); value is already used
(ssadd mt dup); then -- put object in duplicates set
(setq mtclist (cons mtc mtclist)); else -- put content in list
); if
); repeat
(if (> (sslength dup) 0) (sssetfirst nil dup))
); progn
); if
(princ)
); defun
It leaves the first-encountered instance of any given value alone, and all subsequent instances of the same value selected/gripped/highlighted. If you want all instances of any value that's duplicated to be identified, that could be done, but it's more complicated.
It assumes there is no internal formatting within the Mtext objects, or at least that any such formatting [color override, etc.] is identical between ones that you would consider duplicates, since it looks at the entire string content of each object, including internal formatting codes.
Since it doesn't localize the 'dup' variable [so you can use that selection set in some kind of process apart from just having them be selected], if you want to run it again in the same editing session in the same drawing, you should wipe that out -- (setq dup nil) -- first.
@Kent1Cooper wrote:
....
It leaves the first-encountered instance of any given value alone, and all subsequent instances of the same value selected/gripped/highlighted. If you want all instances of any value that's duplicated to be identified, that could be done, but it's more complicated.
....
Since one can't assume that the first-encountered instance of a given duplicate content is the one you'll want to keep, I decided it's better to identify all of them. The attached further-developed TextFindDuplicates.lsp with its TFD command does that, and some other things:
It includes both plain Text and Mtext [see comments at the top about what constitutes a "duplicate" between the two types];
It differentiates each set of duplicates from the others, by giving a different color override to duplicates of each shared content. [Undoing afterwards puts them all back.]
See further explanation/comments at the top of the file.
[Error in Post 4: The last paragraph is incorrect -- it does wipe that clean on subsequent use, by starting the variable again as an empty selection set.]
