Delete everything outside the circle in Lisp.
But since this isn't a long list but only a list containing the entity names of the created polygons, your point in this case is not really valid 
@Anonymous wrote:
Hello,
My task is to create circle, then create some triangles inside and outside that circle. Program should let me draw only triangles inside the circle, and delete ones outside the circle.
Here is the code I've done so far. It works fine through X-axis and Y-axis, but sometimes it draws triangle outside the circle.
What is wrong, and how to make everything deleted outside the circle.
You need to check every single vertex of the drawn polygon against the circle perimeter. If any of the vertex is outside then delete the triangle. See below example. Minimal testing.
(defun c:somefunc (/ center center_t circle curosmode h radius)
(setq center (getpoint "\nCircle center: ")
radius (getpoint "\nCircle radius: ")
radius (distance center radius))
(command "circle" center radius)
(setq circle (entlast))
(setq curosmode (getvar 'osmode))
(setvar 'osmode 0)
(repeat (getint "\nHow many triangles? :")
(setq center_t (getpoint "\nSet the center: ")
h (getpoint "\nSet the height: "))
(command "._polygon" "3" center_t "I" h)
(if (apply 'or
(mapcar '(lambda (x) (> (distance center x) radius))
(cdr (reverse (vl-remove-if-not 'listp (mapcar 'cdr (entget (entlast))))))))
(progn (princ "\nTriangle not contained within circle.") (entdel (entlast)))))
(setvar 'osmode curosmode)
(princ))
Some questions:
Do you mean to eliminate [or prevent from being drawn in the first place] all triangles that extend outside the Circle at all, or only those that are completely outside the Circle?
This line:
(setq h (getpoint "Set the height"))
gives very peculiar results if I type in values for the heights of the triangles, rather than pick points on-screen. Is it your intent that the height must always be set by a point pick [in which case I suggest changing the wording of the prompt, and/or adding center_t as a reference point for rubber-banding], or should the User have the option to type in a value [in which case I suggest using (getdist ) rather than (getpoint )]?
[EDIT: Sorry, this should be in response to @Anonymous -- I picked Reply under a Reply to the original, but should have under the original itself.]
Kent Cooper, AIA 
@Kent1Cooper wrote:
....
This line:
(setq h (getpoint "Set the height"))
.... Is it your intent that the height must always be set by a point pick ..., or should the User have the option to type in a value ...?
....
And springing from that.... The word "height" in relation to a triangle in geometry has a meaning, and it's not the radius of the triangle's Circumcircle. For an equilateral triangle, it's 1.5 times that. Should the prompt be something like "Pick a corner of the triangle: "?
In your routine, the picking of the second point determines both the size and the orientation of the triangle, whereas with a pure-number circle radius for it to be inscribed in, the triangle always gets a horizontal base and a corner pointing straight up. Is that a reason to do it by point pick and not by typing in a value? If so, and if any triangle that extends outside the Circle at all is to be eliminated, I would suggest you leave command echoing on, and even Osnap if you might want it for some point or other, and do something like this:
(defun C:TIC ; = Triangles Inside Circle
(/ cdata ctr-c rad-c)
(command "_.circle")
(while (> (getvar 'cmdactive) 0) (command pause))
(setq
cdata (entget (entlast))
ctr-c (cdr (assoc 10 cdata))
rad-c (cdr (assoc 40 cdata))
); setq
(initget 6); no zero, no negative
(repeat (getint "\nHow many triangles? ")
(command "_.polygon" 3 pause "_inscribed" pause)
(if
(<
rad-c
(apply 'max
(mapcar '(lambda (x) (distance x ctr-c))
(mapcar 'cdr (vl-remove-if-not '(lambda (y) (= (car y) 10)) (entget (entlast))))
)
)
)
(progn ; then
(prompt "\nTriangle extended outside circle.")
(entdel (entlast))
)
(setq triangles (cons (entlast) triangles)); else
)
)
(princ)
)
That allows any of the possible ways of drawing the Circle [pick-point or Diameter/2P/3P/Ttr options], and you can see it dynamically as you draw it. And it lets you see the triangles forming as you draw them, which could prevent drawing a bad one in the first place. By leaving the commands to supply their own prompts and operating within the commands instead of before-hand, you not only get the dynamic drawing aspect, but also a number of your variables are no longer needed.
Another question arises in trying that out: If you draw any that violate the Circle, do you want to still be able to draw the number of triangles you asked for originally? The above and your original give you that many tries, but if any of them are no good, you end up with fewer than you wanted. To get another try for any that fail, it would need to use something like a (while) loop and a counter, rather than that (repeat) function, which would be an easy adjustment.
[EDIT: If used more than once in a drawing session, consider whether you want triangles inside multiple Circles to all be added into one collective 'triangles' list variable, or whether you want to put (setq triangles nil) near the top to start the list over with each running of the command. It would even be possible to make them separate lists for each running, with variable names like triangles1, triangles2, etc., if you need that.]
Kent Cooper, AIA
@Kent1Cooper wrote:
.... If you draw any that violate the Circle, do you want to still be able to draw the number of triangles you asked for originally? The above and your original give you that many tries, but if any of them are no good, you end up with fewer than you wanted. To get another try for any that fail, it would need to use something like a (while) loop and a counter, rather than that (repeat) function, which would be an easy adjustment. ....
Like this:
(defun C:TIC ; = Triangles Inside Circle
(/ cdata ctr-c rad-c n)
(command "_.circle")
(while (> (getvar 'cmdactive) 0) (command pause))
(setq
cdata (entget (entlast))
ctr-c (cdr (assoc 10 cdata))
rad-c (cdr (assoc 40 cdata))
); setq
(initget 6); no zero, no negative
(setq n (getint "\nHow many triangles? "))
(while (> n 0)
(command "_.polygon" 3 pause "_inscribed" pause)
(if
(<
rad-c
(apply 'max
(mapcar '(lambda (x) (distance x ctr-c))
(mapcar 'cdr (vl-remove-if-not '(lambda (y) (= (car y) 10)) (entget (entlast))))
)
)
)
(progn ; then
(prompt "\nTriangle extended outside circle.")
(entdel (entlast))
)
(setq ; else
triangles (cons (entlast) triangles)
n (1- n)
)
)
)
(princ)
)
Kent Cooper, AIA
@ActivistInvestor wrote:
.... According to what I read, the OP wants to know if a triangle is [entirely] within a circle, and wants to reject any triangle that is not [entirely] within a circle, regardless of whether it is entirely outside, or partially inside/outside the circle. ....
I've been wondering all along whether or not that's what they want, and hoping to hear answers from the OP to various questions raised.
Their original code, though it's mistakenly checking within a square that wraps the Circle rather than within the Circle alone, checks only for whether the center-point of each triangle is within the test area, not for whether all of it is. By that criterion, it would keep many potential triangles that are partially inside/outside the circle [as well as many that are entirely outside by surrounding the Circle while having no part that falls inside it]. But it wouldn't keep all that cross the Circle -- it would reject any whose center-point is outside, even if some part extends inside.
@Anonymous, can you clarify what you're after? [And, incidentally, I'm curious about the purpose of such a thing.]
Kent Cooper, AIA