declaring variable
@vishshreevT578L wrote:
(defun CopyLayerColor2 (ent1 ent2 / elist1 elist2 lay1 col1)
....
my question is about declaring variable which i am making bold. (defun CopyLayerColor2 (ent1 ent2 / elist1 elist2 lay1 col1)
The trick is in the use of a function like that, with arguments. Since it does not have a C: before the function name, it is a function, and not a command, which means it must be called inside parentheses, just as with any other AutoLisp function, and not by entering the name at the Command prompt.
The things in the parentheses following the function name are distinguished by whether they are before or after the slash character. Those that are before it are arguments, and you must supply them [I assume that's what you mean by "declaring" them] when you use the function, inside the parentheses calling the function, after the function name, and in the order in the arguments list. They must be the kind of thing that the function will be looking for, in this case entity names. This is how you would use that function:
(CopyLayerColor2 anEntityName anotherEntityName)
Those entity names can be supplied from variables, which you would set by some other means external to this function definition, such as @ВeekeeCZ's first code in Post 4. Or one of them could be (entlast), or either or both could be taken from a list of them with something like (nth) or (car)/(cadr)/(etc.) or (last), or from a selection set with (ssname), or by (entnext), or any other means of conveying an entity name.
Note that the second code in Post 4 doesn't merely redefine the function, but defines it instead as a Command name [with the C: prefixed], without arguments but with selection of entities built into it. That one you would use by just typing in the command name, without surrounding parentheses.
@vishshreevT578L wrote:
....I WILL SET A NEWSTR IN SUCH A WAY
(SETQ NEWSTR (ARGTEST "STR1" 2.0)) THEN IT HAS TO PROMPT FOR
"bad argument: arg2 not a string
Exactly. That's what it's designed to do. The arg1 and arg2 are supposed to be text strings. Try:
(SETQ NEWSTR (ARGTEST "STR1" "2.0"))
@vishshreevT578L wrote:
sir can you give a effective example on this
The first code in Post 4 is one [I expect, though I haven't loaded and tried it]. It defines a CopyLayerColor2 Command [with the C: prefixed]. When you type in that command name, it asks you to select things [in which I would add "and color" in the prompts], and it puts their entity names into the en1 and en2 variables. It then uses those variables as the ent1 and ent2 arguments in the CopyLayerColor2 function.
In the Command's use of the function:
(CopyLayerColor2 en1 en2)
the 'en1' is that variable set earlier in the Command. Since it is the first argument supplied in calling the function, it will be used in the operation of the function wherever the first argument in its argument list ['ent1'] appears in its code. And the second supplied argument [in this case 'en2'] will be used wherever the second argument listed in the function definition line ['ent2'] occurs in its code.
@vishshreevT578L wrote:
NO PROMPT HERE SIR....THATS WHAT IS CONFUSING ME ....
I get the prompts from @ВeekeeCZ's first code in Post 4. Are you loading it correctly? After loading it, does AutoCAD recognize the CopyLayerColor2 command name? If so, does it not prompt you to select the objects?
In trying it out, I discovered something: If the first object's color is ByLayer, but the second one has an override color, the routine will change the second one's Layer, but it will not change its Color to ByLayer to match the first object -- it leaves the Color override on the second object. See below for one that imposes ByLayer Color on the second one if that is the Color of the first one.
But in addition to that, there's a cute trick that can simplify this. If an entity data list has more than one entry for a property for which there can be only one [such as Layer and Color], the entry that comes later in the list "wins" and overrules any earlier one(s). That means it's not necessary to (subst)itute entries taking properties from one list into the other. You can simply add entries onto the end, and the earlier ones will be overruled by the later ones. This eliminates the need for some variables, and for the extraction of Layer and Color properties. Try this [lightly tested]:
(defun CopyLayerColor2 (ent1 ent2 / elist1 elist2); the function
(setq
elist1 (entget ent1); entity data lists
elist2 (entget ent2)
); setq
(setq elist2 (append elist2 (list (assoc 8 elist1)))); assign ent1's Layer to ent2
(setq elist2
(append elist2 ; Color adjustment
(if (assoc 62 elist1); ent1 has override [non-Bylayer] Color
(list (assoc 62 elist1)); then [give that to ent2]
'((62 . 256)); else [make ent2's Color ByLayer]
); if
); append
); setq
(entmod elist2); update properties of ent2
); defun
(defun C:CLC2 (/ en1 en2); = Copy Layer & Color 2 [whatever the 2 means]; the command
(if
(and
(setq en1 (car (entsel "\nObject to copy Layer and Color FROM: ")))
(setq en2 (car (entsel "\nObject to copy Layer and Color TO: ")))
); and
(CopyLayerColor2 en1 en2); apply those entities as arguments to the function
); if
(princ)
); defun
[I shortened the command name from BeekeeCZ's version for ease of use.]
And then, of course, there's the option to just use MATCHPROP -- I assume this must be for situations where there might be other override properties that you don't want copied from the first object to the second. However, MATCHPROP has Settings with which it can be limited to match only Layer and Color -- setting it that way would eliminate the need for any of this, as well as letting you do the matching to more than one other object within one running of the command.
@vishshreevT578L wrote:
....
that means whatever we are declaring here (DEFUN C:TEST (ARG1 ARG2 .... / TEST1 TEST2) HAS TO BE DEFINED IN A VARIABLE.
.....
Not necessarily always in a variable, though that is probably how arguments are supplied in most cases. But you could supply the arguments not in variables. A very trivial example:
(defun Add3 (Num1 Num2 Num3); = Add 3 numbers and only 3 numbers
(+ Num1 Num2 Num3)
)
To use that, you could ask for numbers and put them into variables to feed to it, but you can also feed in numbers directly, and/or symbols and/or the results of other functions:
Command: (Add3 1.234 pi (sqrt 10))
7.53787
[That is trivial because you could just do:
(+ 1.234 pi (sqrt 10))
but one might have a reason to require 3 and only 3 numbers. The (+) function can't restrict how many numbers you add in it, but the (Add3) function would tell you if you supplied the wrong number of arguments.]
@vishshreevT578L wrote:
now i want to inspect this code line by line, so how will i?
I suggest you just read about each function involved in Help. The function names are what immediately follows each left parenthesis -- defun, setq, append, if, and so on.
