Date Format in Lisp Help

[Anonymous]

We are working on a lisp that will fill in some DWGPROPS with one key command. We have it working so typing the command "Approve" will fill in the Author, Subject, and Keyword of the DWGPROPS. For us the Keyword is the date the command is executed. What we can't get is the format of the date within this lisp to be MM/DD/YYYY. We have seen several forum posts for formatting the date, but have been unsuccessful in adding it to this lisp to get it functioning properly. Any help would be greatly appreciated.

Lisp is:

(defun C:APPROVE (/ App Doc DwgProps)
(setq App (vlax-Get-Acad-Object)
Doc (vla-Get-ActiveDocument App)
DwgProps (vla-Get-SummaryInfo Doc)
)
(vla-Put-Author DwgProps "COMPANY")
(vla-Put-Subject DwgProps "APPROVED FOR CONSTRUCTION")
(vla-Put-Keywords DwgProps (rtos (getvar 'cdate) 2 0))
(princ (vla-Get-Author DwgProps))(princ", ")
(princ (vla-Get-Subject DwgProps))(princ", ")
(princ (vla-Get-Keywords DwgProps))(princ", ")
(princ (vla-Get-RevisionNumber DwgProps))(princ", ")
(princ (vla-Get-Title DwgProps))(princ", ")
(princ (vla-Get-Comments DwgProps))(princ", ")
(princ)
)

[ronjonp]

Try this:

(menucmd "M=$(edtime, $(getvar,date),MM/DD/YYYY)")

[hak_vz]

(defun cdate ( / date yyyy mm dd)
  (setq date (rtos (getvar "cdate") 2 6))
  (setq yyyy (substr date 1 4)
        mm    (substr date 5 2)
        dd    (substr date 7 2)
  )
    (strcat dd "/" mm "/" yyyy)
 )
;usage (cdate)  returns 28/07/2021

[Anonymous]

In which line would this string go?

[Anonymous]

Where in our lisp would this go?

[ronjonp · Accepted solution]

---

@Anonymous wrote:

In which line would this string go?

---

Based on your example above it would be in the 'keywords' section.

(vla-put-keywords dwgprops (menucmd "M=$(edtime, $(getvar,date),MO/DD/YYYY)"))

[hak_vz]

(vla-Put-Keywords DwgProps (cdate))

Or in complete code

(defun C:APPROVE (/ App Doc DwgProps cdate)
(defun cdate ( / date yyyy mm dd)
  (setq date (rtos (getvar "cdate") 2 6))
  (setq yyyy (substr date 1 4)
        mm    (substr date 5 2)
        dd    (substr date 7 2)
  )
    (strcat dd "/" mm "/" yyyy)
 )
 
(setq App (vlax-Get-Acad-Object)
Doc (vla-Get-ActiveDocument App)
DwgProps (vla-Get-SummaryInfo Doc)
)
(vla-Put-Author DwgProps "COMPANY")
(vla-Put-Subject DwgProps "APPROVED FOR CONSTRUCTION")
(vla-Put-Keywords DwgProps (cdate))
(princ (vla-Get-Author DwgProps))(princ", ")
(princ (vla-Get-Subject DwgProps))(princ", ")
(princ (vla-Get-Keywords DwgProps))(princ", ")
(princ (vla-Get-RevisionNumber DwgProps))(princ", ")
(princ (vla-Get-Title DwgProps))(princ", ")
(princ (vla-Get-Comments DwgProps))(princ", ")
(princ)
)

[zainshah44]

SIR MY AUTOCAD .VLX LISP COMMAND FORMATE CHNGE TO NOTEPAD PLS TELL ME HOW CAN I SOLVE THIS ISSUE

[Sea-Haven]

You can not edit a VLX. Need to contact the original author.