Creating pline boundary
@ВeekeeCZ wrote:
Try... Assuming you have a block with polylines in the same direction. ....
... and assuming that the Polylines' drawing order matches their positional sequence. Having some of them "out of order" as well as having one drawn running in the other direction are both causes of the undesired result in your second drawing.
That seems the biggest challenge to me -- figuring out for a set of Polylines, with such wildly different lengths and relative positional shifts, what the sequence should be, and which end is which for each one in relation to the others. For example, it wouldn't be hard for a routine to determine for each one which is its upper-most end, if that's a reliable standard to use [which I would not assume, but maybe it is for what you're doing]. But then how would it figure out the order to trace along those ends? It can't do them in either left-to-right or top-to-bottom order, so what standard could be applied that would give a reliable result?
@dani-perez wrote:
.… So, my issue is impossible to solve, isnt it? ….
I wouldn't claim it's impossible, but I'm having a hard time imagining how to do it. Your eye and brain can do it very easily, and could do a heck of a lot of them in the amount of time it would take someone to come up with the code to automate it. But if I can think of a workable approach, I'll be back, and I hope others will ponder whether there's a way to do it.
@dani-perez wrote:
.... picking cant be automated, so I will have to pick one by one. ....
But picking can be greatly reduced from picking one by one in order:
(prompt "\nUse Fence selection across one-line-segment Polylines in sequence to") (setq ss
(ssget ; provides its own "Select objects: " prompt
'(
(0 . "LWPOLYLINE")
(-4 . "<not") (-4 . "&=") (70 . 1) (-4 . "not>") ;; not-closed only
(-4 . "<not") (-4 . "<>") (42 . 0.0) (-4 . "not>") ;; no-bulge [i.e. line segment] only
(90 . 2) ;; single-segment only
); filter list
); ssget
); setq
You will need to type in the F to go into Fence selection, as instructed, but then you just draw a Fence through them along the appropriate path, and what that returns is a selection set of them in positional-sequence order, no matter what their drawn order. A single leg of that Fence path will often be able to pass through a whole bunch of the Polylines, sparing you the need to pick each one to determine the sequence. I haven't followed up with the further processing, stepping through that selection set to work with the Polylines to build the perimeter, but this should give you a big jump on the selection part.
EDIT:
It appears it's not even necessary to step through that selection set. With LOFTNORMALS set to 0 for straight edges instead of splined ones, all you need is to start a LOFT command, and give it ss as the selection, and get your Surface:
(command "_.loft" ss "" "")
and then go on with the Exploding of that into Regions, Unioning them, converting to a Polyline, as in Marko's routine.
There remains the "problem" that in any case, you need to Explode the Block to get the Polylines, but you could make a copy in-place, Explode that, do this with the results [the selection will ignore the underlying Block], and then delete the ss selection set, and your original Block will still be there.
@Kent1Cooper wrote:
But picking can be greatly reduced from picking one by one in order:(prompt "\nUse Fence selection across one-line-segment Polylines in sequence to")….You will need to type in the F to go into Fence selection …. what that returns is a selection set of them in positional-sequence order....
….
It appears it's not even necessary to step through that selection set. …. start a LOFT command, and give it ss as the selection, and get your Surface:(command "_.loft" ss "" "")and then go on with the Exploding of that into Regions, Unioning them, ….
…. you could make a copy in-place, Explode that, do this with the results [the selection will ignore the underlying Block], and then delete the ss selection set, and your original Block will still be there.
So going back to @marko_ribar's earlier notion of LOFTing and Exploding, etc., with the above Fence-selection approach, it can be done with far less code [minimally tested]:
(defun C:WRAP (/ blksel ss)
(if
(and
(setq blksel (entsel "\nSelect Block of one-line-segment Polylines: "))
(= (cdr (assoc 0 (entget (car blksel)))) "INSERT")
); and
(progn ; then
(command
"_.copy" (car blksel) "" "0,0" ""
"_.explode" "_last"
); command
(prompt "\nUse Fence selection across one-line-segment Polylines in sequence to")
(setq ss
(ssget ; provides its own "Select objects: " prompt
'(
(0 . "LWPOLYLINE")
(-4 . "<not") (-4 . "&=") (70 . 1) (-4 . "not>") ;; not-closed only
(-4 . "<not") (-4 . "<>") (42 . 0.0) (-4 . "not>") ;; no-bulge [i.e. line segment] only
(90 . 2) ;; single-segment only
); filter list
); ssget
); setq
(command
"_.loft" ss "" ""
"_.erase" ss ""
"_.explode" "_last"
"_.union" "_previous" ""
"_.explode" "_last"
"_.pedit" "_multiple" "_previous" "" "_join" 0 ""
); command
); progn
); if
(princ)
); defun
It does require LOFTNORMALS=0, and that the Block selected is made up of single-line-segment-only Polylines.
@marko_ribar wrote:
I may be wrong, but then again maybe not... I think you are missing setting peditaccept=1 in your version...
True -- I always have it set that way, so it was when I tested the routine. That can certainly be built in, for those who may not always use that setting. Here's a version that does that, and similarly handles the LOFTNORMALS setting, and suppresses command echoing of all the steps. Tested on the Block in @dani-perez's second sample drawing in Message 3.
(defun C:WRAP (/ svnames svvals blksel ss)
(setq
svnames '(cmdecho loftnormals peditaccept)
svvals (mapcar 'getvar svnames)
); setq
(mapcar 'setvar svnames '(0 0 1)); turn off command echo, set LOFT, accept PEDIT
(if
(and
(setq blksel (entsel "\nSelect Block of one-line-segment Polylines: "))
(= (cdr (assoc 0 (entget (car blksel)))) "INSERT")
); and
(progn ; then
(command
"_.copy" (car blksel) "" "0,0" ""
"_.explode" "_last"
); command
(prompt "\nUse Fence selection across one-line-segment Polylines in sequence to")
(setq ss
(ssget ; provides its own "Select objects: " prompt
'(
(0 . "LWPOLYLINE")
(-4 . "<not") (-4 . "&=") (70 . 1) (-4 . "not>") ;; not-closed only
(-4 . "<not") (-4 . "<>") (42 . 0.0) (-4 . "not>") ;; no-bulge [i.e. line segment] only
(90 . 2) ;; single-segment only
); filter list
); ssget
); setq
(command
"_.loft" ss "" ""
"_.erase" ss ""
"_.explode" "_last"
"_.union" "_previous" ""
"_.explode" "_last"
"_.pedit" "_multiple" "_previous" "" "_join" 0 ""
); command
); progn
); if
(mapcar 'setvar svnames svvals); reset
(princ)
); defun
You do need to be aware enough to notice the instruction to use Fence selection, type the F, draw the Fence, and give it an additional Enter to complete the selection.
In experimenting, I find that if that Block is of non-uniform scales, when Exploded its Polylines become Lines, so it doesn't work. It can be of a scale other than 1, and it can be mirrored so the X and Y don't have the same sign, but it must have equal scale absolute values in all 3 coordinate directions.
It could also use *error* handling, but that's easily added, if it otherwise does what you want.
