Create text with Delta Y of the distance between a given point and where to click.
(defun c:y_diff ( / *error* a b c)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
)
(while
(setq
a (getpoint "\nPick first point >")
b (getpoint a "\nPick second point >")
c (getpoint b "\nPick y differance location text point >")
)
(if
(and a b c)
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 100 "AcText")
(cons 1 (rtos (apply '- (mapcar 'cadr (list a b))) 2 2))
(cons 10 c)
(cons 40 (getvar 'textsize))
)
)
)
)
(princ)
)
Or more general solution
(defun c:xyz_diff ( / *error* a b c d dir)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
)
(initget 1 "x y z")
(setq dir (getkword "\nDifferance direction x y z >"))
(while
(setq
a (getpoint "\nPick first point >")
b (getpoint a "\nPick second point >")
c (getpoint b (strcat "\nPick " dir " differance text location point >"))
)
(if
(and a b c)
(progn
(cond
((= dir "x") (setq d (apply '- (mapcar 'car (list a b)))))
((= dir "y") (setq d (apply '- (mapcar 'cadr (list a b)))))
((= dir "z") (setq d (apply '- (mapcar 'last (list a b)))))
)
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 100 "AcText")
(cons 1 (rtos d 2 2))
(cons 10 c)
(cons 40 (getvar 'textsize))
)
)
)
)
)
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Here's one that makes the Text and then has you position it, so you can see the size of it as you do so, to avoid having it write over something.
(defun C:DeltaYText (/ p1 p2)
(setq
p1 (getpoint "\nFirst point: ")
p2 (getpoint "\nSecond point: ")
)
(command "_.text" "_mc" (getvar 'viewctr))
(if (member '(40 . 0.0) (tblsearch "style" (getvar 'textstyle)))
(command "" 0) (command 0); current height + rotation, or just rotation
)
(command
(rtos (abs (cadr (mapcar '- p1 p2)))); in current mode/precision
"_.move" "_last" "" "@"
)
)
It uses the current Text Style and height [whether or not the Style has a fixed height], on the current Layer, with the text content in whatever the current mode and precision settings are. All of that can be forced to particular values if needed.
Or, how about one that, after you've picked the first point, shows you the Text you'll get as you move the cursor around, until you pick the second point and lock it in?
(defun C:DeltaYText (/ elistbase p1 done txt)
(setq elistbase
(list '(0 . "TEXT") '(10 0.0 0.0 0.0) (cons 40 (getvar 'textsize)) '(72 . 1) '(73 . 2))
); setq
(setq p1 (getpoint "\nFirst point: "))
(prompt "\nSecond point: ")
(while (and (not done) (setq cur (grread T 12 0)))
(cond
((= (car cur) 5); moved cursor
(if txt (entdel txt))
(setq p2 (cadr cur)); cursor location
(redraw)
(grdraw p1 p2 40 1)
(setq txt
(entmakex
(append
elistbase
(list
(cons 11 (mapcar '/ (mapcar '+ p1 p2) '(2 2 2))); insertion
(cons 1 (rtos (abs (cadr (mapcar '- p1 p2))))); content
); list
); append
); entmakex
); setq
); 5 condition
((= (car cur) 3) (setq done T)); picked point - leave drawn Text, end (while) loop
); cond
); while
(prin1)
)
It puts the Text midway between the two points. It could follow up with letting you re-position it, as in my other suggestion. [Unfortunately, while it honors Object Snap for the first point, it doesn't for the second. I think there may be something around that can make that possible, but don't remember the topic.]
Another suggestion: Define a DIMENSION Style with both extension lines and both dimension lines suppressed, and simply use the DIMVERTICAL command. You'll be left with the text content as the Y difference between the definition points you give, with all the options about text position and rotation and style and so on that Dimension Styles offer.
EDIT: Adjusted to add rubber-banding between points:
@Kent1Cooper wrote:
.... Another suggestion: Define a DIMENSION Style with both extension lines and both dimension lines suppressed, and simply use the DIMVERTICAL command. ....
That looks like this:
You can reposition the text part after drawing it, if you like, as I did with the first one after drawing the second one.
It has the advantage over Message 8 of working with Object Snap for both points.
And it has the additional advantage that if you Stretch stuff including the definition point locations, the Y-distance text content will update automatically.
You could also do things like include a prefix in the Dimension Style, such as "ΔY=" [the same could also be added to other routines].
Message 1 did not say anything about multiple second points relative to one common first point, but if that's what you're looking for [such as in @komondormrex's adjusted code in Message 10], that could be added to various routines.
But first, I confess to being curious about what you plan to use this for. What is the meaning of a piece of Text floating somewhere that contains the Y-coordinate difference between two points somewhere, to which the Text makes no reference? How can one know what that Text represents after the fact? This is something I would think is better done with a vertical Dimension, including extension lines [unlike my earlier Dimension suggestion], so the text content has an identifiable relationship to what it represents. So I'm just curious about the application.
Maybe this, using fixed first point.
(defun c:xyz_diff_from_reffpoint ( / *error* a b c d dir)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
)
(initget 1 "x y z")
(setq dir (getkword "\nDifferance direction x y z >"))
(setq a (getpoint "\nPick referance point >"))
(while
(setq
b (getpoint a "\nPick second point >")
c (getpoint b (strcat "\nPick " dir " differance location point >"))
)
(if
(and a b c)
(progn
(cond
((= dir "x") (setq d (apply '- (mapcar 'car (list b a)))))
((= dir "y") (setq d (apply '- (mapcar 'cadr (list b a)))))
((= dir "z") (setq d (apply '- (mapcar 'last (list b a)))))
)
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 100 "AcText")
(cons 1 (rtos d 2 2))
(cons 10 c)
(cons 40 (getvar 'textsize))
)
)
)
)
)
(princ)
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
ORDINATE Dimensions may be able to do what you want without any routine.
@ClaudioRosevel wrote:
ORDINATE Dimensions uses the ucs as a reference for the final value. I need the delta Y value to be added to the chosen value.
You can put the reference location anywhere you want. Draw some Ordinate Dimensions, and with them all selected, go find the grip at 0,0 and drag it to your preferred reference location, and they'll all adjust themselves. You can incorporate that "chosen value" to be added, by just grip-moving the common reference to that far below the "nominal" reference Y position.
Or temporarily change the UCS Origin while you make them, then set it back. Their values won't change [unless and until you drag their reference grips somewhere else].
You can turn off their extension lines if you don't want to see those, with DIMOVERRIDE, setting both DIMSE1 and DIMSE2 Off [they don't show up in the Properties palette for Ordinate Dimensions, for some reason].
Pick a point for datum, enter 210 do offset for text ie point to left, how many more and at what increment 2 & 5.0 all done from a lisp point of view. A good lisp learning task have a go. Advanced front end.
Regards @ClaudioRosevel
Try this code...
;;;___
(defun c:lev (/ Dt dp hp ht np dh tx)
(setq Dt (Getreal "\nEnter Datum Value: ")
dp (getpoint "\nPick Point Datum : ")
ht (getreal "\nEnter Text Height: ")
)
(while
(setq
hp (getpoint dp "\nPick Point Cota Value: ")
)
(setq
np (getpoint hp "\Pick Point to text insertion: ")
dh (- (cadr hp) (cadr dp))
tx (rtos (+ Dt dh) 2 2)
)
(entmakex (list '(0 . "text")
(cons 1 tx)
(cons 10 np)
(cons 11 np)
(cons 40 ht)
(cons 72 2)
)
)
)
(princ)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
