corrugated metal pipe

[Anonymous]

does anyone know if there is a lisp routine that can draw this pipe in
2d, to scale ie; 12", 36" 48" and showing all the corrugations
features


--
Dave Johnson
Cadd Operator
WWC Engineering
Sheridan, Wy.
NT 4.0 sp 6
AcadMap 5
Survcadd CES

[Anonymous]

Dave,

It shouldn't be hard to do, but I think we need more info. By 12" etc. I
assume you mean the diameter of the pipe.

I don't know much about corrugated metal pipe. Looked at the Pacific
Corrugated Pipe Company site. Seems their standard pipe corrugation
dimensions are "pitch" 2.67" by .5" depth. Does that sound right?

And another question, do you mean in top plan view or in plan section view?
In other words, is the graphic representation in plan from above or section?

BTW, this might be better handled with a custom line type or an mline. I
don't know beans about that stuff.

Joe Burke

> does anyone know if there is a lisp routine that can draw this pipe in
> 2d, to scale ie; 12", 36" 48" and showing all the corrugations
> features
>
>
> --
> Dave Johnson
> Cadd Operator
> WWC Engineering
> Sheridan, Wy.
> NT 4.0 sp 6
> AcadMap 5
> Survcadd CES
>
>

[Anonymous]

>
>
> Joe

> yes...12", 24'', 36'', 48'', etc diameter pipe and I believe the pitch is for
> the actual corrugations which isnt really all that important. what I am
> looking for is a graphical representation of the pipe in plan view. right
> know we just connect a bunch of arcs or ellipses to show the corrugation and
> then array a bunch of lines down the length of the pipe.

I put a picture of what our pipes look like in customer files hope it helps

thanks


--
Dave Johnson
Cadd Operator
WWC Engineering
Sheridan, Wy.
NT 4.0 sp 6
AcadMap 5
Survcadd CES

[Anonymous]

Dave,

Could you post a .dwg to customer files? That would be more informative.

Thanks
Joe Burke

>
> > yes...12", 24'', 36'', 48'', etc diameter pipe and I believe the pitch
is for
> > the actual corrugations which isnt really all that important. what I am
> > looking for is a graphical representation of the pipe in plan view.
right
> > know we just connect a bunch of arcs or ellipses to show the corrugation
and
> > then array a bunch of lines down the length of the pipe.
>
> I put a picture of what our pipes look like in customer files hope it
helps
>
> thanks
>
>
> --
> Dave Johnson
> Cadd Operator
> WWC Engineering
> Sheridan, Wy.
> NT 4.0 sp 6
> AcadMap 5
> Survcadd CES
>
>

[Anonymous]

sure.... not a problem
I will put it under the previous post


--
Dave Johnson
Cadd Operator
WWC Engineering
Sheridan, Wy.
NT 4.0 sp 6
AcadMap 5
Survcadd CES

[Anonymous]

Dave,

Thanks for the .dwg file. I was wondering about things like your units
setting. I use Imperial. See below. There's notes about that stuff. The way
it's setup now should work with decimal units. I tested it in your file.
Note, everything is placed on the active layer. It could be modified to put
the pipe outline on some layer and the hatch on another.

So try it and let me know what you think. Seems to work here.

Regards
Joe Burke

;by Joe Burke 8/8/2002 - draw corrugated pipe
;see RAD variable for decimal vs. Imperial units
(defun c:cpipe (/ LEN ANG DIAM RAD STPT ENPT INC INCPT MAXINC NCOPY
P1 P2 P3 P4 PTLST HPN HPA HPS HPD MARK SS *Error*)
(defun *error* (Msg)
(cond
((or (not Msg)
(member Msg '("console break"
"Function cancelled"
"quit / exit abort"
)
) ;close member
) ;close or
) ;closes condition, no message to display
((princ (strcat "\nError: " Msg))) ;else display message
) ;close cond
(setvar "hpname" HPN)
(setvar "hpang" HPA)
(setvar "hpspace" HPS)
(setvar "hpdouble" HPD)
(setvar "cmdecho" 1)
(princ)
) ;end error

(defun SSAfterEnt (ent / ss*)
(cond
((entnext ent)
(setq ss* (ssadd))
(while
(setq ent (entnext ent))
(ssadd ent ss*)
)
)
)
)

;start
(setvar "cmdecho" 0)
(setq DIAM (getdist "\nEnter pipe diameter: ")
STPT (getpoint "\nPick start point: ")
ENPT (getpoint STPT "\nPick end point: ")
LEN (distance STPT ENPT)
ANG (angle STPT ENPT)
P1 (polar STPT (+ ANG (/ pi 2)) (/ DIAM 2))
P2 (polar P1 ANG LEN)
P3 (polar P2 (- ANG (/ pi 2)) DIAM)
P4 (polar P3 (- ANG pi) LEN)
;RAD 2.0 ;<< change this to vary size of corrugation
RAD 0.15 ;for decimal units, 2.0 for Imperial
MAXINC (* RAD 1.5)
MARK (entlast)
HPN (getvar "hpname")
HPA (getvar "hpang")
HPS (getvar "hpspace")
HPD (getvar "hpdouble")) ;setq

(setq NCOPY (+ 1 (fix (/ LEN MAXINC))) ;number of copies
INC (/ LEN NCOPY) ;increment distance
INCPT (polar P1 ANG INC)) ;first increment point

(setq PTLST (list INCPT))
(while (> NCOPY 1)
(setq PTLST (cons (polar INCPT ANG INC) PTLST))
(setq INCPT (polar INCPT ANG INC))
(setq NCOPY (1- NCOPY))
) ;while
(setq PTLST (reverse PTLST))

(command "pline" P1 "a" "r" RAD)
(foreach p PTLST (command p))
(command)
(command "mirror" (entlast) "" STPT ENPT "")
(command "line" P1 P4 "")
(command "line" P2 P3 "")
(setvar "hpname" "_user")
(setvar "hpang" (+ ANG 1.4))
(setvar "hpspace" MAXINC)
(setvar "hpdouble" 0)
(setq SS (ssadd))
(setq SS (ssafterent MARK))
(command "hatch" "" "" "" "" SS "")
;(princ (strcat "\n" "Distance start to end point: " (rtos LEN 3 4)))
;engineering
(princ (strcat "\n" "Distance start to end point: " (rtos LEN 2 4)))
;decimal units
(princ)
(*Error* nil)
) ;end

[Anonymous]

Joe


I dont know quite how to say this but THANK YOU THANK YOU THANK YOU


this is going to save us a lot of time. I did have one of our guys that
understands lisp better than me go through it and add a couple of things like
change the spacing of the hatch to match the pipe size and we might go ahead
and put it on its own layer.


again.....thanks give yourself a raise you deserve it 🙂



--
Dave Johnson
Cadd Operator
WWC Engineering
Sheridan, Wy.
NT 4.0 sp 6
AcadMap 5
Survcadd CES

[Anonymous]

Dave,

You're welcome. 🙂

Joe

[srt_titya]

Could u tell me how to use this lips?

[hmsilva]

---

@srt_titya wrote:
Could u tell me how to use this lips?

---

Hi srt_titya,

I'm not Joe, and unfortunately I have not 'seen' Joe Burke around here for some time...

If your doubt is how to use '.lsp' files in AutoCAD, probably this Lee Mac's tutorial can help you.

If your doubt is specific to this code, please try to explain a little more what difficulties you have using Joe's code.

Hope this helps,
Henrique