Copy attribute from selected block to another

[spartan_vng]

Hi all, I've been digging around the forum and can't find exactly what I'm looking for but I was hoping one of you folks might be able to point me in the right direction. I'm in need of a script that allows me to copy the value of an attribute from a selected block (source) and paste that value to an attribute of the same name in a different block (destination). The trick here I guess is that I need it to continue till I specify when to stop.
Thanks

[marko_ribar]

Quick and dirty...

(defun c:copypasteattribattribbytag ( / att tag str blk a )

  (vl-load-com)

  (setq att (car (nentsel "\nPick attribute...")))
  (setq tag (vla-get-tagstring (vlax-ename->vla-object att)))
  (setq str (vla-get-textstring (vlax-ename->vla-object att)))
  (while (setq blk (car (entsel "\nPick block to paste attribute value to - ENTER TO FINISH...")))
    (setq a blk)
    (while (= (cdr (assoc 0 (entget (setq a (entnext a))))) "ATTRIB")
      (if (= (strcase tag) (strcase (vla-get-tagstring (vlax-ename->vla-object a))))
        (vla-put-textstring (vlax-ename->vla-object a) str)
      )
    )
  )
  (princ)
)

M.R.

[spartan_vng]

wow.... thank you so much. I'll give it a try when I get to work on Monday.
Thanks
Vince

[spartan_vng]

  Hi Marko,

Thanks again for the quick reply. I gave the lisp a try and I works based on the rough description I gave you however I had a fellow coworker tweak the code for me a bit to make it work more for what I was looking for. Only issue I'm running into now is that I need to pick the actual source attribute vs picking the block that has that specific attribute within it. We can try and hack the code some more ( we are not lisp literate) but if you have any suggestions you may have would be greatly appreciated.

Regards,

Vince

[alanjt_ · Accepted solution]

How about something like this...

(defun c:MAV (/ AT:GetSel atts ss i ass)
  ;; Match Attribute Values
  ;; Alan J. Thompson, 2017.01.31


  (defun AT:GetSel (meth msg fnc / ent)
    ;; meth - selection method (entsel, nentsel, nentselp)
    ;; msg - message to display (nil for default)
    ;; fnc - optional function to apply to selected object
    ;; Ex: (AT:GetSel entsel "\nSelect arc: " (lambda (x) (eq (cdr (assoc 0 (entget (car x)))) "ARC")))
    ;; Alan J. Thompson, 05.25.10
    (while
      (progn (setvar 'ERRNO 0)
             (setq ent (meth (cond (msg)
                                   ("\nSelect object: ")
                             )
                       )
             )
             (cond ((eq (getvar 'ERRNO) 7) (princ "\nMissed, try again."))
                   ((eq (type (car ent)) 'ENAME)
                    (if (and fnc (not (fnc ent)))
                      (princ "\nInvalid object!")
                    )
                   )
             )
      )
    )
    ent
  )


  (if (and (AT:GetSel entsel
                      "\nSelect source attributed block: "
                      (lambda (x / d)
                        (if (and (eq (cdr (assoc 0 (setq d (entget (car x))))) "INSERT")
                                 (eq (cdr (assoc 66 d)) 1)
                            )
                          (setq atts (mapcar (function (lambda (a) (cons (vla-get-tagstring a) (vla-get-textstring a))))
                                             (vlax-invoke (vlax-ename->vla-object (car x)) 'GetAttributes)
                                     )
                          )
                        )
                      )
           )
           (progn
             (princ "\nSelect destination attributed block(s): ")
             (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
           )
      )
    (repeat (setq i (sslength ss))
      (foreach a (vlax-invoke (vlax-ename->vla-object (ssname ss (setq i (1- i)))) 'GetAttributes)
        (if (setq ass (cdr (assoc (vla-get-tagstring a) atts)))
          (vla-put-textstring a ass)
        )
      )
    )
  )

  (princ)
)
(vl-load-com)
(princ)

[scot-65]

Selecting the source attribute.

Partial code block for your investigation:

;
 (while (setq a (entsel "Select an ATTRIBUTE to globally update: "))
  (if (= (cdr (assoc 0 (entget (car a)))) "INSERT")
   (progn
    (setq b (nentselp (cadr a)))
    (if (= (cdr (assoc 0 (entget (car b)))) "ATTRIB")
     (progn
      (setq bn (cdr (assoc 2 (entget (car a))))) ;block name
      (setq bt (cdr (assoc 2 (entget (car b))))) ;tag name
      (setq bv (cdr (assoc 1 (entget (car b))))) ;tag value
...
;

???

[john.uhden]

@marko_ribar wrote: "Quick and dirty...

(defun c:copypasteattribattribbytag ..."

Typing in "copypasteattribattribbytag" may be dirty but certainly not quick.  :]

[spartan_vng]

Alan,

dang.... Pretty spot on for what I need. Only thing was is that  I was hoping to have it loop through so I did not have to hit enter to execute the lisp again. No biggie still works for what I need.

Thanks so much

Vince

[alanjt_]

---

@spartan_vng wrote:

Alan,

dang.... Pretty spot on for what I need. Only thing was is that  I was hoping to have it loop through so I did not have to hit enter to execute the lisp again. No biggie still works for what I need.

Thanks so much

Vince

---

You're welcome.

Swap out the first if statement for a while, and you'll be good.

 (if (and (AT:GetSel entsel

TO

 (while (and (AT:GetSel entsel

[tom_durfee]

Thanks @alanjt_

Absolute hero! You've saved me from having to manually re-enter up to 58 attributes per block! (from v1 of dynamic block to v2, with 1 added attribute)

[mrushcadtech]

Would there be a way to enable this routine to set the attribute's layer to "0" and the color of the layer to "GREEN" during the evaluation? 

What about providing an option to select similar once the first destination block was selected?

[MarsksMan]

and if I want a preselected block for source just like MA command?

[Jason.Rugg]

@alanjt_Is there a way to automatically repeat this on multiple sources and copy to multiple destinations? Example would be an old parts list where each line item is an attributed block and need to copy all of the line item attributes to a newer line item block. Would be nice not to have to manually run the command on each line.

[alanjt_]

Definitely. You would just need a list of old attributed blocks and a corresponding list of new attributed blocks. 

[stephanosdoulos]

Saved me a massive amount of time. Thank you very much. 

[hebertsanchez]

This right here is one of the best things that I have found in this forum... 100 thank yous for this good sir. 

[spartan_vng]

No. Prob...just thank the person who originally scripted it for me.
The members are great in helping each other out!

[mail]

Any way to work this across layouts?

[jbernalPTA3R]

THANK YOU THIS REALLY SAVED ME SOME TIME

[john.uhden]

Amazing. I hadn't even tested it.
Please hit the "Accept as solution" button to my previous note.
Remember that we want you to learn from these contributions so that one day
you will be providing the solutions to others.