@jtm2020hyo ,
Attached the fix.
About blocks name:
EXPLAY adds (nnn) as suffix to block name as basic format, example:
you have "ground plan" layout, the block would be "ground plan(1)" if "ground plan(1)" block is not already exist.
if you have "ground plan(1)" layout, the block would be "ground plan(1)" again if "ground plan(1)" block is not already exist. if it is? the block would be "ground plan(2)" ....etc.
the program search Layout name for the parentheses and the number inside and use it as index to increment. the max number is limited to 2 power 7 (up to 128) to prevent infinite loop.
this declares in code as:
; declare constants
(setq UPTO (expt 2 7)) ; (= 128)
if you find this as limitation, you can set a higher power value like (expt 2 😎 increase it to 256 😀
the program will exit if suffix is not a numeric value. rename the layout to resolve this.
enjoy
Moshe
(vl-load-com) ; load ActiveX support
; Export to layout than bring it as standard block
(defun c:EXPLAY (/ bname_generator ; local function
UPTO ERRMSG savAttreq savAttdia fname bname)
; block name generator
(defun bname_generator (LayoutName / is_numeric gen_bn ; local functions
p0 p1 suff)
(defun is_numeric (suf)
(vl-every
'(lambda (c)
(and (>= c 48) (<= c 57))
)
(vl-string->list suf)
); vl-every
); is_numeric
(defun gen_bn (layN j / bn)
(while (and
(< j UPTO)
(tblsearch "block" (setq bn (strcat layN "(" (itoa j) ")")))
)
(setq j (1+ j))
); while
(if (< j UPTO)
bn
)
); gen_bn
(cond
((and
(setq p0 (vl-string-position (ascii ")") LayoutName 0 t))
(setq p1 (vl-string-position (ascii "(") LayoutName 0 t))
)
(setq suff (substr LayoutName (+ p1 2) (- p0 p1 1)))
(if (not (is_numeric suff))
ERRMSG
(gen_bn (vl-string-right-trim (strcat "(" suff ")") LayoutName) (1+ (atoi suff)))
); if
); case
( t
(gen_bn LayoutName 1)
)
); cond
); bname_generator
; here start EXPLAY command
(setvar "cmdecho" 0)
(command "._undo" "_begin")
; declare constants
(setq UPTO (expt 2 7)) ; (= 128)
(setq ERRMSG "illegal value found inside layout name parentheses.")
(setq savAttreq (getvar "attreq"))
(setq savAttdia (getvar "attdia"))
(setvar "attreq" 0)
(setvar "attdia" 0)
(cond
((= (getvar "tilemode") 1)
(vlr-beep-reaction)
(princ "\nthis command only work from layout.")
); case
((not (setq bname (bname_generator (getvar "ctab"))))
(vlr-beep-reaction)
(princ (strcat "\nReached suffix limits, upto " (itoa UPTO) " is allowed, block is not created"))
); case
( t
(if (eq bname ERRMSG)
(progn
(vlr-beep-reaction)
(princ ERRMSG)
); progn
(progn
; depending on layout 'volume' and computer speed
; next code lines may suspend autocad process
; for a while, without echoing to your screen - patience...
(setq fname (strcat (getvar "dwgprefix") bname))
(command "._exportlayout" fname)
(setq bname (vl-filename-base fname))
(setvar "expert" 5)
(command "._-insert" bname)
(command); escape
(vl-file-delete (strcat fname ".dwg"))
(setvar "expert" 0)
(princ (strcat "\n" bname " is now standard block."))
); progn
); if
); case
); cond
(setvar "attdia" savAttdia)
(setvar "attreq" savAttreq)
(command "._undo" "_end")
(setvar "cmdecho" 1)
(princ)
); explay
