Conditional nested in with loop not working like I need it to
Accepted solution
For comparison, or if you like anything about what's there better, there's an essentially identical topic >here<. I posted a TagIncrement routine at Message 11 that isn't marked as a Solution, and uses a different method to keep the latest numerical part [an R option for Repeat], but has some features you may find useful:
:: You can choose the incrementing value [it doesn't always have to be 1], which can also be negative if you want to count downward;
:: It can specify a Prefix and a Suffix or both ;
:: It remembers your choices [of incrementing value, Prefix & Suffix] and also what number you got to, and offers them all as defaults on subsequent use, so you don't have to enter them again;
:: It shows you [at the command prompt area] what the content of the next Tag you place is going to be.
See more commentary at the top of the file, and also look into the other offerings on that thread.
Kent Cooper, AIA 
@Anonymous wrote:
... it works out better for them if it doesn't index UNLESS they hold the shift down ....
The way that part works doesn't seem right to me. If the numerical part of the last one I placed is 3, and I release the Shift key, the next one still increments up to 4, and only the one after that remains the same [at 4]. And after I've done some 4's, then I press down Shift again, the next one doesn't increment up to 5, but that doesn't happen until the one after that. Is that really the way you want it to work? You seem to need to know when you're going to want to change between incrementing and not one step in advance of when you really want the change to occur.
Kent Cooper, AIA
Accepted solution
@Anonymous wrote:
I noticed it lags by one too....
Well, it occurred to me that this could be overcome by moving the check on the Shift key to a different place. This adjustment works as I would prefer, BUT with one caveat: if you want the numerical part to increment right from the start [no repeat of the first number], don't press down Shift until after you've placed the first one. If you press it down before you pick the first location, it will start with the number one higher than you asked for. [It's likely that with an additional variable it could remove that restriction by checking whether or not you're placing the first one, but I didn't work that through.]
(defun C:SEQ (/ base numb pt)
(setq
base (getstring "\nPrefix: ")
numb (getint "\nBeginning Number: ")
ht (getdist "\nText height: ")
); setq
(while (setq pt (getpoint "\nInsertion point: "))
;; if shift key is down, iterate number; else, keep the same.
(if (acet-sys-shift-down) ;; <-- MOVED from after (entmake) to before
(setq numb (1+ numb))
);; If
(entmake
(list
'(0 . "TEXT")
(cons 1 (strcat base (itoa numb)))
(cons 7 (getvar "textstyle"))
(cons 10 pt)
(cons 40 ht)
'(50 . 0)
) ;;list
) ;;entmake
) ;;while
(princ)
); defun
Kent Cooper, AIA
@Kent1Cooper wrote:
.... [It's likely that with an additional variable it could remove that restriction by checking whether or not you're placing the first one, but I didn't work that through.] ....
It was simpler than I expected to figure out a way to do that, so you can press Shift either before or after the first pick, and you'll get the first number you asked for either way, and the next one will increment:
(defun C:SEQ (/ base numb pt next)
(setq
base (getstring "\nPrefix: ")
numb (getint "\nBeginning Number: ")
ht (getdist "\nText height: ")
); setq
(while (setq pt (getpoint "\nInsertion point: "))
;; if shift key is down, iterate number; else, keep the same.
(if
(and
next ; [will be nil at first pick]
(acet-sys-shift-down)
); and
(setq numb (1+ numb))
);; If
(entmake
(list
'(0 . "TEXT")
(cons 1 (strcat base (itoa numb)))
(cons 7 (getvar "textstyle"))
(cons 10 pt)
(cons 40 ht)
'(50 . 0)
) ;;list
) ;;entmake
(setq next T); i.e. past the first one
) ;;while
(princ)
); defun
Kent Cooper, AIA