Change Text Height and Text Style based on Layer Name

[janu319]

Hallo,

I'm looking for lisp that will change the Text Height and Text Style of all the Text/MText on a particular layer. 

I tried to find in the old posts but could not find any. 

Layer Name	Text Style	Text Height
Layer1	Style1	2,25
Layer2	style2	2
Layer3	style3	2,25
Layer4	style2	1,5

Text height set to 0 for all the text styles in the settings. 

Thanks in advance.

Janu

[ВeekeeCZ]

Here is a function and example of usage.

Make sure that the layer is not locked.

(defun :TextHeightByLayer (layer style height / s i)
  (if (setq s (ssget "_A" (list '(0 . "*TEXT")(cons 7 style)(cons 8 layer))))
    (repeat (setq i (sslength s))
      (setpropertyvalue (ssname s (setq i (1- i))) "Height" height))))

(:TextHeightByLayer "Layer1" "TextStyle1" 2.25)

Or is you want to make all at once, make another function...

(defun c:ChangeAllTexts () 

(:TextHeightByLayer "Layer1" "TextStyle1" 2.25)

...

(princ)

)

[janu319]

Thank you for the quick response, but after loading the code, I got NIL response. 

There is a layer "Layer1" and also a text style "Text Style1" in my drawing. Please see attached image. 

Am I doing something wrong? 

[ВeekeeCZ]

Looks just about right.

It does not change a style at all. You cannot have a style of one name with different properties for different layer.

It simply changes the text's property.

[janu319]

But there is no change in Text properties as well. Text height also not changed. 

[ВeekeeCZ]

Then you're doing something wrong.

[janu319]

 I just copy paste the code you provided in to the command prompt, and nothing happened in the drawing. Please see the attached screen shot.  

I'm using autoCAD 2018, in case if that matters, I think not. 

[ВeekeeCZ · Accepted solution]

Ok, I see your point. I didn't understand your goal about style right.

(defun :TextHeightByLayer (layer style height / s i d)
  (if (and (or (setq d (tblobjname  "STYLE" style))
	       (prompt (strcat "Error: TextStyle '" style "' not found in the drawing!")))
	   )
    (if (setq s (ssget "_A" (list '(0 . "*TEXT") (cons 8 layer))))
      (repeat (setq i (sslength s))
	(setpropertyvalue (ssname s (setq i (1- i))) "TextStyleID" d)
	(setpropertyvalue (ssname s i) "Height" height))))
  (if s (princ (strcat (itoa (sslength s)) " texts found.")))
  (princ))

[CodeDing · Accepted solution]

@janu319 ,

This code is not working because there was some misinterpretation between @ВeekeeCZ and you.

Bee's code takes text on a LAYER and STYLE then changes HEIGHT.

You are looking for a code that takes LAYER then changes STYLE and HEIGHT.

So, when you run Bee's code, it does not find any text with the style of "TextStyle1" (thank you for the picture btw).

I made some edits and I think this code is what you're looking for. I have not tested yet, but should work.

(defun SetStyleHeightByLayer (lyr sty hgt / ssT cnt e)
  (if (and (setq ssT (ssget "_A" (list '(0 . "*TEXT") (cons 8 lyr))))
           (setq sty (tblobjname "STYLE" sty)))
    (repeat (setq cnt (sslength ssT))
      (setq e (ssname ssT (setq cnt (1- cnt))))
      (setpropertyvalue e "TextStyleId" sty)
      (setpropertyvalue e "Height" hgt) t ;<--this 't' is return value
    );repeat
  ;else
    (prompt "\nNothing performed. Check for text and text style. Then try again.")
  );if
);defun

EDIT:

Looks like BeekeeCZ just posted update! Sorry, not trying to intrude. Now you should have 2 codes to approach with!

Best,

~DD

[janu319]

Thank you, this is what exactly I'm looking for. 

[janu319]

Thank you for your time, both codes are working fine. 🙂