Change specific word color
@msarqui wrote:
pbejse wrote:
Thats good to know.
Question:
- Will there be two or more target "WORD" present on one MTEXT string? Yes, and I think it is better to change one target "WORD" at a time. But, there is a nuance here: So, if I have two different target "WORD" on one MTEXT string, I will execute the routine two times. But, I can have two equal target "WORD" in the same MTEXT. In that case, the routine will change both.
- Will you be running the same routine on a MTEXT already has colors in it? Yes
- Like in the example, not just one color? Yes, the MTEXT could have more than one color Different item different color? Yes
Thanks!
OK, i think i get the general idea now. I'll start writing the code....
Try this
Color Me Bad
(defun c:CMB (/ str ss rgx obj objtype)
;;; Color Me Bad pBe Feb 2015 ;;;
;;; Special Thanks to Lee Mac ;;;
;;; for introducing me to RegEx ;;;
(if (and
(setq
Str (getstring T "\nWhich word do you want to change color? ")
)
(snvalid str)
(setq col (acad_colordlg
(if col
col
7
)
nil
)
)
(setq ss (ssget "_X" '((0 . "MTEXT,TEXT"))))
)
(progn
(setq rgx (vlax-get-or-create-object "VBScript.RegExp"))
(vlax-put-property rgx 'global actrue)
(vlax-put-property rgx 'ignorecase actrue)
(vlax-put-property rgx 'multiline actrue)
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
(cond
((null (vl-string-search
(strcase str)
(strcase (setq s (vla-get-textstring obj)))
)
)
)
((equal (setq objtype (vla-get-Objectname obj)) "AcDbMText")
(vlax-put-property
rgx
'pattern
(Strcat
"\\\\C([0-9]|[1-9][0-9]|1[0-9][0-9]|2[0-4][0-9]|25[0-5]);"
str
)
)
(vla-put-textstring
obj
(if (not (eq s
(setq s (vlax-invoke
rgx
'replace
s
(Strcat "\\C" (itoa col) ";" str)
)
)
)
)
s
(progn
(vlax-put-property rgx 'pattern str)
(vlax-invoke
rgx
'replace
s
(Strcat "{\\C" (itoa col) ";" str "}")
)
)
)
)
)
((eq objtype "AcDbText") (vla-put-color obj col))
((eq objtype "AcDbBlockReference")
(princ "\n<<< Discontinued >>>")
)
)
)
(vlax-release-object rgx)
)
)
(princ)
)
Command: CMB
Which word do you want to change color? CSA S37-13
HTH
@hmsilva wrote:
Using the 'VBScript RegExp Object', nice approach, pBe!!!
Cheers
Henrique
Thank you Henrique, dealing vl-string functions is too troublesome . too many things to consider.
Hope the code is enough for msarqui. I saw a bug on the code but I will modify it tomorrow to maintain the letter case of the target "word"
Cheers my friend 🙂
@msarqui wrote:
Yes! Is enough and I am very thankful to you. The routine is really fast, even in a large drawing (like the one I have). Also, it keeps the existing formatation.
....Many many thanks!.
Excellent and you are welcome msarqui
msarqui wrote:
I did not understand if your comment about the letter case of the target "word" is related to what I will tell you now. If the answer is yes, I'm sorry, but I noticed one small thing and, I want to say before all, it doesn't bothers me because I do not have this "small words" as a target. I think maybe this could be something to work for a future and more specific routine. So, here is the thing: if I type "and" for the target word, 1 for the color, and I have a word like "standard", this last will change to "standard". But, like I said, in my drawings I have only "larger words" and the routine changed all very consistently.
I meant, when you typed in BANANA and the target "word" is "Banana" the original letter case will remain as Banana
......
((null (and (setq p (vl-string-search (strcase str) (strcase (setq s (vla-get-textstring obj))))) (setq str (substr s (1+ p) (strlen str))) ) )
)
......
As for "and" in standard, its as simple as removing (snvlaid str) from the code and replacing it with (/= str ""), then you can type " and " <--with whitespace
Also, i found out that Multi-line attributes can be assigned with colors < Copy or Swap Text.> Maybe one of these days i'll modify the code to do just that.
pBe
pbejse wrote:
...
As for "and" in standard, its as simple as removing (snvlaid str) from the code and replacing it with (/= str ""), then you can type " and " <--with whitespace
....
I can imagine a further complication.... The following situation may not be likely to occur with "and" as a potentially-nested word, but there are countless other possible nested words. Imagine that the word you want is "wood" and some text might include the word "plywood," or "woodwork," in which you don't want to change the partial "wood" inside. Typing in " wood " with surrounding spaces as the target word could miss it in certain instances, since it may not always have spaces on both sides of it, for example where it occurs followed immediately by a comma or period or right parenthesis, or preceded by a left parenthesis. Maybe it's nothing for the OP to be concerned about, if they would usually be using the routine on longer and less-likely-to-be-nested words, but it remains a possibility.
@Kent1Cooper wrote:
I can imagine a further complication....
....., but it remains a possibility.
I guess the user had to be extra careful with the target words then. But you are right, there will be complications.
Very observant of you Kent, thank you for the info.
pBe
