Change Layer Color for Printing
If you have a file .txt that has list of layer names and its colors written as
layer1,50 layer2,100 1,15 2,25
This code will change color of that layers to that color. Since I use entmod approach colors should be written as numbers 1 - 255
(defun c:lcff (/ *error* str_to_lst f file1 redak lst layer_color layer_name lay)
(defun *error* ()
(setvar "cmdecho" 1)
(close file1)
)
(defun str_to_lst (str / len lst pos )
(setq len (1+ (strlen ",")))
(while (setq pos (vl-string-search "," str))
(setq lst (cons (substr str 1 pos) lst)
str (substr str (+ pos len))
)
)
(reverse (cons str lst))
)
(setvar "cmdecho" 0)
(setq f (getfiled "Open File" (getvar "dwgprefix") "txt" 2))
(setq file1 (open f "r"))
(while (setq redak (read-line file1))
(setq lst (str_to_lst redak) layer_name (car lst) layer_color (atoi(cadr lst)))
(if (tblsearch "layer" layer_name)
(progn
(setq lay (entget (tblobjname "layer" layer_name)))
(setq lay (subst (cons 62 layer_color)(assoc 62 lay) lay))
(setq lay (entmod lay))
)
)
)
(close file1)
(setvar "cmdecho" 1)
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
I didn't see a method to toggle to RED to default layer color. I guess I'd need two .TXT files, one to change the layers to RED and another to change them back to default colors.
I've made it the way that you have two txt files, one with original layer colors and other with changes. If needed, I can try to modify this so that you have one file with covers both situation. I'd add a function to write out all layers with current colors, that can be easily edited. Idea is to have thx file written as
"layer_name,original_color,changed color". In that case you are not restricted to change colors to RED but can do it how ever you like it. Also I have to check how this function works regarding changing color to current layer. If it doesen't work we have to create temporary curent layer, perform all changes and reset curent layer. Presumption is that all element in a layer are created using color bylayer. So helper function to do that would be handy. Also we presume that all layers use indexed colors. If true colors are needed then this has to be done to. In that case code becomes a bit complex. Original function was written as a simple and not completely optimized solution.
At the moment, combining @ВeekeeCZ answers your request.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@RocksterB wrote:
.... to plot certain layers color RED and change it back to default again later. ....
Now, if the routine finds the controlling layer I-FURN-SEAT is anything color but RED, it changes these just layers I-FURN-SEAT, I-FURN-FREE & I-FURN-STOR to RED. .... This is a temporary property change used to plot the drawings with RED line work.
....
After plotting, I run the "same" routine and if it finds the controlling layer I-FURN-SEAT is RED, it changes them back to their original layer color. ....
I think this can be a lot simpler, and involve only one running of the command to cover both halves of the above description and include the Plotting. Lightly tested:
(defun C:PFR (); = Plot Furniture Red
(if (member '(62 . 1) (tblsearch "layer" "I-FURN-SEAT")); reference Layer is Red?
(progn ; then -- Plot, then put standard [non-red] colors to certain Layers
(initdia)
(command-s "_.plot")
(command "_.layer" "_color" 4 "I-FURN-SEAT" "_color" 3 "I-FURN-FREE" "_color" 50 "I-FURN-STOR" "")
); progn
(progn ; else -- change certain Layers to Red, Plot, put Layer colors back
(command "_.layer" "_color" 1 "I-FURN-SEAT,I-FURN-FREE,I-FURN-STOR" "")
(initdia)
(command-s "_.plot")
(command "_.layerp"); revert Layer color change
); progn
); if
(princ)
); defun
Note that you can apply the same Layer-command option to more than one Layer at a time, with comma separators [all 3 to Red in one shot].
