Change Attribute Value with user input
@Anonymous wrote:
There might be many more ways to do this but this is the only way that i can think of. I am open to any ideas if anyone has any input.
I would think so too.
Why use attribute blocks If you are planning to explode [ burst ] it afterwards. Use a regular block then change the values per value match.
Using the attached none-attribute block [ DXF TAG NA.dwg ]
(defun c:INB (/ bn values ip el value)
(if (and
(or (tblsearch "BLOCK" (setq bn "DXF TAG NA"))
(setq bn (findfile "DXF TAG NA.dwg"))
)
(setq values
(mapcar '(lambda (itm)
(setq tmp (getstring T (strcat "\nEnter " itm ": ")))
(cons itm tmp)
)
'("JOBNAME" "JOBNUMBER" "PRODUCT" "VIEW" "QUANTITY")
)
)
(setq ip (getpoint "\nPick Point to Insert the Block....."))
)
(progn
(command "_.insert" bn ip 1 1 0)
(setq el (entlast))
(command "_.explode" el)
(while (setq el (entnext el))
(if (and
(eq "TEXT" (cdr (assoc 0 (setq ent (entget el)))))
(setq value (assoc (cdr (assoc 1 ent)) values))
)
(entmod (subst (cons 1 (cdr value)) (assoc 1 ent) ent))
)
)
)
)
(princ)
)
If you still want to use your attribute block
(defun c:IBB (/ bn values ip blk value)
(if (and
(or (tblsearch "BLOCK" (setq bn "DXF TAG"))
(setq bn (findfile "DXF TAG.dwg"))
)
(setq values
(mapcar '(lambda (itm)
(setq tmp (getstring T (strcat "\nEnter " itm ": ")))
(cons itm tmp)
)
'("JOBNAME" "JOBNUMBER" "PRODUCT" "VIEW" "QUANTITY")
)
)
(setq ip (getpoint "\nPick Point to Insert the Block....."))
(setq blk (vlax-invoke
(vlax-get (vla-get-ActiveLayout
(vla-get-ActiveDocument (vlax-get-acad-object))
)
'Block
) 'InsertBlock ip bn 1 1 1 0))
)
(progn
(foreach itm (vlax-invoke blk 'GetAttributes)
(if
(setq value (assoc (vla-get-tagstring itm) values))
(vla-put-textstring itm (cdr value))
)
)
(sssetfirst nil (ssadd (entlast)))
(c:burst)
)
)
(princ)
)
HTH
@Anonymous wrote:
.... If I was going to want to insert that block into any DWG ....
... I would definitely not do it as in the original description, with one that has values in the Attributes already, needing to be changed, if you're then asking the User for values to change them to. I would Insert one in "raw" [un-filled-out] form, and let it do the asking for the values, which INSERT is built to do with Attributed Blocks [provided the Attributes are not defined with constant values]. Then BURST it. Or am I missing something?
[The Block can be a drawing file in any location in OPTIONS's Support File Search Path list, and INSERT will find it -- no need for the routine to spell out a file path. And once it's already in a drawing, you can use it there again without its needing to reach out to the external file as it would if the file path is built into the routine.]
Kent Cooper, AIA 
@Anonymous wrote:
I cant get the block to insert in any drawing but but its own... any reason that would be happening? I tried playing around with it to get it to work and didn't have any luck.
I do agree with Kent1Cooper, If the routine will ask the user for the values might as well do it with the native insert command (with ATTREQ set to 1) where you get that pretty dialog box for input. or even better use tool palettes.
Whats the point of "bursting" the blocks anyway? keeping the attributes is much better specially if you need to gather info on your drawings [ Quantity per Job number etc.. ].
Now getting back to your query, Not sure what you mean sbrathovd. Did you try the suggestion below?
@Kent1Cooper wrote:[The Block can be a drawing file in any location in OPTIONS's Support File Search Path list, and INSERT will find it -- no need for the routine to spell out a file path. And once it's already in a drawing, you can use it there again without its needing to reach out to the external file as it would if the file path is built into the routine.]
Otherwise, post a sample drawing.