Ok it look like you are getting close to what you want, but you have a few issues with proper arguments you are passing to functions.
You don't need to enclose the attribute section in a progn code block.
the LM:SetAttributeValues function takes an entity and a list of attribute tag and value pairs
should look like this (LM:SetAttributeValues (car blk) (list l))
You had specified an ssname function with blk as the argument. your blk is a listed selection point and entity name. (car blk) pulls out the entity name from the list.
your l variable (BTW use something that doesn't look like a 1 for a variable name)
is constructed properly but the function is looking for a list of dotted pairs.
Here is some updated code, hopefully this helps.
(defun c:abc (/ b l blk i layertable layname)
(setq blk (entsel "\nSelect blocks to modify: "))
(initget (+ 1 2 4))
(setq b (getreal "\nNew att value? (>0;1<)"))
;open layer
(setq LayerTable (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
(if (and (tblsearch "LAYER" "MC_BLOCK")
(setq layname (vla-item layertable "MC_BLOCK"))
(= (vlax-get-property layname 'lock) :vlax-true)
)
(vla-put-lock layname :vlax-false))
;modify attribute
(setq l (cons "CAMPO_6" (itoa (fix b))))
(LM:SetAttributeValues (car blk) (list l))
;close layer
(setq LayerTable (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
(if (and (tblsearch "LAYER" "MC_BLOCK")
(setq layname (vla-item layertable "MC_BLOCK"))
(= (vlax-get-property layname 'lock) :vlax-false)
)
(vla-put-lock layname :vlax-true))
(princ)
)
(defun LM:SetAttributeValues ( blk lst / enx itm )
(if (= "ATTRIB" (cdr (assoc 0 (setq enx (entget (setq blk (entnext blk)))))))
(if (setq itm (assoc (strcase (cdr (assoc 2 enx))) lst))
(progn
(if (entmod (subst (cons 1 (cdr itm)) (assoc 1 enx) enx))
(entupd blk)
)
(LM:SetAttributeValues blk lst)
)
(LM:SetAttributeValues blk lst)
)
)
)
| 
| 
