Bounding box with offset code help

[atrotto]

Hello folks,

I'm just getting started with AutoLISP / Active X, and I cannot figure out why this isn't working. The bottom left corner of the rectangle drew with offset when I was testing with just mno, but when I replicated it with mxo, the code stops working. The bulk of this code is borrowed, leaving honorable mention in the comments. 

;;Foamstamp.lsp
;;Bounding code borrowed from BlackBox on CadTutor

(defun c:FoamStamp (/ eName mn mx mno mxo)
 (vl-load-com)
 (if (setq eName (car (entsel "\n  >>  Select Object  >> ")))
   (progn
     (vla-getboundingbox (vlax-ename->vla-object eName) 'mn 'mx)
     
     (vl-cmdf "._rectang" (
                            (setq mno (mapcar (lambda (a)(- a 0.25))(vlax-safearray->list mn)))
			    (setq mxo (mapcar (lambda (b)(+ b 0.25))(vlax-safearray->list mx)))
                          )
     ) 
    (princ)
   )
 )
)

[ВeekeeCZ · Accepted solution]

It must be '(lambda... or (function (lambda...

[atrotto]

Thanks, figured it was something simple...

[ВeekeeCZ]

But this way would be more readable

(defun c:FoamStamp (/ eName mn mx mno mxo)
  (vl-load-com)
  (if (setq eName (car (entsel "\n  >>  Select Object  >> ")))
    (progn
      (vla-getboundingbox (vlax-ename->vla-object eName) 'mn 'mx)
      (vl-cmdf "._rectang"
	       (mapcar '+ (vlax-safearray->list mn) '(-0.25 -0.25))
	       (mapcar '+ (vlax-safearray->list mx) '(+0.25 +0.25)))))
  (princ)
  )

[atrotto]

Even better. I was going down a rabbit hole with lambda mostly because it was the Neat New Thing I read about on the Autodesk resource. Thank you so much.

[Kent1Cooper]

---

@ВeekeeCZ wrote:

....
	       (mapcar '+ (vlax-safearray->list mn) '(-0.25 -0.25))
	       (mapcar '+ (vlax-safearray->list mx) '(+0.25 +0.25)))))
....

---

A small thing, but it seems a little odd to add negative numbers to the coordinates....  [And the plus signs on the numbers for the upper right are not needed.]  How about:

  (mapcar '- (vlax-safearray->list mn) '(0.25 0.25))

  (mapcar '+ (vlax-safearray->list mx) '(0.25 0.25)))))

[ВeekeeCZ]

That is what I like about it. Directly see that it goes left and down. Don't have to think about what is subtracted from what... But I guess it's just a matter of personal preference.

[atrotto]

@bee @Kent1Cooper 

Secondary question, does get-boundingbox work with multiple selected entities? As in, could I feed this code multiple objects, and would it be able to make a large bounding box around them?

[ВeekeeCZ]

See this:

http://www.lee-mac.com/ssboundingbox.html

[Kent1Cooper]

---

@atrotto wrote:

.... does get-boundingbox work with multiple selected entities? As in, could I feed this code multiple objects, and would it be able to make a large bounding box around them?

---

Not this Topic's code directly, but in addition to @ВeekeeCZ 's link, I also have a routine that will do that, called DrawBoundingBoxMult.lsp, >here<.  I imagine there are more out there for the Searching.  Any of them would need to be adjusted similarly to this topic if you want the box outboard of the actual extents by some distance.

[atrotto]

Hello, I started looking into this code, but the way Lee approaches handling creating the polyline has me scratching my head as to where to sneak in the offset. Ideally, I'd like to do it in the testcode he gave, so that I could reference the bounding box protocol in a few other programs that would have different offsets.
Am I right in saying that I can't just jam the calculation into his block creating the point coordinates starting at line 21?

[ВeekeeCZ]

Your line is this one

(setq box (LM:ssboundingbox sel))

(setq box (:offset box))

So add one more line below it and figure out the :offset function. It does not necessarily be a function, possibly just an expression that does the offset to coords saved as a list in box variable. 

[Sea-Haven]

Like BeekeeCZ the 'box'

(setq box (LM:SSBOUNDINGBOX (ssget)))
!pts ((20.0 38.0 0.0) (179.0 201.0 0.0))
so offset pts (car box) & (cadr box)

is 2 points as a list, so can apply the offset.