Area field + m²

[aclima]

Hello.

I believe this lisp may already exists but I've not be able to find it. Maybe one of you can help me.
I'm looking for a lisp that creates an mtext with the area of a polyline as object "field" and the suffix "m²", will be very useful for the work I'm doing. thank you

[dennis]

http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/link-between-text-mtext-and-attribute...

Been there, done that.

[Ranjit_Singh]

Here's a very basic version

(defun c:somefunc  (/ mtobject mtht)
 (setq mtht     (getreal "\nEnsert mText Height: ")
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (getpoint "\nInsert mText Insertion Point :"))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr2%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject mtht)
 (princ))

[aclima]

Hello

Thank you, this error appears after importing lisp with appload. Same arror appear after running the command.

"somefunc.lsp successfully loaded.
somefunc.lsp successfully loaded.
Command: ; error: malformed list on input
Command: ; error: malformed list on input"

[Ranjit_Singh]

Try the attached

[aclima]

Hi again!

Thanks a lot for the help.

I would make the following two changes: the command would not ask what the height of mtxt would be (it would use the default value), and more importantly, it would allow the user to change the pecision of the value it displays. In the work I am currently doing, for example, I should not present decimal places.

I also noticed that the text is not placed at the insertion point if the UCS is rotated.
Still, it's already a good help, thank you.

[Ranjit_Singh]

I am mostly working in wcs and never try to catch ucs in my routines. Those are good points. Try below code.

(defun c:somefunc  (/ mtobject mtprec)
 (initget 7)
 (setq mtprec     (getint "\nEnter mText decimal Precision: ")
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (trans (getpoint "\nInsert mText Insertion Point :") 1 0))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr" (if (> mtprec 8) "8" (itoa mtprec)) "%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject (getvar 'textsize))
 (mapcar '(lambda (x y) (setpropertyvalue (entlast) x y)) '("Direction/X" "Direction/Y") (list (car (getvar 'ucsxdir)) (cadr (getvar 'ucsxdir))))
 (princ))

[aclima]

Nice 🙂

The only thing is, if i'm using it correctly, it doesn't allow to remove all decimal places with the "Enter mText decimal Precision" input. The minimum acceptable is 1.

I would also present the last value imputed in this option as default when running the command again command , to speed up the process of multiple area tagging.

thanks

[Ranjit_Singh · Accepted solution]

That shouldn't be too difficult.

(defun c:somefunc  (/ mtobject prec)
 (if (null *somefuncmtprec*) (setq *somefuncmtprec* 2))
 (initget 4)
 (setq prec     (getint (strcat "\nEnter mText decimal Precision <" (itoa *somefuncmtprec*) ">: "))
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (trans (getpoint "\nInsert mText Insertion Point :") 1 0))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr" (if (> prec 8) (progn (setq *somefuncmtprec* 8) "8") (if (null prec) (itoa *somefuncmtprec*) (progn (setq *somefuncmtprec* prec) (itoa *somefuncmtprec*)))) "%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject (getvar 'textsize))
 (mapcar '(lambda (x y) (setpropertyvalue (entlast) x y)) '("Direction/X" "Direction/Y") (list (car (getvar 'ucsxdir)) (cadr (getvar 'ucsxdir))))
 (princ))

[aclima]

Thank you! 🙂

It works beautifully and will be a great help. 

[Ranjit_Singh]

You are welcome

[SufyanAhmed]

Hi,Aclima

Find the attached file may be found useful to You.

[aclima]

hello. This lisp is not working anymore, can you help?

[cadffm]

Hi,

It is working the same way as before,  also in 2023.

Open a new file, draw a rectangle

load the lisp by APPLOAD and run command AA2

after this (you say it dowsn't work),

open your Textscreen[F2] and share the log content with us all.

[aclima]

Hi, Thanks for the feed back, I'm referring to this one from @Ranjit_Singh . 

Cad loads but doesn't run, command is "mtobject", right?

[cadffm]

---

@aclima  schrieb:

Hi, Thanks for the feed back, I'm referring to this one from @Ranjit_Singh . 

Oh, okay - I checked the other one.

Cad loads but doesn't run, command

No (error)message?

Normally you get a message!?

Like "unknown command" is you try to start a command what doesn't exist.

is "mtobject", right?

?

That looks more like "somefunc" 🙂

---

[aclima]

somefunc, of course.

silly mistake. 🙂 Beautiful!

Thanks!

[fpanUVCLZ]

hello,
this LISP is good help for me. thank you for your sharing.

I'd like to make the following two changes: the command would not ask what the height of mtext, but it would use 200 height as default value. Also, the command would not ask what the precision of the value it displays, it would setting a precision of 3 d.p. as default value.
thanks.