I have a block with one attribute and text placed near to it.
I need to add the text value to the attribute.
can anyone help me.
add text value to a block attibute
@Anonymous wrote:
is there any possible way to do this.
Yes, there is a way, But i don't think the drawing sample you posted is anything like the actual drawing file you are trying to fix, all entities are in layer "0".
Post a more realistic drawing if you please.
@john.uhden wrote:
....There must be other properties to distinguish one entity from the next,
even such as content or position.
True, But I would prefer to include the layer name on a filter, plus it's just good practice to use layers in any drawing package.
@Anonymous wrote:
The actual drawing file is very huge with 1.4 million sqm
I am not asking for THE file but only something similar.
@Anonymous wrote:
All these block points are in one layer and the text in another layer.
That will do.
@Anonymous wrote:
is there any possible way to do this.
One way
(Defun c:demo ( / _DXF attrcoll textcoll tfattr attrblk i entity data)
(defun _DXF (d e)(Cdr (Assoc d (entget e))))
(if
(and
;;; Select block where value will be stored ;;;
(setq attrcoll nil textcoll nil
bwattr (car (entsel "\nSelect Block: ")))
(eq "INSERT" (_DXF 0 bwattr))
;;; Select Text object to pair with block ;;;
(setq tfattr (car (entsel "\nSelect text: ")))
(eq "TEXT" (_DXF 0 tfattr))
;;; Search whole database for Block/Text/layer ;;;
(princ "\nSelect objects to process")
(setq ss (ssget "_X" (apply 'append
(list
;;; Blocks using 2 filters from selection block ;;;
;;; Block name (Assoc 2 ..) ;;;
;;; Layer name (Assoc 8 ..) ;;;
'((-4 . "<OR")(-4 . "<AND")(0 . "INSERT")(66 . 1))
(list (assoc 2 (entget bwattr))
(assoc 8 (entget bwattr)))
;;; Text entity using 1 filter from selected text ;;;
;;; Layer name (Assoc 8 ..) ;;;
'((-4 . "AND>")(-4 . "<AND")(0 . "TEXT"))
(list (assoc 8 (entget tfattr)))
'((-4 . "AND>")(-4 . "OR>")))))
)
)
(progn
;;; Process selection. gather insertion point ;;;
(repeat (setq i (sslength ss))
(setq entity (ssname ss (setq i (1- i))))
(setq data (list (_DXF 10 entity) entity))
(if (eq "INSERT" (Cdr (Assoc 0 (entget entity))))
;;; Block attribue collection ;;;
(Setq attrcoll (cons data attrcoll))
;;; Text collection ;;;
(Setq textcoll (cons data textcoll))
)
)
(Foreach itm attrcoll
;;; Search text ins point nearest the block (itm) ;;;
(setq from_To (car (vl-sort
(mapcar '(lambda (to)
(list (distance (car itm) (car to))
(_DXF 1 (cadr to)) to )) textcoll)
'(lambda (a b) (< (Car a)(Car b))))
)
)
;;; The text entity closest to the block ;;;
(setq attrblk (cadr (last from_To))
;;; Remove the current nearest text list ;;;
textcoll (vl-remove (last from_To) textcoll))
;;; Assign the string value to attribute ;;;
(Vla-put-textstring
(car (Vlax-invoke (vlax-ename->vla-object (cadr itm))
'Getattributes))
(cadr from_To))
;;; Delete the processed string entity ;;;
(entdel attrblk)
)
)
)
(princ)
)
HTH
