Add ( ) in attributes
Yes the position are always different. this is the most commun difference. but the layer and the color are are different too
the ( ) and purple color mean this is an old block replaced by the new (red) and the purple value are obsolete and the red are now effective
i can select them by select similar because they are on different layers. that only select the bloc with the layer removed
if you need more info let me know
Accepted solution
Hi jonathan,
in my opinion there's no need to apply a LISP routine or other.
Just go on through these steps:
- select similar blocks "anchor_anno" that are on "removed" layer;
- launch the "find" command;
- in the "find what" box type the text string you want to substitute;
- in the "replace with" box type the same text with ( );
- check "list results";
- check "block attribute value";
- press "find";
- should appear a list of values;
- press "replace all";
- go on with these steps for all the values you have to change.
I wouldn't do it other way.
Hope this helps,
Giancarlo
Accepted solution
@Anonymous wrote:
hi
i post the sample asked Davitg.
it containt a small aera where i have to add new value block in red and identify obselete value in purple and ( ). the ( ) is not placed yet to let you try if you have any idea.
many thanks
Hi Jonathan,
perhaps something will do the trick...
(vl-load-com)
(defun c:demo (/ atts i obj ss str)
(if (setq ss (ssget ":L" '((0 . "INSERT") (66 . 1) (2 . "ANCHOR_ANNO") (62 . 6))))
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
atts (vlax-invoke obj "GetAttributes")
)
(foreach att atts
(if (and (/= (setq str (vla-get-textstring att)) "")
(not (vl-string-position (ascii "(") str))
)
(vla-put-textstring att (strcat "(" str ")"))
)
)
)
)
(princ)
)
Hope this helps,
Henrique
@Anonymous wrote:
Henrique i have to thanks you again because your lisp work very well! (but i removed the fist line)
i never used lisp before and i didn't understand anything about the syntax but i will read tonight about and try to adapt the code to an other bloc. but This bloc have 2 attributes and the first will need only "(" and second attribute will have ")"
my challenge this w-e will be to find How list or identify attributes in a bloc
any tip, comment or document will be accept 🙂
You're welcome, Jonathan!
The 'demo' will select 'ssget' inserts (0 . "INSERT") with the name (2 . "ANCHOR_ANNO") wite attributes (66 . 1) and color 6 (62 . 6), will exclude locked layers ":L"
Process all selected objects as vla objects, (setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
get the attributes as list of atributes (vlax-invoke obj "GetAttributes")
test if the atribute textstring is not empty (/= (setq str (vla-get-textstring att)) "")
and test if in atribute textstring dont exist a "(" to not add more then one if a user select the same block twice (not (vl-string-position (ascii "(") str))
if the tests are true, put the parenthesis in the textstring (vla-put-textstring att (strcat "(" str ")"))
For the other block, is the name the same?
If not, select the block chamging the name, test for the tag,
if first tag (vla-put-textstring att (strcat "(" str ))
if second tag (vla-put-textstring att (strcat str ")"))
To study the functions, open the code in vlide, highlights the function and press the button with a ? it will open the help files in the selected function...
EDIT: some sites, AfraLISP Jeffery P Sanders Lee Mac
Hope this helps,
Henrique
Accepted solution
Hi John,
your code have na error in ssget filter list...
The group code 66 it's an atribute flag.if 1, the insert have attributes.
(66 . 1)
The groupe code for índex color is 62 and (62 . 6) is for color 6.
If you change the filter list
(setq s (ssget "_:L" '((0 . "INSERT") (2 . "ANCHOR_ANNO") (66 . 6))))
to
(setq s (ssget "_:L" '((0 . "INSERT") (2 . "ANCHOR_ANNO") (66 . 1) (62 . 6))))
it should select INSERTs with the name ANCHOR_ANNO with attributes, color 6 and not in locked layers.
But if the user runs the code more than once in the same INSERT, the code will continue adding parentheses to the text string, regardless the parentheses existence already in the string...
I would suggest to add a test before add a parentheses, i.e.
(if (not (wcmatch (setq str (getpropertyvalue b "POLE_NO")) "(*"))
(setpropertyvalue b "POLE_NO" (strcat "(" str ")"))
)
Probably something like this:
(defun c:demo (/ b i s str)
(if (setq s (ssget "_:L" '((0 . "INSERT") (2 . "ANCHOR_ANNO") (66 . 1) (62 . 6))))
(repeat (setq i (sslength s))
(setq b (ssname s (setq i (1- i))))
(if (not (wcmatch (setq str (getpropertyvalue b "POLE_NO")) "(*)"))
(setpropertyvalue b "POLE_NO" (strcat "(" str ")"))
)
(if (not (wcmatch (setq str (getpropertyvalue b "HEIGHT")) "(*"))
(setpropertyvalue b "HEIGHT" (strcat "(" str))
)
(if (not (wcmatch (setq str (getpropertyvalue b "YEAR_ADDED")) "*)"))
(setpropertyvalue b "YEAR_ADDED" (strcat str ")"))
)
)
)
(princ)
)
Untested....
Hope this helps,
Henrique
Accepted solution
@Anonymous wrote:
thanks so much for your help!
i applied your idea of test but i used and other option
[code]
(if (not (vl-string-search "(P" (getpropertyvalue b "POLE_NO")))
(progn
(setpropertyvalue b "POLE_NO" (strcat "(" (getpropertyvalue b "POLE_NO") ")"))
(setpropertyvalue b "HEIGHT" (strcat "(" (getpropertyvalue b "HEIGHT")))
(setpropertyvalue b "YEAR_ADDED" (strcat (getpropertyvalue b "YEAR_ADDED") ")"))
);progn
);if[code]
If 'POLE_NO' text value will always start with P, then it's a good test...
Henrique