Table SetAutoScale & SetAutoScale2
Each cell can contain multiple pieces of content, the first piece content in a cell has an index of 0. So the third parameter of SetAutoScale2 is usually assigned a value of 0. The following is an example that should set the AutoScale value to True for each cell in all table objects located in Model space.
Dim acTable As AcadTable
Dim acEnt As AcadEntity
' Step through all entities in Model space
For Each acEnt In ThisDrawing.ModelSpace
' Check to see if the entity is a Table
If acEnt.ObjectName = "AcDbTable" Then
Set acTable = acEnt
Dim nRow As Integer, nCol As Integer
nRow = 0
' Step through each row in the table
Do While acTable.Rows > nRow
nCol = 0
' Step through each column
Do While acTable.Columns > nCol
' Set the AutoScale value for each cell based on the content in
' index 0, the first content in each cell
acTable.SetAutoScale2 nRow, nCol, 0, True
nCol = nCol + 1
Loop
nRow = nRow + 1
Loop
End If
Next acEnt
Lee Ambrosius
Senior Principal Content Experience Designer
For additional help, check out the AutoCAD Developer Documentation
Okay... I went back and took a look at a few things, it seems to me that SetAutoScale and SetAutoScale won't work because those functions aren't designed for text content but rather blocks to auto-fit a cell (http://help.autodesk.com/view/OARX/2018/ENU/?guid=OREFNET-Autodesk_AutoCAD_DatabaseServices_Table_Ge... Some clarification needs to be made in the ActiveX documentation about which content is affected by AutoScale.
If I am not mistaken, your goal is to increase the width of each column to fit the longest text string.
From what I can tell, there isn't a direct way to tell the table to adjust its column widths automatically using the methods and properties of the AcadTable object. It is possible I missed something though. You can adjust the width of each column based on the longest text string by first calculating the width of each text string in each column using something like the following code. The code sample is what I used to adjust the width and height of the cell in the above images.
Sub AdjustColumnWidths()
Dim acTable As AcadTable
Dim acEnt As AcadEntity
Dim sCellTextVal As String
Dim oMtext As AcadMText
Dim dMtextWidth As Double
' Define the insertion point for the mtext object
Dim insPt(0 To 2) As Double
insPt(0) = 0: insPt(1) = 0: insPt(2) = 0
' Create an empty mtext object, this object will be used to get the max width
' of the text string in a column later
Set oMtext = ThisDrawing.ModelSpace.AddMText(insPt, 0, "")
oMtext.Visible = False
' Step through all entities in Model space
For Each acEnt In ThisDrawing.ModelSpace
' Check to see if the entity is a Table
If acEnt.ObjectName = "AcDbTable" Then
Set acTable = acEnt
acTable.RegenerateTableSuppressed = True
Dim dColWidth() As Double
ReDim dColWidth(acTable.Columns)
Dim nRow As Integer, nCol As Integer
nRow = 0
' Step through each row in the table
Do While acTable.Rows > nRow
nCol = 0
' Skip the first row, the header
If nRow > 0 Then
' Step through each column
Do While acTable.Columns > nCol
' Get the current column width
If dColWidth(nCol) = 0 Then dColWidth(nCol) = acTable.GetColumnWidth(nCol)
' Set the MText object based on the text in the cell
oMtext.TextString = acTable.GetTextString(nRow, nCol, 0)
oMtext.StyleName = acTable.GetTextStyle2(nRow, nCol, 0)
oMtext.Height = acTable.GetTextHeight2(nRow, nCol, 0)
' Calculate the width of the MText using its boundary box
Dim vMin, vMax As Variant
oMtext.GetBoundingBox vMin, vMax
' Make sure to include the Margins in the width for the new column
dMtextWidth = vMax(0) - vMin(0) + _
acTable.GetMargin(nRow, nCol, acCellMarginLeft) + _
acTable.GetMargin(nRow, nCol, acCellMarginRight)
' Is the width of the MText object greater than the current column width?
If dMtextWidth > dColWidth(nCol) Then dColWidth(nCol) = dMtextWidth
' If dMtextWidth > dColWidth(nCol) Then
' acTable.SetColumnWidth nCol, dMtextWidth * 1.05
' dColWidth(nCol) = dMtextWidth * 1.05
'
' ' Change to match original row height of 3
' acTable.SetRowHeight nRow, 3
' End If
nCol = nCol + 1
Loop
End If
nRow = nRow + 1
Loop
' Change the width of the columsn in the table
nCol = 0
Do While acTable.Columns > nCol
acTable.SetColumnWidth nCol, dColWidth(nCol)
nCol = nCol + 1
Loop
' Reset the height of the data rows that are not equal to 3
nRow = 2
Do While acTable.Rows > nRow
If acTable.GetRowHeight(nRow) <> 3 Then acTable.SetRowHeight nRow, 3
nRow = nRow + 1
Loop
' Recalculate the table
acTable.RecomputeTableBlock True
acTable.RegenerateTableSuppressed = False
End If
Next acEnt
' Remove the Mtext object created earlier for calculating the column width
oMtext.Delete
Set oMtext = Nothing
End Sub
Lee Ambrosius
Senior Principal Content Experience Designer
For additional help, check out the AutoCAD Developer Documentation
