Project Parameters - Delete All

[barr.jarryd]

Hey folks,

I'm trying to build a macro that will completely wipe the project parameters(user defined settings), and I cannot seem to get a list or foreach loop to detect the parameters.

This is what I have so far but I keep getting an error that it cannot be evaluated.

FOREACH par IN FOLDER($Project._keys) {

        EDIT USERPAR project SELECT $par

        DELETE USERPAR project SELECTED

}

Many thanks for anyone that may have some insight into this matter.

[Sean571]

You need to remove the folder() and then also put the command in a DOCOMMAND. It's annoying but it's the only way to get variables to work in this case

FOREACH par IN $project._keys { 
    string $cmd = "EDIT USERPAR project SELECT '" + $par + "'"
    DOCOMMAND $cmd     
    DELETE USERPAR project SELECTED 
}

[Sean571]

Shoot. This worked except it tries to delete more than what we want. Give me a sec and I'll come up with a solution

[barr.jarryd]

I got as far as doing this,

But $parameterName keeps giving me an error

FUNCTION Main() {

    INT parameterCount = 0 

    STRING parameterName = ""

    bool check = 1

    DIALOGS ERROR OFF

    WHILE $check == 1 {

        $parameterName = $project._keys[$parameterCount]

        EDIT USERPAR project SELECT $parameterName

        DELETE USERPAR project SELECTED

        $parameterCount = $parameterCount + 1

        $check = entity_exists($project._keys[$parameterCount])

    }

        MESSAGE INFO "All parameters deleted"

        DIALOGS ERROR ON

        MACRO ABORT ALL


}

[Sean571 · Accepted solution]

So there is actually a form that can lists all the project variables, and there are a few that we never want to delete. If you type in FORM PROJECTVARS in the command window you will see this dialog:

So it's not pretty but this works:

string list defaultProjectVars = {"A360", "Customer", "FusionProductionJob", "HoleTagCatalog", "Notes", "OrderNumber", "PartName", "Programmer", "ProjectHistory", "TextBlocks", "ThicknessSets", "Tolerances"}

FOREACH par IN $project._keys { 
   If NOT member(defaultProjectVars, par) {
      string $cmd = "EDIT USERPAR project SELECT '" + $par + "'"
      DOCOMMAND $cmd     
      DELETE USERPAR project SELECTED 
   }      
}

[barr.jarryd]

That worked awesome thank you!

I ended up with this by the end but yours is much better.

RESET LOCALVARS

    INT parameterCount = 0 

    STRING parameterName = ""

    STRING parameterCheck = ""

    STRING cmd = ""

    bool check = 0

    DIALOGS ERROR OFF

    WHILE $check == 0 {

        $parameterName = $project._keys[$parameterCount]

        $cmd = "EDIT USERPAR project SELECT " + "'" + $parameterName + "'"

        DOCOMMAND $cmd

        DELETE USERPAR project   SELECTED

        $parameterCount = $parameterCount + 1

        $parameterCheck = "$" + "project." + $parameterName

        $check = ERROR $parameterCheck

    }

        MESSAGE INFO "All parameters deleted"

        DIALOGS ERROR ON

        MACRO ABORT ALL

[danmic7JH66]

I've been looking for a solution myself to this exact problem. Thanks for sharing.