Create block frm external dwg file using .Net API freeze(hangs) the AutoCAD 2016

[Anonymous]

Hi All,

I have created function which creates block using external drawing file, I have used following code. It creates the block properly but after creating block in the current active document auto cad hangs.  

 Public Sub InsertDrawingAsBlock(doc As Document, path As String, blockname As String, ipt As Point3d, ByVal scalefator As Scale3d, ByVal rotation As Double, ByVal xmlAttribList As XmlNodeList)

        'current drawing database
        Dim currentdb As Database = doc.Database

        'current drawing's editor
        Dim editor As Editor = doc.Editor
        Dim lock As DocumentLock = doc.LockDocument()

        Dim strAttribTag As String
        Dim strAttribValue As String


        Using lock

            Dim blockid As ObjectId = ObjectId.Null

            ' create database to read dwg file
            Dim sourcedb As New Database(False, True)

            Using sourcedb

                sourcedb.ReadDwgFile(path, System.IO.FileShare.Read, True, "")

                blockid = currentdb.Insert(path, sourcedb, True)

                Using tr As Transaction = doc.TransactionManager.StartTransaction()
                    Dim bt As BlockTable = DirectCast(tr.GetObject(currentdb.BlockTableId, OpenMode.ForRead), BlockTable)


                    If bt.Has(blockname) Then
                        ' MessageBox.Show(string.Format("Block {0} does already exist\nTry another block or Exit", blockname));
                        Return
                    End If

                    bt.UpgradeOpen()

                    Dim btrec As BlockTableRecord = DirectCast(blockid.GetObject(OpenMode.ForRead), BlockTableRecord)
                    btrec.UpgradeOpen()

                    btrec.Name = blockname

                    btrec.DowngradeOpen()

                    '---> debug only
                    ' this code block is written in the good programming manner (remember that)
                    'For Each index As ObjectId In btrec
                    '    Dim en As Entity = DirectCast(index.GetObject(OpenMode.ForRead), Entity)

                    '    Dim adef As AttributeDefinition = TryCast(en, AttributeDefinition)

                    '    If adef IsNot Nothing Then
                    '        editor.WriteMessage(vbLf + adef.Tag)
                    '    End If
                    'Next
                    '<--- debug only

                    Dim btr As BlockTableRecord = DirectCast(currentdb.CurrentSpaceId.GetObject(OpenMode.ForWrite), BlockTableRecord)

                    Using btr
                        Using bref As New BlockReference(ipt, blockid)
                            Dim mat As Matrix3d = Matrix3d.Identity

                            bref.TransformBy(mat)

                            bref.ScaleFactors = scalefator
                            bref.Rotation = rotation
                            btr.AppendEntity(bref)

                            tr.AddNewlyCreatedDBObject(bref, True)

                            Using btAttRec As BlockTableRecord = DirectCast(bref.BlockTableRecord.GetObject(OpenMode.ForRead), BlockTableRecord)
                                Dim atcoll As Autodesk.AutoCAD.DatabaseServices.AttributeCollection = bref.AttributeCollection

                                For Each subid As ObjectId In btAttRec
                                    Dim ent As Entity = DirectCast(subid.GetObject(OpenMode.ForRead), Entity)
                                    Dim attDef As AttributeDefinition = TryCast(ent, AttributeDefinition)

                                    If attDef IsNot Nothing Then
                                        ' ed.WriteMessage("\nValue: " + attDef.TextString);
                                        Dim attRef As New AttributeReference()

                                        attRef.SetPropertiesFrom(attDef)

                                        attRef.Visible = attDef.Visible

                                        attRef.SetAttributeFromBlock(attDef, bref.BlockTransform)
                                        attRef.HorizontalMode = attDef.HorizontalMode

                                        attRef.VerticalMode = attDef.VerticalMode

                                        attRef.Rotation = attDef.Rotation

                                        attRef.TextStyleId = attDef.TextStyleId

                                        attRef.Position = attDef.Position + ipt.GetAsVector()
                                        attRef.Tag = attDef.Tag

                                        attRef.FieldLength = attDef.FieldLength


                                        If xmlAttribList IsNot Nothing Then
                                            For Each xmlAttrib In xmlAttribList
                                                strAttribTag = GetXMLAttribute(xmlAttrib, "tag")
                                                strAttribValue = GetXMLAttribute(xmlAttrib, "value")
                                                If attDef.Tag = strAttribTag Then
                                                    ' set the attribute text to to the correct string
                                                    attRef.TextString = strAttribValue

                                                End If
                                            Next xmlAttrib
                                        End If


                                        atcoll.AppendAttribute(attRef)

                                        tr.AddNewlyCreatedDBObject(attRef, True)

                                    End If

                                Next
                            End Using

                            bref.DowngradeOpen()
                        End Using
                    End Using

                    btrec.DowngradeOpen()

                    bt.DowngradeOpen()

                    'editor.Regen()
                    tr.TransactionManager.QueueForGraphicsFlush()
                    doc.TransactionManager.FlushGraphics()
                    tr.Commit()
                End Using
            End Using
        End Using
    End Sub

I have also executed the profiler and found that acad.exe takes more time. (Please find attached screenshot of the profiler) As per the profiler some "Malloc" funciton from ACGE20.dll (auto cad file) takes more CPU time for execution.  

[Norman_Yuan]

What value is passed to the argument "path" when this InsertDrawingAsBlock() method is called? A simple file name without path, like "xxxx.dwg", or a fully pathed file name, like "C:\My drawings\my blocks\xxxx.dwg"? In either case (unless the "path" and "blockname" arguments are given the SAME value, your code will not work as expected:

1. you code creates a block definition, named the same as the value of "path" parameter in this line of code:

blockId=currentdb.Insert(path, sourcedb, True)

In this case, the value of "path" could be invalid as block name (containing character "\", "."...). Oddly enough, AutoCAD still inserts the drawing as block definition and gives it a BLANK name.

2, Then your your code creates a block reference to the newly inserted block definition, and changes the block reference's name to the value of parameter "blockname", which effectively changes the blockrefernce's definition from the newly inserted definition to an pre-existing block definition named the same as the value of "blockname" parameter. As you can see, if the drawing does not have block definition with the name as the value of "blockname" parameter already existing, your code would fail to continue after you test 

If bt.Has(blockname) Then....

So, the correct code should be:

blockid = currentdb.Insert(blockname, sourcedb, True)

In this case, if the drawing has a block with the same name already, this line of code will redefine the block definition into the inserted drawing.

Also, you do not need to use so many levels of "Using...End Using" block inside a transaction. Any DB-residing DBObject opened inside a transaction will be disposed by the Transaction automatically. So the code would a lot easier to write/read, sothing like:

Dim blockid As ObjectId=ObjectId.Null

Using sourcedb

   sourceDb.ReadDwgFile(....)

   blockid=currentdb.Insert(blockname,sourcedb,true)

End Using

Using tran As Transaction = ....

 ...

 ...

  tran.Commit()

End Using

[Anonymous]

Thanks for reviewing the code, Drawing generation working fine. I am focusing to the performance and auto cad hang issue.

[Norman_Yuan · Accepted solution]

---

tejas.mer wrote:
...Drawing generation working fine. ...

---

Well, if the values of "path" and "blockname" parameters passed ti InsertDrawingAsBlock() method are different (they should be different, or you would not need 2 arguments for this method, right?), then "Drawing generating" would ONLY be "working fine" when the drawing has a block names as the value of "blockname" parameter. The block reference you see generated in the drawing IS NOT because of inserting a drawing file as block, which probably is not you really expected. You can try run your code against a new/blank drawing (e.g. no block definition already exists in that drawing).

So, if I were you, knowing the code does not do what I want to do, I'd fix that before worrying AutoCAD freezing. That is , CHANGE this line:

blockId=currentdb.Insert(path, sourcedb, True)

to this:

blockid = currentdb.Insert(blockname, sourcedb, True)

As for the AutoCAD freezing, does it happen when you run your faulty code the second time (or more than once)? If that is the case, then that is likely because of the line of code:

blockId=currentdb.Insert(path, sourcedb, True)

when the value of path is a file name with ".dwg" and/or with full path "c:\xxxx\xxxx\aaa.dwg". As I said, this kind of value is not VALID as block name, but AutoCAD somehow still take the inserted drawing as a block definition with blank name. But if you run that line of code again, AutoCAD would try to create another block definition with blank name, which would likely crash AutoCAD in some way, thus the freezing. However, I did not actually write code to try this, just a guess.

Anyway, using a file path/name in Database.Insert() is a big NO. As common convention, when inserting block from external file, the file name (without path and extension) would be used as the block name, so your code could be:

Dim blockid As ObjectId=ObjectId.Null

Dim blkName=System.IO.Path.GetFileNameWithoutExtension(path)

Using sourcedb

   sourceDb.ReadDwgFile(path,....)

   blockid=currentdb.Insert(blkName,sourcedb,true)

End Using

[Anonymous]

Hi Norman,

Thanks for updates.

Now I have reduced my code to just focus on the AutoCAD hang issue. Below is the updated code....

 Public Sub InsertDrawingAsBlock(doc As Document, path As String, blockname As String, ipt As Point3d, ByVal scalefator As Scale3d, ByVal rotation As Double)

        'current drawing database
        Dim currentdb As Database = doc.Database

        'current drawing's editor
        Dim editor As Editor = doc.Editor
        Dim lock As DocumentLock = doc.LockDocument()


        Using lock

            Dim blockid As ObjectId = ObjectId.Null

            ' create database to read dwg file
            Dim sourcedb As New Database(False, True)

            Using sourcedb
                sourcedb.ReadDwgFile(path, System.IO.FileShare.Read, True, "")
                blockid = currentdb.Insert(blockname, sourcedb, True)
            End Using
        End Using
    End Sub

In the above, Path is the complete path like "c:\xxxx\xxxx\aaa.dwg" and blockName is "aaa". After execution of above code autocad freezes for few seconds.

Can you please try this and let me know why autocad 2016 hangs?

Regards,

Tejas

[_gile · Accepted solution]

Hi,

Isn't this related to the file you insert ?
Did you notice the same problem with different files (size, location, ...) ?

I tried your code and it worked fine without any freezing.

By my side I use similar methods with AutoCAD 2007 to 2017 without having such problem.

[Anonymous]

Hi Gilles,

Yes, You are right it is related to specific drawing file for most of the drawing files it is working fine. I will share drawing file if possible. So that it will be helpful to find root cause.