How to change the rotation order xyz to zyx ,but have the same performance?

[Anonymous]

i change the rotate order xyz to zyx  the bone pos changed, but the transform attributes not changed.i just want to change the rotate order  and don't change the bone performance

[hamsterHamster]

It is likely that you need to resample the data for another rotation order. In short, what comes to mind, is to use HIK and define XYZ character, then have a characterized copy of the original character with ZYX order joints and use the former as a Source, then Bake skeleton.

If you plan to export it to FBX then there are some settings within the exporter which might reinterpolate those rotations from HIK Quaternion back to Euler.

[Anonymous]

thanks your reply; i fund a mel command [xform -p true -roo zxy;] to change the keyframe attribute; but i can't change rotate attribute in each frame.the rotate order attribute seems shared by all the bone animatin .only the select keyframe rotate changed. 

[hamsterHamster]

The command is the right one. I just wrote expression that runs through the timeline, unfortunately it doesn't update keyframes. I asked into Maya Programming, waiting for response.

[hamsterHamster · Accepted solution]

You see @Anonymous , wonders happen.

With that great help from @mcw0 the script works.

// resamples animation from one rotation order to another
string $sel[] = `ls -sl` ;

// save current rot order for every object in selection
int $roos[] ;
$i = 0 ;
for ( $s in $sel ) {
    $roos[$i] = `getAttr ($s+".rotateOrder")` ;
    $i++ ;
}

// resample keyframes within the playback range
$start = `playbackOptions -q -min` ;
$end = `playbackOptions -q -max` ;
print("Resampling range: "+ $start +" - "+ $end +"\n") ;
$axis = { "x", "y", "z"} ;
for ( $i = $start; $i <= $end; $i++ ) {
    currentTime -e $i ; 
    for ( $j = 0; $j < size($sel); $j++ ) {
        select -r $sel[$j] ;
        setAttr ($sel[$j]+".rotateOrder") $roos[$j] ;
        xform -p true -roo zxy $sel[$j];      // HERE YOU SET DESIRED ROT ORDER
        for ($a in $axis){
            $val = `getAttr ($sel[$j] +".r"+ $a)` ;
            setKeyframe -at (".r"+ $a) -v $val ;
        }
    }
}

 See entire discussion here.

And support the idea here.

[mcw0]

I don't know.  The original question was about maintaining "performance" and not "pose".  Changing the rotation order changes the performance because the interpolation between keyframes will be different.  The only solid solution is to bake the animation to the new rotation order.

[hamsterHamster]

My version of script does exactly that - it bakes every frame. Your example, as I understood, was a little different - it iterates through every existing keyframe.

At least, I resampled some xyz-mocaped rigs in my project and those look easier editable than before, even some gimbal locks seem to be gone, sufficient to offset just one shoulder curve to e.g. get rid of torso-arm penetration, whereas before I had to edit all three axis.

[mcw0]

My bad.  I didn't look that closely.  That's what I get for sneaking stuff in while at work.  LOL!!!

[Anonymous]

thanks for your script! it's solve my problem! Cheers.