Change Sketch Symbol by Ilogic

[yohansampaio]

Hello,

I have a question about whether it's possible to change the text within a sketch symbol that exists in an existing detail.

In this case, I have a sketch symbol called "PA" with the text "Perfil Alto" inside.

I need a rule that changes the text from Perfil Alto to High Profile.

However, within the sketch symbol, the text is inserted as the requested input. (Property field: "OBSERVATIONS", VALUE: "PERFIL ALTO").

Can anyone help me?

This code below is not working.

' Obter o documento de desenho atual
Dim oDrawDoc As DrawingDocument = ThisApplication.ActiveDocument
Dim oSheet As Sheet = oDrawDoc.Sheets(1)

' Percorrer todos os símbolos da folha
Dim oSymbol
For Each oSymbol In oSheet.SketchedSymbols
    If oSymbol.Definition.Name = "PA" Then
        ' Substitui o valor do prompt chamado "OBSERVAÇÕES"
        oSymbol.SetPromptResultText("OBSERVAÇÕES", "HIGH PROFILE")
    End If
Next

 

[Andrii_Humeniuk · Accepted solution]

Hi @yohansampaio .
To get and edit Property Field you need to use TextBoxes object. Below you can see an example of editing text according to your case.

' Obter o documento de desenho atual
Dim oDrawDoc As DrawingDocument = ThisApplication.ActiveDocument
Dim oSheet As Sheet = oDrawDoc.Sheets(1)

' Percorrer todos os símbolos da folha
For Each oSymbol As SketchedSymbol In oSheet.SketchedSymbols
    If oSymbol.Definition.Name = "PA" Then
        ' Substitui o valor do prompt chamado "OBSERVAÇÕES"	
		Dim oTextBoxes As TextBoxes = oSymbol.Definition.Sketch.TextBoxes
		For Each oTBox As Inventor.TextBox In oTextBoxes
			If Not oTBox.Text = "OBSERVAÇÕES" Then Continue For
			If oSymbol.GetResultText(oTBox) = "PERFIL ALTO" Then
				oSymbol.SetPromptResultText(oTBox, "HIGH PROFILE")
				Exit For
			End If
		Next
    End If
Next

[yohansampaio]

Thank you so much @Andrii_Humeniuk for your help.

It worked , and now I can adapt it to other situations.