Attach Balloon without right click menu ?

[Anonymous]

I prefer to use the "radial menu only" selection in the markings menu

Problem is, the only way I've been able to find to attach a stacked balloon is by using the right click context menu

I cannot find any way to attach a stacked balloon without turning on the right click context menu.

it doesn't appear to be an option to add to either the ribbon or the radial menu

any help would be appreciated

thanks!!

[clutsa]

I made a custom Sub in VBA and assigned that sub to the wheel. You can see if that works for you.

Sub AttachBalloon()
    Dim doc As DrawingDocument
    Set doc = ThisApplication.ActiveDocument
    doc.SelectSet.Select (ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingBalloonFilter, "Select a balloon to attach to."))
    ThisApplication.CommandManager.ControlDefinitions("DrawingAttachBalloonCtxCmd").Execute
End Sub

[Anonymous]

Clutsa, thank you for taking the time two write that up for me. I'm having a bit of trouble implementing it however.

I also noticed that my radial menu does not come up when I have a balloon selected, so that part may not work either. I may need to select the balloon and then select and run the ilogic from the ilogic toolbar

[clutsa · Accepted solution]

I wrote that code for VBA. We could certainly turn it into an external iLogic rule too but I threw a video together to show you how to add it to VBA as well.

[Anonymous]

Clusta,

Thank you for the video, that helped a ton. I was able to get the macro up and running and it works beautifully. however it only appears to work once or twice before inventor crashes.

not sure whats causing that

 

[clutsa]

I'm not having that problem... since you have a fairly repeatable problem I would fill out the crash report (e-mail and details). Autodesk has always been really great about getting back to me. 

You can try this code but I don't think that will really change anything.

Sub AttachBalloon()
    Dim app As Application
    Set app = ThisApplication
    Dim ComMan As CommandManager
    Set ComMan = app.CommandManager
    Dim doc As DrawingDocument
    Set doc = app.ActiveDocument
    doc.SelectSet.Select (ComMan.Pick(SelectionFilterEnum.kDrawingBalloonFilter, "Select a balloon to attach to."))
    ComMan.ControlDefinitions("DrawingAttachBalloonCtxCmd").Execute
    Set ComMan = Nothing
    Set doc = Nothing
    Set app = Nothing
End Sub

[Anonymous]

hmm still having the same problem with the new code.

I'll send the crash report to autodesk and see what they come back with.

but, in the meantime, with careful usage this macro is great. 

thank you for all of your time. 

[clutsa]

I did get an error (but not a crash) if I tried to escape out ILO picking a balloon... This seems to have fixed that.

Sub AttachBalloon()
    Dim app As Application
    Set app = ThisApplication
    Dim ComMan As CommandManager
    Set ComMan = app.CommandManager
    Dim doc As DrawingDocument
    Set doc = app.ActiveDocument
    Dim oBalloon As Variant
    Set oBalloon = ComMan.Pick(SelectionFilterEnum.kDrawingBalloonFilter, "Select a balloon to attach to.")
    If Not oBalloon Is Nothing Then
        doc.SelectSet.Clear
        doc.SelectSet.Select (oBalloon)
        ComMan.ControlDefinitions("DrawingAttachBalloonCtxCmd").Execute
    End If
End Sub