Selecting a named face with ilogic

[jake_pietrzak]

Hi Everyone, its been a while.

Recently I encountered a problem with my dxf exporter.

Can anyone help with selecting a named face in part or assembly with ilogic?

[jake_pietrzak]

To Give you more context, this a bit of code I found (thanks @ClintBrown3D)

Dim doc = ThisApplication.ActiveDocument
Dim entity = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kPartFaceFilter, "Select a Face to Export as DXF")

doc.SelectSet.Select(entity)

 But in here instead of typing the name of the face in part i need to click on it.

Does anyone has any idea how to pick face by name, not by clicking on it?

Thanks!

[FINET_Laurent · Accepted solution]

Hi,

Here is a quick code as an exemple :

Dim Doc As Inventor.Document = ThisApplication.ActiveDocument
Dim o As ObjectCollection = Doc.AttributeManager.FindObjects("*", "*", "Face2")

Dim obj As Object = o(1)

Dim f As Inventor.Face 
f = DirectCast(obj, Face)	

 Kind regards,

FINET L. 

[Curtis_Waguespack · Accepted solution]

Hi @jake_pietrzak 

Assuming you've assigned the face a name as shown, you can select the face by it's name using something like this example.

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

Dim oNamedEntities = iLogicVb.Automation.GetNamedEntities( ThisDoc.Document)
oFace = oNamedEntities.FindEntity("My Face")
ThisDoc.Document.SelectSet.Select(oFace)

[jake_pietrzak]

Thanks @Curtis_Waguespack  & @FINET_Laurent ,

This is very helpful and easy solution for my problem.

Exactly what I need.

Thanks again!

Ok, it works great, but I have another challenge for you 😉

Lets say I have Assembly called: Assembly 01 😉

In this assembly I have 3 parts called: Part 01, Part 02 & Part 03.

Parts: Part 01 & Part 02 have a face called: Face 01.

How can I  select Face 01 in each part from assembly level?

[Curtis_Waguespack · Accepted solution]

Hi @jake_pietrzak ,

Here is a quick example for selecting the named faces in parts ( if the named face exists) from an assembly.

Dim oDoc As AssemblyDocument = ThisDoc.Document
Dim oOcc As ComponentOccurrence
Dim oFaceProxy As FaceProxy
fname = "Face 01"

For Each oOcc In oDoc.ComponentDefinition.Occurrences
	Dim oNamedEntities = iLogicVb.Automation.GetNamedEntities(oOcc.Definition.Document)
	If oNamedEntities.NameExists(fname) = False Then Continue For
	oFace = oNamedEntities.FindEntity(fname)
	oOcc.CreateGeometryProxy(oFace, oFaceProxy)
	ThisDoc.Document.SelectSet.Select(oFaceProxy)
Next

 I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com