iLogic code to create a User Parameter
Hi @Biju.Veedu. I don't know why I didn't think about this earlier, but the FlatPattern object kind of acts like a ComponentDefinition object, because it is derived from it, so it has it's own separate set of parameters and user parameters. It's user parameters aren't even available to the main parent component definition, because they are at a deeper level. Here is an iLogic rule I threw together to help you write a series of entries into the flat pattern's own user parameters. I included several lines of comments to help guide you through what's going on. You will need to manually edit the parameter specs to the way you want them, after determining that the code works. I just specified 4 different types of user parameters for a somewhat dynamic test (simple numeric, equation, text, & boolean). Also, if you're not already aware, any plain numbers typed in iLogic, that represent measurements, will be understood as 'database' units (cm for length, radians for angle, etc), so you may have to either add them as an Expression, or include some math to convert its value to suit your needs.
Here's the rule:
iLogicVb.UpdateWhenDone = True
Parameter.UpdateAfterChange = True
MultiValue.UpdateAfterChange = True
Dim oPDoc As PartDocument = ThisDoc.Document
'only work with a Sheet Metal part
If Not TypeOf oPDoc.ComponentDefinition Is SheetMetalComponentDefinition Then Exit Sub
Dim oSMDef As SheetMetalComponentDefinition = oPDoc.ComponentDefinition
If Not oSMDef.HasFlatPattern Then Exit Sub
Dim oFP As FlatPattern = oSMDef.FlatPattern
Dim oUParams As UserParameters = oFP.Parameters.UserParameters
Dim oUParam As UserParameter
'create a List of Arrays of Object
'of Object Type, because the Array will include numbers, strings (text), boolean, and Enum Types
Dim oToBeCreated As New List(Of Object())
'in each Array we add to the main list, we will be entering the following items, in order
'(0) = specify if the value (below) should be understood as a plain value, or as an expression (involves an equation)
'(1) = the parameter's name
'(2) = the parameter's value or equation (if it's an equation, "enclose it within quotes")
'(3) = specify the units of the parameter
oToBeCreated.Add({"Expression", "Param_1", 25.75 in, UnitsTypeEnum.kInchLengthUnits})
oToBeCreated.Add({"Expression", "Equation_1", "Param_1 + 4.25 in", UnitsTypeEnum.kInchLengthUnits})
oToBeCreated.Add({"Value", "Text_1", "A Text Value", UnitsTypeEnum.kTextUnits})
oToBeCreated.Add({"Value", "Boolean_1", True, UnitsTypeEnum.kBooleanUnits})
'now try to either update or create these user parameters
'remember, an Array is zero (0) based, not 1 pased, so its first item is zero (0)
For Each oSpecs As Object() In oToBeCreated
Try
'try to find and update the value of the existing user parameter
If oSpecs(0) = "Value" Then
oUParams.Item(oSpecs(1)).Value = oSpecs(2)
ElseIf oSpecs(0) = "Expression" Then
oUParams.Item(oSpecs(1)).Expression = oSpecs(2)
End If
Catch
'that failed, so it doesn't exist yet, so create it
If oSpecs(0) = "Value" Then
oUParam = oUParams.AddByValue(oSpecs(1), oSpecs(2), oSpecs(3))
ElseIf oSpecs(0) = "Expression" Then
oUParam = oUParams.AddByExpression(oSpecs(1), oSpecs(2), oSpecs(3))
End If
End Try
Next
RuleParametersOutput
oPDoc.Update2(True) ' True = accept any errors and continueIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you want and have time, I would appreciate your Vote(s) for My IDEAS 💡or you can Explore My CONTRIBUTIONS
Wesley Crihfield
(Not an Autodesk Employee)
Hi @c.neutschK4ZB6. There is a one line iLogic snippet within the 'System' side of the Snippets in a folder called "Excel Data Links" which is labeled "MultiValue list from Excel". You might be able to use that to get a list of values from an Excel sheet to a multi-value user parameter in your drawing.
Here is what that snippet's code looks like:
MultiValue.List("d0") = GoExcel.CellValues("filename.xls", "Sheet1", "A2", "A10")
You would have to change the name of the Parameter being specified, and that parameter would have to already exist. Then you would have to fill in the real name of your Excel file (full path may be needed), sheet name, and cell addresses.
And if the parameter doesn't already exist, you could add a line of code above that to create the needed parameter like this.
ThisDrawing.Document.Parameters.UserParameters.AddByValue("ExcelValues", "", "Text")
MultiValue.List("ExcelValues") = GoExcel.CellValues("C:\Temp\Parameter Values.xlsx", "Sheet1", "A2", "A10")Notice that the parameter is created as a Text type parameter, because I am expecting text type values. If you are expecting different data type, such as numbers, you would need to change the value and units being specified at the end of the parameter creation line. There are lots of ways of doing that, but that's about the quickest & simplest.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @urban.ostirZ44XW. If I am fully understanding your request then I believe I have an iLogic rule that should be able to do a task like that for you. I also put a few messages in the code for feedback, but commented them out. Let me know if this works for you as you were wanting. See below code:
If ThisDoc.Document.DocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
MsgBox("An Assembly Document must be active for this rule to work. Exiting.", vbCritical, "")
Exit Sub
End If
Dim oADoc As AssemblyDocument = ThisDoc.Document
Dim oTotalArea As Double = oADoc.ComponentDefinition.MassProperties.Area
'MsgBox("Total Area in 'database units' = " & oTotalArea,,"")
oTotalArea = (oTotalArea * .5)
'MsgBox("Half of Total Area in 'database units' = " & oTotalArea,,"")
'<<< convert units here if needed >>>
UOM = oADoc.UnitsOfMeasure
oLengthUnitsStr = UOM.GetStringFromType(UnitsTypeEnum.kDefaultDisplayLengthUnits)
If UOM.LengthUnits <> UnitsTypeEnum.kDatabaseLengthUnits Then
oTotalArea = UOM.ConvertUnits(oTotalArea, "cm^2", oLengthUnitsStr & "^2")
End If
'MsgBox("Half of Total Area in 'document units' = " & oTotalArea,,"")
oUParams = oADoc.ComponentDefinition.Parameters.UserParameters
Dim oUParam As UserParameter = Nothing
For Each oUP As UserParameter In oUParams
If oUP.Name = "HALF_TOTAL_AREA" Then
oUParam = oUP
oUParam.Expression = oTotalArea.ToString
End If
Next
If IsNothing(oUParam) Then
oUParam = oUParams.AddByExpression("HALF_TOTAL_AREA", oTotalArea.ToString, oLengthUnitsStr & "^2")
End If
Wesley Crihfield
(Not an Autodesk Employee)
Hello everyone, thank you very much for these threads, they help me a lot at work and iLogic. I can't program but I manage to make small progress with code. Using the instructions from the thread, I was able to establish user parameters using a rule. But I can't figure out how to set the parameter as exported. Can you help me please? Thank you very much and greetings from the Czech Republic
oMyParameter=ThisApplication.ActiveDocument.ComponentDefinition.Parameters.UserParameters 'Setting an userParameter as text parameter oParameter=oMyParameter.AddByValue("Hmotnost", "", UnitsTypeEnum.kTextUnits) oParameter = oMyParameter.AddByValue("Povrch", "", UnitsTypeEnum.kTextUnits) iLogicVb.UpdateWhenDone = True
Hi @cubbanec. We were just given the ability to 'expose/export' UserParameter objects that represent 'text' or 'Boolean' units in the 2024 version o.... So, if you are using 2024, then you should be able to add another line of code after you create the parameter, just for setting its 'ExposedAsProperty' property to True. After you set that to True, you can then access its UserParameter.CustomPropertyFormat property, and all of its added functionality, which is similar to the settings you see when you right click on a parameter in the Parameters dialog box, after checking that box, and choose Custom Property Format from the right-click menu.
Dim oUParams As UserParameters = ThisApplication.ActiveDocument.ComponentDefinition.Parameters.UserParameters
'Setting an userParameter as text parameter
Dim oUParam1, oUParam2 As UserParameter
oUParam1 = oUParams.AddByValue("Hmotnost", "", UnitsTypeEnum.kTextUnits)
oUParam1.ExposedAsProperty = True
oUParam2 = oUParams.AddByValue("Povrch", "", UnitsTypeEnum.kTextUnits)
oUParam2.ExposedAsProperty = True
iLogicVb.UpdateWhenDone = TrueIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @n_lindner. In your code, Line 21 is specifying the initial value as an empty String (""), which should be a number like an unquoted 1.0, instead. Everything else looks OK to me.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @kwilson_design. The initial value you are specifying is within quotation marks. That will not work if the value is supposed to be interpreted as a Unitless value. When the value is in quotes, it is seen as a String (text). Remove the quotes.
Wesley Crihfield
(Not an Autodesk Employee)
Glad to see that you figured it out. Sorry, I did not realize you wanted to maintain the equation within the one Parameter. For some reason I just assumed you only needed the numerical value that resulted from that equation to be recorded. I do use the AddByExpression method the most myself, because it allows me to input values that I know will be interpreted the way I intend for them to be interpreted, instead of being automatically understood as 'database units'. I also usually use the Parameter.Expression (instead of Parameter.Value) when setting the value of a Parameter/UserParameter/ModelParameter type API objects for the same reasons, but that only works good for setting a specific numerical value when there is not already an equation there, and that can be difficult to detect since it always contains both numerical values and text (units indicator).
Wesley Crihfield
(Not an Autodesk Employee)