How to copy a part in an assembly using iLogic or API?
Hi @alewis. There are likely several paths that could be taken within the code to make this happen, but I chose a fairly straight forward, basic, and logical route. It doesn't attempt to do any thing further, like re-constrain the component or place it any specific orientation/position, just copy it, and place the copy back into the assembly. Within this process it needs to know the path & file name that you want to use for the 'new' document, so I simply choose to make the copy within the same directory/folder as the original, then just append "_copy" to the end of the file name. If you need to change that, it should be fairly easy, due to how I have laid all the data out within the code.
Here's the iLogic rule code I created for this task, that worked as planned when tested:
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
MsgBox("An Assembly Document must be active for this rule to work. Exiting.",vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument
Dim oADef As AssemblyComponentDefinition = oADoc.ComponentDefinition
'create variable to represent original component
Dim oOriginal As ComponentOccurrence
'set its value however you prefer
'oOriginal = oADef.Occurrences.ItemByName("MyComponent:1")
oOriginal = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kAssemblyOccurrenceFilter, "Select a component to copy.")
'now get the actual document / file it represents
Dim oOrigDoc As Document = oOriginal.Definition.Document
'get its full file name (path, name, & extension)
Dim oOrigFile As String = oOrigDoc.FullFileName
'<<< now specify the new path & file name for the new file (after copied) >>>
'capture 'path' of original
Dim oPath As String = System.IO.Path.GetDirectoryName(oOrigFile)
'capture file name only (without path or extension) of the original
Dim oOrigName As String = System.IO.Path.GetFileNameWithoutExtension(oOrigFile)
'capture extension of original
Dim oExt As String = System.IO.Path.GetExtension(oOrigFile)
'get 'local' directory seperator character (just in case it's different on your computer)
Dim oDirSep As Char = System.IO.Path.DirectorySeparatorChar
'now assemble the new path, name, & extension
Dim oCopiedFile As String = oPath & oDirSep & oOrigName & "_copy" & oExt
'now copy it
ThisApplication.FileManager.CopyFile(oOrigFile, oCopiedFile, FileManagementEnum.kCopyFileMask)
'now insert the copied document back into the assembly as a component
Dim oPosition As Matrix = ThisApplication.TransientGeometry.CreateMatrix
oADef.Occurrences.Add(oCopiedFile, oPosition)If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you want and have time, I would appreciate your Vote(s) for My IDEAS 💡or you can Explore My CONTRIBUTIONS
Wesley Crihfield
(Not an Autodesk Employee)
OK. So you were using the ItemByName() instead of the Pick method, that's just fine. Looking back over the code I posted above, I can see now that I left out an important step that might have prevented this behavior. There needed to be a step in there just before the CopyFile line, where it checks to see if that file already exists, before trying to save over it. Something like this:
If System.IO.File.Exists(oCopiedFile) Then
MsgBox("A file by that name already exists. Exiting rule.", vbCritical, "")
Exit Sub 'or Return
End IfOnce we add that step in, we still need to deal with the new challenge of making multiple copies of the same part, with each having a unique file name. To do this, we will either need to hard code a quantity number into the code, or prompt the user for a quantity. Maybe something like this:
Dim oQty As Integer = CInt(InputBox("Specify Quantity Of Copies To Make.", "QUANTITY","1"))(I put the InputBox within CInt() to change its return data Type from String to Integer.)
Then, we will need to work on a naming scheme, or plan for making each file name unique. What would you like to see happen with the file names instead of just appending "_copy" to the end? One fairly simple option might be to add a simple Integer to the end of the file name, then increment that number by 1 for each copy in the quantity.
This would be an example of this idea:
For oCopy As Integer = 1 To oQty
Dim oCopiedFile As String = oPath & oDirSep & oOrigName & oCopy & oExt
Try
ThisApplication.FileManager.CopyFile(oOrigFile, oCopiedFile, FileManagementEnum.kCopyFileMask)
Catch
MsgBox("Failed to copy file.", vbInformation, "")
End Try
Dim oPosition As Matrix = ThisApplication.TransientGeometry.CreateMatrix
oADef.Occurrences.Add(oCopiedFile, oPosition)
NextAlso, if you wanted we could capture the 'position/orientation' (Matrix) of the original component, before we copy it, then use that when we insert the copied versions of it, instead of placing them at the origin. The way to capture this would be like this:
Dim oPosition As Matrix = oOriginal.TransformationThen don't re-create that same variable again down below, because it has already been created and its value set here.
Does all this make sense to you?
Wesley Crihfield
(Not an Autodesk Employee)
