How to Add A Block Name to iProperties
@BeKirra
Hi, I think it would need to either be done manually, or possibly with some code. This post can be moved to the Inventor Programming forum if you would like.
Did you find a post helpful? Then feel free to give likes to these posts!
Did your question get successfully answered? Then just click on the 'Accept solution' button. Thanks and Enjoy!
Chris Benner
Community Manager - NAMER / D&M
@BeKirra
When you say selecting the block name, how do you envision this working? Selecting it from where?
Did you find a post helpful? Then feel free to give likes to these posts!
Did your question get successfully answered? Then just click on the 'Accept solution' button. Thanks and Enjoy!
Chris Benner
Community Manager - NAMER / D&M
Hahaha, it's a good point.
What I am trying to do is inserting the block name to view label in drawing file.
If block name can be available in iProperties then I will be able to insert it to view labels in drawing.
Here is what I mean.
Thanks.
@BeKirra Thank you for that!
I am going to move the post since I believe it will require some code for Inventor to dig the Block Name out of the sketch automatically (if it is even possible at all)... otherwise, I think the workflow you so beautifully drew up for me is possible... but very manual. Let's see what the programming gurus think.
Did you find a post helpful? Then feel free to give likes to these posts!
Did your question get successfully answered? Then just click on the 'Accept solution' button. Thanks and Enjoy!
Chris Benner
Community Manager - NAMER / D&M
Hi @BeKirra. Below is an example of an iLogic rule that you can run on the part. This rule will get the names of all sketch block definitions in the current part, present them to the user, to select one, then write the chosen name to the Description iProperty.
Sub Main
Dim oPDoc As PartDocument = TryCast(ThisDoc.Document, Inventor.PartDocument)
If oPDoc Is Nothing Then Return
Dim oSBDNames As New List(Of String)
For Each oSBD As SketchBlockDefinition In oPDoc.ComponentDefinition.SketchBlockDefinitions
oSBDNames.Add(oSBD.Name)
Next oSBD
Dim sChosenSBDName As String = InputListBox("Choose SketchBlockDefinition Name To Put In Description.", _
oSBDNames, oSBDNames(0), "SketchBlockDefinition Names", "List of SketchBlockDefinition Names")
If sChosenSBDName <> "" Then
'write the chosen name to the Description iProperty
oPDoc.PropertySets.Item(3).Item(14).Value = sChosenSBDName
End If
oPDoc.Update2(True)
End SubBelow is another rule that will iterate through every planar sketch in the current part, and iterate through every sketch block in each of those sketches, until it finds the first one, then it writes the name of that sketch block to the Description iProperty.
Sub Main
Dim oPDoc As PartDocument = TryCast(ThisDoc.Document, Inventor.PartDocument)
If oPDoc Is Nothing Then Return
Dim sSkBlkName As String = String.Empty
For Each oSk As PlanarSketch In oPDoc.ComponentDefinition.Sketches
For Each oSB As SketchBlock In oSk.SketchBlocks
sSkBlkName = oSB.Name
Exit For
Next oSB
If sSkBlkName <> String.Empty Then Exit For
Next oSk
If sSkBlkName <> String.Empty Then
'write it to the Description iProperty
oPDoc.PropertySets.Item(3).Item(14).Value = sSkBlkName
End If
oPDoc.Update2(True)
End SubThe stuff on the drawing side would then be up to you. Creating notes within drawings by code that include 'linked' pieces of information can be pretty complicated, because it involved 'formatted text', which includes XML tags.
If this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Thanks to @WCrihfield
😀
It looks possible to get the block name using a code.
However, I don't prefer using "Description" as it has usually been used for the part/assembly.
I wish to create a New Item under "Standard iProperties" or "Custom iProperties" (see snapshot below).
Can it be done?
Thanks again.
Hi @BeKirra. Sure, that detail can be changed. Below is another example iLogic rule, similar to my first example above, but instead of writing the chosen SketchBlock name to the Description property, it attempts to write it to a custom iProperty. We can not 'add' any new items to the 'standard' iProperties, but can add new properties to the custom ones. iProperties are stored within PropertySets. There are always at least 4 of these PropertySet objects within the PropertySets of every document. The first 3 sets are all standard, so we can not add or remove any properties from those sets, and can only change the values of some of them. The fourth set is always the custom one, but it usually is empty (does not contain any custom properties), until we either create some on purpose, or set some of our parameters to export, which automatically creates a custom iProperty for those parameters, with same name and value as the parameter. So, in order to write something to a custom iProperty, we must make sure the property object we want to write it to exists first. Sometimes that requires creating a new custom iProperty, if the one we want to write to does not already exist.
One of the most popular ways to handle that situation is to use a Try...Catch...End Try statement, which allows us to 'try' some code that we believe may sometimes cause an error (such as trying to access a named property that does not exist), while avoiding that error, and allows us to do something different when it does block the expected error (such as creating the custom property). That process could also be done differently (without using a Try...Catch statement), by iterating through all existing custom properties, and checking their names, to find the one we want first, if it exists. If found, set its value, but if not found, create it.
Sub Main
Dim oPDoc As PartDocument = TryCast(ThisDoc.Document, Inventor.PartDocument)
If oPDoc Is Nothing Then Return
Dim oSBDNames As New List(Of String)
For Each oSBD As SketchBlockDefinition In oPDoc.ComponentDefinition.SketchBlockDefinitions
oSBDNames.Add(oSBD.Name)
Next oSBD
Dim sChosenSBDName As String = InputListBox("Choose SketchBlockDefinition Name To Put In Description.", _
oSBDNames, oSBDNames(0), "SketchBlockDefinition Names", "List of SketchBlockDefinition Names")
If sChosenSBDName <> "" Then
'write the chosen name to a 'custom' iProperty
'to do that, we first need to make sure the custom iProperty exists, or create it
Dim oCProps As Inventor.PropertySet = oPDoc.PropertySets.Item(4) 'always the Custom one
Dim oCProp As Inventor.Property = Nothing
Dim sPropName As String = "SketchBlock Name"
Try 'try to find existing custom iProperty
oCProp = oCProps.Item(sPropName)
'if it was found, then set its value
oCProp.Value = sChosenSBDName
Catch 'getting the custom property failed, so create it, and set its value at same time
oCProp = oCProps.Add(sChosenSBDName, sPropName)
End Try
End If
oPDoc.Update2(True) 'update part, ignoring any errors
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @BeKirra. I am not sure I understand
I notice the code doesn't show all sketch block names if multiple blocks are added to custom iproperties.
Instead the last adding in block name is shown.
Can all block names be available and selectable
Are you saying that when you run this rule, you are not seeing the names of all the sketch blocks that are available in the part included in that list dialog, but are only seeing one name in that list dialog? Or are you saying that, after the rule has finished, you are only seeing one block name as the value of the single iProperty, but you were expecting multiple block names to be in that one custom iProperty's value? Unlike user UserParameter object, which has the UserParameter.ExpressionList property, for storing multiple possible values to choose from in a drop-down list, the Inventor.Property (iProperty) can only have one value, and does not have any way to store multiple possible values in a list. When we set the value of a property, its previous value is overwritten by the new value. If your intention is...if the custom iProperty already exists, and already has a value, then just add the current block name to the end of the existing value, instead of replacing its current value, then we would have to change how that part of the code works. There is also a way to force the list dialog to allow you to select multiple names at one time, but it is a bit complicated. And if done that way, then not only would the list presentation part of the code need to be changed, but there would also need to be additional changes made, such as adding a loop for iterating through each of the names that were selected in the list.
Or, are you wanting a new custom property, with a different name, to be created each time you run the rule, so that each of them contains a single sketch block name. If so, then how should each property be named, so that they are different from each other.
In order to add to a property's existing value, instead of replace its value, you would have to do something like:
oProperty.Value = oProperty.Value.ToString & sNextValueToAdd
...where 'oProperty' is a variable representing an existing custom Property, and 'sNextValueToAdd' represents the next piece of data that you would like to add to the property's existing value. Or, you could put multiple String type values together into a single String value, with commas, colons, or some other separator character between each of them.
Wesley Crihfield
(Not an Autodesk Employee)
OK. Below is a modified version of the previous code example. In this example, if the custom iProperty already exists, and is found, it will attempt to add the currently selected sketch block name to the end of the custom property's current value, with a comma and a space inserted between the existing value and the new sketch block name, instead of replacing the value of the custom iProperty.
Sub Main
Dim oPDoc As PartDocument = TryCast(ThisDoc.Document, Inventor.PartDocument)
If oPDoc Is Nothing Then Return
Dim oSBDNames As New List(Of String)
For Each oSBD As SketchBlockDefinition In oPDoc.ComponentDefinition.SketchBlockDefinitions
oSBDNames.Add(oSBD.Name)
Next oSBD
Dim sChosenSBDName As String = InputListBox("Choose SketchBlockDefinition Name To Put In Description.", _
oSBDNames, oSBDNames(0), "SketchBlockDefinition Names", "List of SketchBlockDefinition Names")
If sChosenSBDName = "" Then Return
'write the chosen name to a 'custom' iProperty
'to do that, we first need to make sure the custom iProperty exists, or create it
Dim oCProps As Inventor.PropertySet = oPDoc.PropertySets.Item(4) 'always the Custom one
Dim oCProp As Inventor.Property = Nothing
Dim sPropName As String = "SketchBlock Name"
'try to find existing custom iProperty, if it exists
Try : oCProp = oCProps.Item(sPropName) : Catch : End Try
'if existing was found, then 'add to' its value, instead of replacing its value
If oCProp IsNot Nothing Then
oCProp.Value = oCProp.Value.ToString & ", " & sChosenSBDName
Else 'it was not found, so try to create it
Try : oCProp = oCProps.Add(sChosenSBDName, sPropName) : Catch : End Try
End If
oPDoc.Update2(True) 'update part, ignoring any errors
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
HI @BeKirra. It seems like I am going to have to ask some of the same questions again that I asked in Message 13. I already mentioned that a custom iProperty can not have a multi-value list, like a UserParameter can. And I mentioned that the only way to put multiple values in one iProperty is to separate them by something like commas (or by a space, or some other character). I also asked if you wanted multiple custom iProperties...one for each sketch block name. And if so, how should each custom iProperty be named differently.
If you would like me to write/change code to do something for you, I need to know every tiny detail about what you want the code to do, because code needs to be extremely specific for it to work properly. If you want multiple custom iProperties to be created, then there will need to be a naming system integrated into the code, to generate a different name for each one. Not only that, but it will need to know how to find all the existing custom iProperties that are just for sketch block names, and not other stuff, because it will need to find all the existing ones each time, to know which name to use when assigning the 'next' name, so it is not attempting to overwrite an existing property's value.
I also mentioned in that same message, that there is a way to allow you to select multiple block names at once from the same list, instead of only being able to select one at a time. If we went that route, then the code would know the total number of block names it will be dealing with, and can simply iterate through that collection creating a new property for each of them in a loop. The property name could be the same as the sketch block name, or it could just get an incrementing index integer added onto the end of the name of each property. Just one possible option.
Wesley Crihfield
(Not an Autodesk Employee)
@WCrihfield wrote:I also mentioned in that same message, that there is a way to allow you to select multiple block names at once from the same list, instead of only being able to select one at a time. If we went that route, then the code would know the total number of block names it will be dealing with, and can simply iterate through that collection creating a new property for each of them in a loop. The property name could be the same as the sketch block name, or it could just get an incrementing index integer added onto the end of the name of each property. Just one possible option.
Hi @WCrihfield
1st of all, thanks for your help again. 😀
Sorry I didn't describe it clear. My bad.
My purpose is to insert the individual block name to drawing as mentioned earlier in the image in message #6.
BTW In the custom ipeoperties there may have already had other parameter names. The number of those items may be varied from time to time.
Hi @BeKirra. That response did not really answer all my questions, but I assume that since you quoted that part of my previous message, you want to try the multi-select list scenario. But since I still do not know how you want each custom iProperty to be named, I decided to show you an example of the 'base name with incrementing index' naming convention route. In this example, the 'base name' of every custom iProperty it creates/updates will be "SketchBlock". Then that will be followed by a space, and an integer, with the integer increasing in value for each selected name in the collection, as it iterates through them. In this example, I have replaced the iLogic 'InputListBox' function with my own tweaked version of it, which allows us to select multiple items at the same time. The selection mode can be changed from 'MultiSimple' to 'MultiExtended' (if you prefer using Ctrl / Shift / Arrows). It was originally set to 'One'.
Sub Main
Dim oPDoc As PartDocument = TryCast(ThisDoc.Document, Inventor.PartDocument)
If oPDoc Is Nothing Then Return
Dim oSBDNames As New List(Of String)
For Each oSBD As SketchBlockDefinition In oPDoc.ComponentDefinition.SketchBlockDefinitions
oSBDNames.Add(oSBD.Name)
Next oSBD
Dim oChosenNames As List(Of String) = UseListDialog("Choose SketchBlockDefinition Name To Put In Description.", _
oSBDNames, oSBDNames(0), "SketchBlockDefinition Names", "List of SketchBlockDefinition Names")
If oChosenNames Is Nothing OrElse oChosenNames.Count = 0 Then Return
Dim oCProps As Inventor.PropertySet = oPDoc.PropertySets.Item(4) 'always the Custom one
Dim sPropBaseName As String = "SketchBlock"
Dim iNum As Integer = 0
For Each sChosenName As String In oChosenNames
iNum += 1
Dim sNextPropName As String = sPropBaseName & " " & iNum.ToString
Dim oCProp As Inventor.Property = Nothing
Try : oCProp = oCProps.Item(sNextPropName) : Catch : End Try
If oCProp IsNot Nothing Then
oCProp.Value = sNextPropName
Else 'it was not found, so try to create it
Try : oCProp = oCProps.Add(sChosenName, sNextPropName) : Catch : End Try
End If
Next sChosenName
oPDoc.Update2(True)
End Sub
Function UseListDialog(Optional Instructions As String = Nothing, _
Optional Items As IEnumerable = Nothing, Optional DefaultValue As Object = Nothing, _
Optional Title As String = Nothing, Optional ListName As String = Nothing) As List(Of String)
Using oLD As New InputListBoxDialog(Title, ListName, Instructions, Items, DefaultValue)
Dim oLB As System.Windows.Forms.ListBox = oLD.Controls.Item(0).Controls.Item(2)
oLB.SelectionMode = System.Windows.Forms.SelectionMode.MultiSimple
Dim oDlgResult As System.Windows.Forms.DialogResult = oLD.ShowDialog()
Dim oSelected As List(Of String) = oLB.SelectedItems.Cast(Of String).ToList
Return oSelected
End Using
End FunctionIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @WCrihfield,
Yes, I missed your points.
Sorry I was too busy and not able to reply.
What I really need is the names of block.
I don't worry about the "value" of blocks.
It's be much appreciated if "SketchBlock 1", "SketchBlock 2" and so on can be replaced with block names.
Thanks again.
