Flat pattern to dxf with bend line

[kresh.bell]

I have ilogic for export flat pattern in dxf which is great for me, could anyone help me and edit it in such a way that it does not generate a tangent line but just a band line (ideally if only the band line were blue in color but that not necessary)

Dim oAsmDoc As AssemblyDocument

oAsmDoc = ThisApplication.ActiveDocument

oAsmName = Left(oAsmDoc.DisplayName, Len(oAsmDoc.DisplayName) -4)



'check that the active document is an assembly file
If ThisApplication.ActiveDocument.DocumentType <> kAssemblyDocumentObject Then

	MessageBox.Show("Please run this rule from the assembly file.", "iLogic")
	
	Exit Sub
	
End If

'get user input
RUsure = MessageBox.Show ( _
"This will create a DXF file for all of the asembly components that are sheet metal." _
& vbLf & "This rule expects that the part file is saved." _
& vbLf & " " _
& vbLf & "Are you sure you want to create DXF for all of the assembly components?" _
& vbLf & "This could take a while.", "iLogic  - Batch Output DXFs ",MessageBoxButtons.YesNo)

If RUsure = vbNo Then

	Return
	
	Else
	
End If

oPath = ThisDoc.Path

oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

oContext = ThisApplication.TransientObjects.CreateTranslationContext

oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism

oOptions = ThisApplication.TransientObjects.CreateNameValueMap

'get DXF target folder path
oFolder = oPath & "\" & oAsmName & " DXF Files"

'Check for the DXF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then

    System.IO.Directory.CreateDirectory(oFolder)
	
End If
'- - - - - - - - - - - - -

'- - - - - - - - - - - - -Component  - - - - - - - - - - - -
'look at the files referenced by the assembly
Dim oRefDocs As DocumentsEnumerator

oRefDocs = oAsmDoc.AllReferencedDocuments

Dim oRefDoc As Document


'work the the drawing files for the referenced models
'this expects that the model has been saved
		For Each oRefDoc In oRefDocs
			
			iptPathName = Left(oRefDoc.FullDocumentName, Len(oRefDoc.FullDocumentName) - 3) & "ipt"

    		'check that model is saved
			If(System.IO.File.Exists(iptPathName)) Then
			
                Dim oDrawDoc As PartDocument
				
                oDrawDoc = ThisApplication.Documents.Open(iptPathName, True)
				
            	oFileName = Left(oRefDoc.DisplayName, Len(oRefDoc.DisplayName))
				
				Try
				
                	'Set the DXF target file name
                	oDataMedium.FileName = oFolder & "\" & oFileName & ".dxf"
				
					Dim oCompDef As SheetMetalComponentDefinition
				
					oCompDef = oDrawDoc.ComponentDefinition
					
					If oCompDef.HasFlatPattern = False Then
					
						oCompDef.Unfold
						
					Else
					
   						oCompDef.FlatPattern.Edit
						
					End If

					Dim sOut As String
				
					sOut = "FLAT PATTERN DXF?AcadVersion=2004&OuterProfileLayer=IV_OUTER_PROFILE"

					
					oCompDef.DataIO.WriteDataToFile( sOut, oDataMedium.FileName)
				
					'just for check its works coretcly
					'i=MessageBox.Show(oDataMedium.FileName, "Title",MessageBoxButtons.OKCancel)
					
					'MessageBox.Show(i,"title",MessageBoxButtons.OK)
				
					'If i=2 Then
				
						'Exit Sub
				
					'End If

					oCompDef.FlatPattern.ExitEdit
				
				Catch
				
				End Try
                
				oDrawDoc.Close
				
			Else
					
			End If
			
		Next

[alewer · Accepted solution]

Is it OK for you to still have the tangent lines, but have them on an invisible layer? From the API helpfiles, I see no way (using DataIO.WriteDataToFile) to omit tangent lines from the .dxf, but you make the tangent layer (and tangent roll layer) invisible:

Argument	Type	Default Value	Note
TangentLayer	String	IV_TANGENT
OuterProfileLayer	String	IV_OUTER_PROFILE
ArcCentersLayer	String	IV_ARC_CENTERS
InteriorProfilesLayer	String	IV_INTERIOR_PROFILES
BendLayer	String	IV_BEND	BendUpLayer + BendDownLayer (legacy support)
BendUpLayer	String	IV_BEND
BendDownLayer	String	IV_BEND_DOWN
ToolCenterLayer	String	IV_TOOL_CENTER	ToolCenterUpLayer + ToolCenterDownLayer (legacy support)
ToolCenterUpLayer	String	IV_TOOL_CENTER
ToolCenterDownLayer	String	IV_TOOL_CENTER_DOWN
FeatureProfilesLayer	String	IV_FEATURE_PROFILES	FeatureProfilesUpLayer + FeatureProfilesDownLayer (legacy support)
FeatureProfilesUpLayer	String	IV_FEATURE_PROFILES
FeatureProfilesDownLayer	String	IV_FEATURE_PROFILES_DOWN
AltRepFrontLayer	String	IV_ALTREP_FRONT
AltRepBackLayer	String	IV_ALTREP_BACK
UnconsumedSketchesLayer	String	IV_UNCONSUMED_SKETCHES
TangentRollLinesLayer	String	IV_ROLL_TANGENT
RollLinesLayer	String	IV_ROLL
***Color	String		*** indicates name of layer from the argument column. RGB values separated by ;. Example: TangentLayerColor=255;0;0
***LineType	Long		*** indicates name of layer from the argument column. Long value from LineTypeEnum. Example: TangentLayerLineType=37644
***LineWeight	Double		*** indicates name of layer from the argument column. Value in centimeters. Example: TangentLayerLineWeight=.1016
CustomizeFilename	String
AcadVersion	String		2018, 2013, 2010, 2007, 2004, 2000, or R12 (for DXF only)
SimplifySplines	Boolean	True	Enable spline replacement by linear segments
SplineTolerance	Double	0.01	Chord tolerance for spline replacement
AdvancedLegacyExport	Boolean	True
MergeProfilesIntoPolyline	Boolean	False	Build a polyline of the exterior profiles
RebaseGeometry	Boolean	False	Move geometry to 1st quadrant
InvisibleLayers	String		List of layer names to make invisible, separated by ;

If moving tangent lines to an invisible layer is acceptable, replace this existing line of code:

sOut = "FLAT PATTERN DXF?AcadVersion=2004&OuterProfileLayer=IV_OUTER_PROFILE"

With this:

sOut = "FLAT PATTERN DXF?AcadVersion=2004&OuterProfileLayer=IV_OUTER_PROFILE&InvisibleLayers=IV_TANGENT;IV_ROLL_TANGENT"

If an invisible layer is not an acceptable solution, I recommend that you look into exporting flat pattern geometry to .dxf using the dxf TranslatorAddin. This allows you to control layers by .ini files, much like a "manual" (GUI) export to .dxf.