Extracting overall length/width of an irregular shape of a plate using iLogic
You're best off in the customisation forum.
https://forums.autodesk.com/t5/inventor-customization/bd-p/120
Inventor Certified Professional
Hi @eugene.morales .
Here is something that can do what you want pretty accurately. It takes advantage of the fairly new OrientedMinimumRangeBox property of the SurfaceBody object. Of course if you are dealing with a flat plate, and all you wanted was 2D surface specifications, you could just inspect the Face, or something like that.
Sub Main
Dim oPDoc As PartDocument = ThisDoc.Document
Dim oPDef As PartComponentDefinition = oPDoc.ComponentDefinition
Dim oOBox As OrientedBox = oPDef.SurfaceBodies.Item(1).OrientedMinimumRangeBox
Dim oDim1 As Double = ConvertDBToMM(oOBox.DirectionOne.Length)
Dim oDim2 As Double = ConvertDBToMM(oOBox.DirectionTwo.Length)
Dim oDim3 As Double = ConvertDBToMM(oOBox.DirectionThree.Length)
Dim oDims() As Double = {oDim1, oDim2, oDim3}
Dim oThickness As Double = MinOfMany(oDims)
Dim oLength As Double = MaxOfMany(oDims)
Dim oWidth As Double
'figure out which dim is left, or if two or more are equal
Dim oWidthIdentified As Boolean
For Each oDim In oDims
If oDim <> oThickness And oDim <> oLength Then
oWidth = oDim
oWidthIdentified = True
Exit For
ElseIf oDim = oLength And oDim = oThickness Then
'minimum dim and maximum dim are same, so middle dim will also be the same
oWidth = oLength
oWidthIdentified = True
End If
Next
If oWidthIdentified Then
MsgBox("Thickness = " & oThickness & vbCrLf & _
"Width = " & oWidth & vbCrLf & _
"Length = " & oLength, , "")
Else
MsgBox("Size = " & oDim1 & " x " & oDim2 & " x " & oDim3, , "")
End If
End Sub
Function ConvertDBToMM(oInputValue As Double) As Double
Return ThisApplication.UnitsOfMeasure.ConvertUnits(oInputValue, UnitsTypeEnum.kDatabaseLengthUnits, UnitsTypeEnum.kMillimeterLengthUnits)
End Function
If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you want and have time, I would appreciate your Vote(s) for My IDEAS 💡or you can Explore My CONTRIBUTIONS
Wesley Crihfield
(Not an Autodesk Employee)
This edit should either create or update a text type user parameter named "Material Size" with the result size information. You can change that parameter name if you want. You may also want to limit the decimal places of accuracy or round the results before writing them to the parameter, to suit your preference. If you only want width and length written to the parameter, it will usually do that. But when the width variable isn't established, it may fall back to writing all 3 values to the parameter. You could probably just add more checks in there to better determine which of the 3 are the middle value or if the width and length are the same, but different than the thickness.
Anyways, here's the updated iLogic code:
Sub Main
Dim oPDoc As PartDocument = ThisDoc.Document
Dim oPDef As PartComponentDefinition = oPDoc.ComponentDefinition
Dim oOBox As OrientedBox = oPDef.SurfaceBodies.Item(1).OrientedMinimumRangeBox
Dim oDim1 As Double = ConvertDBToMM(oOBox.DirectionOne.Length)
Dim oDim2 As Double = ConvertDBToMM(oOBox.DirectionTwo.Length)
Dim oDim3 As Double = ConvertDBToMM(oOBox.DirectionThree.Length)
Dim oDims() As Double = {oDim1, oDim2, oDim3}
Dim oThickness As Double = MinOfMany(oDims)
Dim oLength As Double = MaxOfMany(oDims)
Dim oWidth As Double
'figure out which dim is left, or if two or more are equal
Dim oWidthIdentified As Boolean
For Each oDim In oDims
If oDim <> oThickness And oDim <> oLength Then
oWidth = oDim
oWidthIdentified = True
Exit For
ElseIf oDim = oLength And oDim = oThickness Then
'minimum dim and maximum dim are same, so middle dim will also be the same
oWidth = oLength
oWidthIdentified = True
End If
Next
'write results to custom Parameter
Dim oUParams As UserParameters = oPDef.Parameters.UserParameters
Dim oUParam As UserParameter
'get or create the user parameter
Try
oUParam = oUParams.Item("Material Size")
Catch
'it wasn't found, so create it, and just give it an empty (space) answer for now
oUParam = oUParams.AddByValue("Material Size", " ", UnitsTypeEnum.kTextUnits)
End Try
If oWidthIdentified Then
oUParam.Value = oWidth & " x " & oLength
' MsgBox("Thickness = " & oThickness & vbCrLf & _
' "Width = " & oWidth & vbCrLf & _
' "Length = " & oLength, , "")
Else
oUParam.Value = oDim1 & " x " & oDim2 & " x " & oDim3
' MsgBox("Size = " & oDim1 & " x " & oDim2 & " x " & oDim3, , "")
End If
End Sub
Function ConvertDBToMM(oInputValue As Double) As Double
Return ThisApplication.UnitsOfMeasure.ConvertUnits(oInputValue, UnitsTypeEnum.kDatabaseLengthUnits, UnitsTypeEnum.kMillimeterLengthUnits)
End FunctionIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you want and have time, I would appreciate your Vote(s) for My IDEAS 💡or you can Explore My CONTRIBUTIONS
Wesley Crihfield
(Not an Autodesk Employee)
Hi
Remove the space in the User parameter of "Material Size"
There are two instances to change
Change it to "MaterialSize"
Thanks for catching that little detail@rhasell. That's the kind of stuff that happens when you get in too much of a hurry within multiple projects and skip retesting code after making changes.
Wesley Crihfield
(Not an Autodesk Employee)
