Balloon Locations
This should be possible. One question. Is the zone that's specified in the BOM, the zone where the balloon is located or the zone where the part is located? I assume the balloon, but just wanted to check.
Accepted solution
Take a look at this. It doesn't do the BOM portion of what you wanted but it does figure out all of the balloon information that you need.
http://modthemachine.typepad.com/my_weblog/2010/09/balloon-reporting-macro.html
Thanks for providing me some blog material. 🙂
You can use the Balloon.GetBalloonType method to determine this. For the standard balloon it will return kCircularWithOneEntryBalloonType as the type and for the split balloon you'll get kCircularWithTwoEntriesBalloonType.
Wow! I had totally forgotten I had written that. The easiest thing is your last suggestion. It just requires a slight edit to the existing program to write out the data into a csv file. Creating a new custom table wouldn't be very hard either but a bit more work. I can't remember all of the details of working with parts lists right now so I'm not sure adding it to the parts list will work but even if that is possible it would be the most work. Here's a quick edit to the existing program to write out a csv file. After making this change it would be best to have it create the tables so you can create a table per sheet. Right now this creates a single table for all sheets because all of the balloons for all sheets are being written into the file. It's most a matter of design and figuring out how the program should behave and then making it do that should be fairly easy.
Public Sub BalloonReport()
' Get the active drawing document.
Dim drawDoc As DrawingDocument
Set drawDoc = ThisApplication.ActiveDocument
' Open a file to write the results into.
Dim filename As String
filename = "C:\Temp\BalloonReport.csv"
Open filename For Output As #1
' Print out the header for the report, both to the
' output file and the immediate window in VBA.
Debug.Print "Sheet, Balloon Value, Sheet Position"
Print #1, "Sheet, Balloon Value, Sheet Position"
' Iterate through the sheets.
Dim drawSheet As Sheet
For Each drawSheet In drawDoc.Sheets
' Determine the zones within this sheet. This assumes that
' the border was created as a standard border where the
' zones are explicitly defined. If this is a custom border
' then some other mechanism will need to be created to
' define the zones.
Dim border As DefaultBorder
Set border = drawSheet.border
Dim XZoneWidth As Double
Dim YZoneWidth As Double
XZoneWidth = drawSheet.Width / border.HorizontalZoneCount
YZoneWidth = drawSheet.Height / border.VerticalZoneCount
Dim XZoneIsNumber As Boolean
If border.HorizontalZoneLabelMode = kBorderLabelModeNumeric Then
XZoneIsNumber = True
Else
XZoneIsNumber = False
End If
Dim YZoneIsNumber As Boolean
If border.VerticalZoneLabelMode = kBorderLabelModeNumeric Then
YZoneIsNumber = True
Else
YZoneIsNumber = False
End If
' Iterate through the balloons on this sheet.
Dim drawBalloon As Balloon
For Each drawBalloon In drawSheet.Balloons
' Because the border is numbered in the X direction from
' right to left and the sheet coordinate system is from
' left to right, this reverses the X coordinate so the
' zone computation will be correct.
Dim newXPosition As Double
newXPosition = drawSheet.Width - drawBalloon.Position.x
' Determine the X zone.
Dim XZone As Integer
XZone = Int(newXPosition / XZoneWidth)
' Get the X zone as a string.
Dim XZoneValue As String
If XZoneIsNumber Then
XZoneValue = XZone + 1
Else
XZoneValue = Chr(XZone + 65)
End If
' Determine Y zone.
Dim YZone As Integer
YZone = Int(drawBalloon.Position.y / YZoneWidth)
' Get the Y zone as a string.
Dim YZoneValue As String
If YZoneIsNumber Then
YZoneValue = YZone + 1
Else
YZoneValue = Chr(YZone + 65)
End If
' Iterate through each value set associated with this balloon.
Dim valueSet As BalloonValueSet
For Each valueSet In drawBalloon.BalloonValueSets
' Print out the results for this value set.
Debug.Print """"; drawSheet.name & """,""" & valueSet.value & """,""" & XZoneValue & ", " & YZoneValue & """"
Print #1, """"; drawSheet.name & """,""" & valueSet.value & """,""" & XZoneValue & ", " & YZoneValue & """"
Next
Next
Next
' Close the output file.
Close #1
MsgBox "Report written to: """ & filename & """"
End Sub