auto fit columns in parts list
That adjustment was too much for me, because it causes it squished some columns further than they are allowed, and caused the contents of some cells to wrap to a new row.
However, we are definitely on the right track.
I made one more tweak to the math in that line, and now the results seem as perfect as I've ever seen them, at least for my test application.
I changed that line to this:
oPList.PartsListColumns(oNext).Width = oWidths(i) + (oPList.DataTextStyle.FontSize * .5)after making this change, and running the code on my drawing, I zoomed in extremely close on my PartsList to inspect it. I can't manually move the column dividers ANY towards narrowing them further, and none of the rows contents were or titles were wrapped to new rows.
Ladies and gentlement...I think we have a winner here!
Wesley Crihfield
(Not an Autodesk Employee)
That adjustment was too much for me. It caused some of my columns to squish to narrow (further than you can manually narrow them), and caused some of the row's contents to wrap to new rows.
However we are definitely on the right track here.
I made another adjustment to the math in this line, that seems to work perfectly now.
I changed that line to this:
oPList.PartsListColumns(oNext).Width = oWidths(i) + (oPList.DataTextStyle.FontSize * .5)
After making this change in the code and running on my text drawing, I zoomed way in as far as I could on my PartsList, to inspect it. I couldn't manually drag the dividers between the columns ANY towards narrowing them, and none of the cell contents were wrapped to new rows.
Ladies and gentlement...I believe we have a winner here!
PS: Sorry it posted twice. When I posted the first time it said it errored out and I didn't see the post. Then two showed up.
Wesley Crihfield
(Not an Autodesk Employee)
In my test assembly drawing, I am using the following settings in my TextStyle:
(all numbers in these settings are in Inches)
And I am using the following PartsListStyle settings:
Then I manually adjusted all column widths to way wider than they needed to be, just for the test.
And here is the updated iLogic rule (based on @Lesoux c# code, kudos):
'Public Sub FitColumnsWidth(oPartsList As PartsList)
Sub Main
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kDrawingDocumentObject Then
MsgBox("A Drawing Document must be active for this rule (" & iLogicVb.RuleName & ") to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oDDoc As DrawingDocument = ThisDrawing.Document
Dim oTG As TransientGeometry = ThisApplication.TransientGeometry
For Each oSheet As Inventor.Sheet In oDDoc.Sheets
For Each oPList As PartsList In oSheet.PartsLists
Dim oPPoint As Point2d = oTG.CreatePoint2d(0,0)
Dim oTempGNote As Inventor.GeneralNote = oSheet.DrawingNotes.GeneralNotes.AddFitted(oPPoint, "", oPList.DataTextStyle)
Dim oColQty As Integer = oPList.PartsListColumns.Count
Dim oWidths(oColQty) As Double
Dim i As Integer
For i = 0 To oColQty - 1
Dim oNext As Integer = i + 1
oTempGNote.Text = oPList.PartsListColumns(oNext).Title
oWidths(i) = oTempGNote.FittedTextWidth
For Each oRow As PartsListRow In oPList.PartsListRows
If oRow.Visible Then
oTempGNote.Text = oRow(oNext).Value
If oTempGNote.FittedTextWidth > oWidths(i) Then
oWidths(i) = oTempGNote.FittedTextWidth
End If
End If
Next
oPList.PartsListColumns(oNext).Width = oWidths(i) + (oPList.DataTextStyle.FontSize * .5)
Next
oTempGNote.Delete()
Next
Next
End Sub
When I ran this rule, it seemed to work exactly as I wanted it to. It narrowed all of the PartsList columns, seemingly the maximum amount, without causing them to squish too narrow, and without causing the contents of any of the cells to wrap to new lines/rows. Even after zooming in as far as possible on the end of the column divider, and attempting to manually adjust that divider to narrow the column, it wouldn't go ANY narrower.
Then I tested manually narrowing one of my columns, so that some of the cell contents within wrapped to new rows, then ran the rule. It corrected the column width, so that the contents of that row no longer wrap to a new row, just as I was hoping for.
Now, this may not be an ideal solution for the situations where you need your content to wrap to new rows, in order to fit the PartsList within a certain available width, or need to maintain a maximum width. In that situation, you may need to either add some additional code which sets your limitations, then checks and adjusts the outcome accordingly, or you may need to use a different technique.
Wesley Crihfield
(Not an Autodesk Employee)
It looks like the code you posted is set-up to be a reference function, not the main/overall code. So the intent is to have a Sub Main...some other code, a call to this reference function, some more code...then End Sub, then this reference function would be its own block of code somewhere below End Sub. The call within the Sub Main...End Sub block of code would be calling this function below to run at that point.
If you want this code to act as a complete standalone rule, you would have to change a few things.
Replace this:
Public Function PartsListFitColumns(oPartsList As PartsList) As PartsListwith this:
Sub MainThen, since the old code was being provided with a PartsList as an input variable, we would now have to get the PartsList a different way. There are multiple ways to get a PartsList, so I'm just going to show one simple way as an example. Put this as the next line under your Sub Main, and before your "If oPartsList Is Nothing" check line.
Dim oPartsList As PartsList = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingPartsListFilter,"Select a Parts List.")Now at the end of the rule, delete the line "Return oPartsList", then simply replace "End Function" with "End Sub" (without the quotes).
That should convert your code to a standalone iLogic rule that should work by itself.
If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you have time, please... Vote For My IDEAS 💡or you can Explore My CONTRIBUTIONS
Inventor 2021 Help | Inventor Forum | Inventor Customization Forum | Inventor Ideas Forum
Wesley Crihfield
(Not an Autodesk Employee)
Not exactly on topic, but related, and useful.
Using the same techniques as I did for adjusting the columns widths of a PartsList earlier in this post, I have developed another iLogic rule to do the same thing for a RevisionTable. So this other rule will widen/narrow each column within all RevisionTables on all sheets of a drawing, to a width that best fits the contents of all cell in their column. It finds the longest text within the column, then sets the column width to match it, which also causes any rows which were wrapping to new lines to fit cell contents, to just use one line (and fix the row height to single row height).
Here is the link to that contribution post.
If this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Since I wanted a 1-click way to use this tool, I created a VBA macro out of it. I had to change the oWidths variable's type from an Array (which had it's size pre-set), to an ArrayList, because VBA didn't like using a variable to set the initial size of the Array, and I didn't want to deal with using ReDim. In order to use the ArrayList, I had to go to Tools > References, then Browse to set a reference to "mscorlib.dll" (C:\Windows\Microsoft.NET\Framework64\v4.0.30319\mscorlib.tlb") so VBA would recognize it.
This is the VBA macro version of the iLogic code I posted here back on 01-15-2021 07:31 AM.
Sub PartsList_AutoFitWidth()
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kDrawingDocumentObject Then
Call MsgBox("A Drawing Document must be active for this rule to work. Exiting.", vbOKOnly + vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oDDoc As DrawingDocument
Set oDDoc = ThisApplication.ActiveDocument
Dim oTG As TransientGeometry
Set oTG = ThisApplication.TransientGeometry
Dim oSheet As Inventor.Sheet
Dim oPList As PartsList
For Each oSheet In oDDoc.Sheets
For Each oPList In oSheet.PartsLists
Dim oPPoint As Point2d
Set oPPoint = oTG.CreatePoint2d(0, 0)
Dim oTempGNote As Inventor.GeneralNote
Set oTempGNote = oSheet.DrawingNotes.GeneralNotes.AddFitted(oPPoint, "", oPList.DataTextStyle)
Dim oColQty As Integer
oColQty = oPList.PartsListColumns.Count
Dim oWidths As New ArrayList
Dim i As Integer
For i = 0 To oColQty - 1
Dim oNext As Integer
oNext = i + 1
oTempGNote.Text = oPList.PartsListColumns(oNext).Title
Call oWidths.Insert(i, oTempGNote.FittedTextWidth)
Dim oRow As PartsListRow
For Each oRow In oPList.PartsListRows
If oRow.Visible Then
oTempGNote.Text = oRow(oNext).Value
If oTempGNote.FittedTextWidth > oWidths.Item(i) Then
oWidths.Item(i) = oTempGNote.FittedTextWidth
End If
End If
Next
oPList.PartsListColumns(oNext).Width = oWidths.Item(i) + (oPList.DataTextStyle.FontSize * 0.5)
Next
Call oTempGNote.Delete
Next
Next
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @WCrihfield, thank you for the code! I know this was a while ago, but the code here doesn't work well for me. You wouldn't know the reason? I tried your font settings too, with no success. Here's a snapshot of just after running the code, for an example:
Hi @emanuel.c. I am not 100% sure what may be causing that behavior, because I have been using that code ever since the date it was posted above without encountering that. After reviewing the code again just now, it looks like the only 'raw' numerical value involved is in line 28 of my iLogic version above, or line 36 of the VBA version above, where I am specifying the value '.5'. I'm wandering if there may be a Double data type tolerance/accuracy related issue going on there. Maybe that value needs to have a bunch of zero's after it to improve its accuracy. I believe the accuracy of the Double data type goes all the way down to the 15th decimal place, when there is only a zero to the left of the decimal point. But that is just a wild guess, without any testing to back it up. I know I have seen other ways of attaining super accurate text size before, that may work better than how it is being done here, but I don't recall where my notes/snippet are about that process. I think they included AddReference &/or Imports to other areas of the vb.net system, to use some other types of tools, like along the System.Drawing.Font direction. Following are some links to content on Microsoft's vb.net website that may point you in the right direction for now.
Wesley Crihfield
(Not an Autodesk Employee)
