Hi,
Bad news:
You are not able to redefine origin (base planes and axes).
You are not able to move existing body (without creating some transform features).
Good news:
You can copy existing body to the new position and hide the original body.
Then you can export STEP file with visible bodies only.
Here is code sample how to do it. It creates copy of selected body and sets the orientation. You can choose from three different implementations.
- Fixed (precalculated) transformation
- Transformation defined by active view
- Transformation defined by planar face (face normal defines z axis) and linear edge (edge direction defines x axis)
Source body becomes invisible.
Final body is not moved to first quadrant and origin can be everywhere. If it is important for you, you need to modify the code.
Sub main
Dim partDoc As PartDocument = ThisDoc.Document
'Select body for transformation
Dim srcBody As SurfaceBody = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kPartBodyFilter, "Select body")
'Setup transformation
'Select from following implementations
Dim t As Matrix
' t = GetTransformationFixed()
' t = GetTransformationFromActiveView()
t = GetTransformationFromPlaneAndEdge()
'Copy source body
Dim tgtBody = ThisApplication.TransientBRep.Copy(srcBody)
'Transform body to position
ThisApplication.TransientBRep.Transform(tgtBody, t)
Dim entities = ThisApplication.TransientObjects.CreateObjectCollection
entities.Add(tgtBody)
'Create NonParametricBaseFeatureDefinition
Dim baseFeatureDef As NonParametricBaseFeatureDefinition = partDoc.ComponentDefinition.Features.NonParametricBaseFeatures.CreateDefinition()
baseFeatureDef.BRepEntities = entities
baseFeatureDef.OutputType = BaseFeatureOutputTypeEnum.kSolidOutputType
'Create NonParametricBaseFeature
partDoc.ComponentDefinition.Features.NonParametricBaseFeatures.AddByDefinition(baseFeatureDef)
'Hide source body
srcBody.Visible = False
SetFinalCamera()
End Sub
Function GetTransformationFixed() As Matrix
'Setup body transformation
Dim tg = ThisApplication.TransientGeometry
Dim o As Point = tg.CreatePoint(1, 2, 3)
Dim x As Vector = tg.CreateVector(1, 1, 0)
x.Normalize()
Dim y As Vector = tg.CreateVector(-1, 1, 0)
y.Normalize()
Dim z As Vector = tg.CreateVector(0, 0, 1)
z.Normalize()
Dim t As Matrix = tg.CreateMatrix()
t.SetCoordinateSystem(o, x, y, z)
Return t
End Function
Function GetTransformationFromPlaneAndEdge() As Matrix
Dim face As Face = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kPartFacePlanarFilter, "Select top face")
Dim plane As Plane = face.Geometry
Dim n As UnitVector = plane.Normal
Dim edge As Edge = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kPartEdgeLinearFilter, "Select X edge")
Dim line As LineSegment = edge.Geometry
Dim d As UnitVector = line.Direction
Dim o = face.PointOnFace
Dim x = d.AsVector
Dim z = n.AsVector
Dim y = z.CrossProduct(x)
y.Normalize
Dim t As Matrix = ThisApplication.TransientGeometry.CreateMatrix()
t.SetCoordinateSystem(o, x, y, z)
t.Invert()
Return t
End Function
Function GetTransformationFromActiveView() As Matrix
Break
Dim cam As Camera = ThisDoc.Document.Views(1).Camera
Dim z = cam.Target.VectorTo(cam.Eye)
z.Normalize
Dim y = cam.UpVector.AsVector()
Dim x = y.CrossProduct(z)
x.Normalize
Dim o = cam.Target
o = ThisApplication.TransientGeometry.CreatePoint()
Dim t As Matrix = ThisApplication.TransientGeometry.CreateMatrix()
t.SetCoordinateSystem(o, x, y, z)
t.Invert
Return t
End Function
Sub SetFinalCamera
Dim cam As Camera = ThisDoc.Document.Views(1).Camera
Dim tg = ThisApplication.TransientGeometry
cam.Target = tg.CreatePoint(0, 0, 0)
cam.Eye = tg.CreatePoint(0, 0, 1)
cam.UpVector = tg.CreateUnitVector(0, 1, 0)
cam.ApplyWithoutTransition
End Sub
