Overriding Auto Scale in Title block
Hi JonathanESeiler,
I understand the use of scale callouts on the views for fabrication drawings with mixed scales on the same sheet. But I'm not sure I understand this request:
"Perhaps the rule could search every drawing view on a single sheet and write "Varies", or the prompted entry box could have a manual written value in the text box and avoid running the rule. "
I would think that you would want to look at each view on the drawing and leave the drawing label for each view to display the scale, but then if more than one scale is found in those views, the titleblock scale entry is changed to read "Varies.
Is that what you're thinking or am I missing something here?
Also, is the scale field in the titleblock really a prompted entry? Or is it a field that looks at a custom iProperty? ( Generally speaking, prompted entry should be avoided. )
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Hi JonathanESeiler,
Here is an iLogic rule to check each drawing view scale on the sheet and then update a custom iProperty to show the scale if all of the views are the same scale, or show "Varies" if they are not.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Dim odrawdoc As DrawingDocument
odrawdoc = ThisApplication.ActiveDocument
customPropertySet = odrawdoc.PropertySets.Item("Inventor User Defined Properties")
iLogicVb.UpdateWhenDone = True
Try
prop = customPropertySet.Item("Scale")
Catch
' catch error when not found and create the iproperty
customPropertySet.Add("", "Scale")
End Try
Dim oSheet As Sheet
Dim oViews As DrawingViews
Dim oView As DrawingView
Dim dScale As Double
Dim sScale As String
oSheet = odrawdoc.ActiveSheet
'get first view scale
dScale = oSheet.DrawingViews.Item(1).Scale
oViews = oSheet.DrawingViews
For Each oView In oViews
'MessageBox.Show(oView.Scale , "iLogic")
If dScale <> oView.Scale Then
sScale = "Varies"
Exit For
Else
sScale = oView.ScaleString
End If
Next
iProperties.Value("Custom", "Scale") = sScale
@Anonymous wrote:
You have perfectly understood what I was asking for.
We are still running inventor 2015, so the scale is a prompted entry field currently. We may be moving to 2017 at the end of the year but I am not holding my breath. Can you adjust the code to fit that scenario? As I am sure you have already run across, the link I supplied in my original post is the script I am currently running.
Hi JonathanESeiler,
I think I'll have to reverse my earlier thoughts on prompted entry for this. After working through this example, it later occurred to me that using a custom iProperty would update the title block on every sheet, which would not be desired for this. Using prompted entry to hold this scale would allow each sheet's title block to update independently.
I'll try to provide an updated example using prompted entry in the next couple of days.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Hi JonathanESeiler,
Here is the updated rule. I used much of what was found at the beinginventive link you provided, and just re-worked it as I stepped through so that I understood what was going on there., and didn't miss anything.
I tested it a bit, but post back if you run into issues.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Sub Main
'this rule expects a prompted entry
'in the title block with the value of: <Scale>
Dim oDrawdoc As DrawingDocument
oDrawdoc = ThisApplication.ActiveDocument
iLogicVb.UpdateWhenDone = True
Dim oSheet As Sheet
Dim oTitleBlock As TitleBlock
Dim oView As DrawingView
Dim dScale As Double
Dim sScale As String
Dim oScaleText As TextBox
Dim oScaleString As String
oScaleString = String.Empty
'get current sheet
curSheet = oDrawdoc.ActiveSheet
For Each oSheet In oDrawdoc.Sheets
'get first view scale
dScale = oSheet.DrawingViews.Item(1).Scale
'get the title block
oTitleBlock = oSheet.TitleBlock
If (oTitleBlock Is Nothing) Then Continue For
oScaleText = GetScaleTextBox(oTitleBlock.Definition)
If (oScaleText Is Nothing) Then Continue For
For Each oView In oSheet.DrawingViews
If dScale <> oView.Scale Then
oScaleString = "Varies"
Exit For
Else
oScaleString = oView.ScaleString
End If
Next
oTitleBlock.SetPromptResultText(oScaleText, oScaleString)
Next
'return to original sheet
curSheet.Activate
End Sub
Function GetScaleTextBox(ByVal titleDef As TitleBlockDefinition) As TextBox
For Each defText As TextBox In titleDef.Sketch.TextBoxes
If (defText.Text = "<Scale>" Or defText.Text = "Scale") Then
Return defText
End If
Next
Return Nothing
End Function
Hi JonathanESeiler ,
I think the error might be related to having a sheet with no views on it. I'll have a look at it and also make sure it handles the case "when triggering the rule again on a blank sheet, the scale noted remains "Varies" "
I'll try to post something back later today.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Accepted solution
JonathanESeiler wrote:However, when there is only one scale, it does not input the scale in the title block like the original code did.
Also, When triggering the rule again on a blank sheet, the scale noted remains "Varies"
Hi JonathanESeiler,
I tested for both of these conditions and fixed the error that occurred when no view was found on a sheet, but I could not replicate the case where the code did not input the scale in the title block when there is only one scale.
I might have been that a sheet with not views was causing the problem, and fixing that, fixed both issues, but let me know if this revised version still does not work as expected.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Sub Main
'this rule expects a prompted entry
'in the title block with the value of: <Scale>
Dim oDrawdoc As DrawingDocument
oDrawdoc = ThisApplication.ActiveDocument
iLogicVb.UpdateWhenDone = True
Dim oSheet As Sheet
Dim oTitleBlock As TitleBlock
Dim oView As DrawingView
Dim dScale As Double
Dim sScale As String
Dim oScaleText As TextBox
Dim oScaleString As String
oScaleString = String.Empty
'get current sheet
curSheet = oDrawdoc.ActiveSheet
For Each oSheet In oDrawdoc.Sheets
'get first view scale
Try
dScale = oSheet.DrawingViews.Item(1).Scale
Catch
End Try
'get the title block
oTitleBlock = oSheet.TitleBlock
If (oTitleBlock Is Nothing) Then Continue For
oScaleText = GetScaleTextBox(oTitleBlock.Definition)
If (oScaleText Is Nothing) Then Continue For
For Each oView In oSheet.DrawingViews
If dScale <> oView.Scale Then
oScaleString = "Varies"
Exit For
Else
oScaleString = oView.ScaleString
End If
Next
oTitleBlock.SetPromptResultText(oScaleText, oScaleString)
Next
'return to original sheet
curSheet.Activate
End Sub
Function GetScaleTextBox(ByVal titleDef As TitleBlockDefinition) As TextBox
For Each defText As TextBox In titleDef.Sketch.TextBoxes
If (defText.Text = "<Scale>" Or defText.Text = "Scale") Then
Return defText
End If
Next
Return Nothing
End Function
Edit:
I see you started a new separate thread. I 'll move my reply over there: