[IV 2014] - Export IGS depuis vue de dessin

[gmassart]

Bonjour

J'aimerai avoir un script VBA pour exporter un IGS à partir d'une vue sélectionnée.

Quelqu'un aurait un bout de code sous la main ? Je dois le personnalisé pour le nom du fichier exporté et aussi récupérer une ipropriété du fichier (son épaisseur)

D'avance merci pour votre aide (ThomasB44 tu es en premier ligne pour répondre 🐵 )

[ThomasB44]

Haha @gmassart

Donc si je résume le workflow :

1. Il faut récupérer la référence du modèle de la vue sélectionnée
2. Ouvrir cette référence
3. Construire le nom : Nom pièce + ipropriété ?
4. Enregistrer sous *.iges avec le bon nom
5. A l'emplacement du fichier modèle?
6. Fermer le modèle et revenir au dessin

Est ce que c'est bien ça que tu veux ?

[gmassart]

Oui c'est ça

A chaque fois qu'on fait une machine, on parcourt les plans pour exporter les tôles pliées en IGES (le fournisseur déplie lui même en fonction de sa machine)

Ca nous ferait gagner pas mal de temps, mais je dois récupérer le nom de la vue et l'épaisseur de la tôle pour le nom pour faire l'export.

Pour le chemin on a un chemin spécifique pour les exports relatif au projet donc ça je vais le gérer facilement.

[ThomasB44 · Accepted solution]

Salut @gmassart

Voici un premier essai rapide, il me manque des info pour ton épaisseur, mais tu verras déjà la base pour ton export

Pour l'export IGES, j'ai trouvé l'extrait de code sur le forum customisation, j'avais jamais utilisé avant...mais je pense que toutes les options de configuration sont là !

Le petit bonus, soit tu sélectionnes la vue et tu lances le code, soit tu sélectionnes pendant le code...j'adore

Ou est renseigné ton épaisseur ? Paramètre ? iPropriété ? iPropriété personnalisée ?

Si il s'agit uniquement de pièces de tolerie, c'est un paramètre, mais il faudra gérer les exceptions ?

If ThisApplication.ActiveDocument.DocumentType <> kDrawingDocumentObject Then
    MessageBox.Show("This is not a drawing" & vbNewLine & "End of rule...", "iLogic",MessageBoxButtons.OK,MessageBoxIcon.Error)
    Return
End If

If ThisApplication.ActiveDocument.SelectSet.Count = 0 Then
oView = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingViewFilter,"Select a view:")
Else
oView = ThisApplication.ActiveDocument.SelectSet(1)
End If

'Full path of referenced model
oModelFullFileName = oView.ReferencedDocumentDescriptor.ReferencedDocument.FullFileName
'Referenced model name
oModelName = oView.ReferencedDocumentDescriptor.ReferencedDocument.DisplayName
'Referenced model name without extension
oModelNameWE = Left(oModelName, Len(oModelName) - 4)

Dim Epaisseur As String
Epaisseur = iProperties.Value(oModelName, "Summary", "Title")

'Define document to open
oModelDoc = ThisApplication.Documents.Open(oModelFullFileName, True)
'set translator options
Dim oIGESTranslator As TranslatorAddIn
oIGESTranslator = ThisApplication.ApplicationAddIns.ItemById("{90AF7F44-0C01-11D5-8E83-0010B541CD80}")
Dim oContext As TranslationContext = ThisApplication.TransientObjects.CreateTranslationContext
oContext.Type = kFileBrowseIOMechanism
Dim oOptions As NameValueMap = ThisApplication.TransientObjects.CreateNameValueMap
Dim oDataMedium As DataMedium = ThisApplication.TransientObjects.CreateDataMedium
'Set export path
Dim IGESDir = "C:\Temp\"
oDataMedium.MediumType = kFileNameMedium
'Set export file name
oDataMedium.FileName = IGESDir & oModelNameWE & " " & oView.Name & " " & Epaisseur & ".igs"
If oIGESTranslator.HasSaveCopyAsOptions(oModelDoc, oContext, oOptions) Then
' Set geometry type for wireframe.
' 0 = Surfaces, 1 = Solids, 2 = Wireframe
oOptions.Value("GeometryType") = 1
' To set other translator values:
' oOptions.Value("SolidFaceType") = n
' 0 = NURBS, 1 = Analytic
' oOptions.Value("SurfaceType") = n
' 0 = 143(Bounded), 1 = 144(Trimmed)
'Use Export To IGES to save drawing configuration and set here
'Dim strIniFile As String = "C:\IGES\ConfigurationFile.ini"
' Create the name-value that specifies the ini file to use.
'oOptions.Value("Export_Acad_IniFile") = strIniFile
'Save File
Call oIGESTranslator.SaveCopyAs(oModelDoc, oContext, oOptions, oDataMedium)
End If
'Close referenced model
oModelDoc.Close

[gmassart]

Super merci je vais tester ça

L'épaisseur c'est celle des pièces de tôlerie, faut que je teste l'existence de la propriété avant de lancer l'export

Je vais rajouter dans mon "form" l'export automatique vers le répertoire par défaut ou par choix.

Je reviendrais avec le code complet

[ThomasB44]

Oui dans ce cas faut aller chercher le paramètre avec un try catch et un message et arret du code si le paramètre n'existe pas.

[gmassart]

Je travaille pas en ilogic, mais en VBA

J'ai du modifier le code pour être compatible avec le VBA (Je peux pas faire de Dim MaVariable = "toto", je suis obligé de Dim avant puis faire un Set)

[ThomasB44]

Oups, j'avais oublié que tu avais demandé en VBA...

Perso depuis qu'il y a iLogic, j'ai quasiment tout transféré la dessus...

Que donne ton code ? Ça fonctionne ?

[gmassart]

J'ai une partie du code qui fonctionne basé sur le tien pour la partie IGES.

Je récupère bien le nom de ma vue et l'épaisseur.

Je vais juste regarder maintenant pour les vues où j'ai un assemblage qui contient une tôle, pour forcer la sélection en pièce et donc demander à l'utilisateur de sélectionner la pièce

Dans le workflow ça sera > sélectionner la vue, contrôler si c'est une pièce seul ou pas, sinon passer en sélection pièce, sélectionner la pièce et continuer.

Ensuite j'attaque les DXF

Sélectionner la vue, ouvrir la pièce, forcez la sélection d'une face, demander l'épaisseur (idéalement faudrait que je trouve un truc du genre, sélectionnez une arrête qui représente l'épaisseur et prendre sa longueur) et ensuite export de la face en DXF

Je vais essayer de faire ça cette semaine, je reviendrais mettre le code complet ici.

[gmassart]

Juste pour ça j'ai créé cette fonction pour la gestion de l'épaisseur

Function GetThickness()
    Dim oPartDoc As PartDocument
    Set oPartDoc = ThisApplication.ActiveDocument
    ' Make sure the document is a sheet metal document.
    If oPartDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then
        Dim oSheetMetalCompDef As SheetMetalComponentDefinition
        Set oSheetMetalCompDef = oPartDoc.ComponentDefinition
        GetThickness = oSheetMetalCompDef.Thickness.ModelValue * 10 & "mm" 'L'unité de base est le cm... Logique Autodesk...
    Else
        Dim sThickness As String
        sThickness = InputBox("Veuillez entrer l'épaisseur de la tôle sans unité", "Epaisseur de la tôle")
        If sThickness <> "" Then
            GetThickness = sThickness
        Else
            MsgBox "Vous n'avez pas précisé d'épaisseur, la valeur est forcée à Xmm"
            GetThickness = "X"
        End If
    End If
End Function

[gmassart]

La fonction qui va bien pour exporter une face au format dxf avec sélection de face obligatoire

Function Export2DXF(sFileFullPath As String)
    Dim oFace As Face
    Set oFace = ThisApplication.CommandManager.Pick(kPartFaceFilter, "Sélectionnez une face :")
    If Not oFace Is Nothing Then
        ThisApplication.ActiveDocument.SelectSet.Select oFace
    Else
        MsgBox "Vous n'avez pas sélectionné de face. L'export est annulé", vbCritical, "Mauvaise sélection"
        Exit Function
    End If
    Dim Cm As CommandManager
    Set Cm = ThisApplication.CommandManager
    Call Cm.PostPrivateEvent(PrivateEventTypeEnum.kFileNameEvent, sFileFullPath)
    Dim oCtrlDef As ButtonDefinition
    Set oCtrlDef = ThisApplication.CommandManager.ControlDefinitions.Item("GeomToDXFCommand")
    Call oCtrlDef.Execute
End Function