Inventor 2024에서 부품의 작업 평면 가시화를 일괄 끌 수 있는 ilogic 소스가 있을까요?

[손광호]

Inventor2024에서 모델링 작업 시 가시성의 불편함이 있어 문의 드립니다.

인벤터 프로그램 자체를 컸다가 다시 켜고 다시 실행하면 항상 하기 객체 가시성의 뷰는 천체 체크됩니다,

조립품에서 객체 가시성의 원점 작업 평면을 끄면 작업 평면이 꺼진 상태에서 작업을 할 수 있습니다.

하지만 인벤터를 컸다가 디시 켜면 이 부분의 체크가 되어 다시 전체 작업 평면이 보입니다.

조립품에서 각 부품 별 작업평면을 많이 켜 놨기 때문에 일일히 각 부품에 들어가서 가시성 체크를 풀어 주어야 합니다.

  조립품에서 각 부품을 열지 않고 전체 부품의 작업 평면 가시성 체크를 풀고 저장할 수 있는 방법이 있을까요?

[nitealth]

ilogic까지 안쓰셔도

띄우신 화면에 보이는 뷰 패널의 '모든 작업피쳐' 기능에 단축키 하나 걸어넣고 껏다 켯다하면

말씀하신부분 해결되지 않으신지요? 

어셈블리상 하위 ipt까지 모두 적용됩니다.

단, 모델링 표현에서 잠금표시가 있는 1차로 사용하지 마시고,

기본값을 활성화 하시고 사용하시면 마지막 지정한 뷰 상태대로 저장이 됩니다.

[yd_kwon · Accepted solution]

부품 작업 평면 끄기 - 출처

이거에 다른 소스 합치면 평면이 꺼지긴 합니다.

주의 사항

- 링크된 원본 부품의 평면을 Off 하니 주의하세요. 저장할 때 부품 상태가 변경되었다고 뜹니다.

Sub Main
	If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
		MessageBox.Show("This Rule " & iLogicVb.RuleName & " only works on Assembly Files.", "WRONG DOCUMENT TYPE", MessageBoxButtons.OK, MessageBoxIcon.Error)
		Return
	End If
	
	Dim oAsmDoc As AssemblyDocument = ThisApplication.ActiveDocument
	Dim oRefDocs As DocumentsEnumerator = oAsmDoc.AllReferencedDocuments
	Dim invApp = ThisApplication	
	
	invApp.ScreenUpdating = False
	For Each oRefDoc As Document In oRefDocs
		'if is not a Part, skip to next referenced document
		If oRefDoc.DocumentType <> DocumentTypeEnum.kPartDocumentObject Then Continue For
		Dim cmpDef = oRefDoc.ComponentDefinition
		Dim repMgr = cmpDef.RepresentationsManager
		Dim initDVR = repMgr.ActiveDesignViewRepresentation
		'Dim txt =""
		If initDVR.DesignViewType <> DesignViewTypeEnum.kMasterDesignViewType Then repMgr.DesignViewRepresentations(1).Activate

		Try
			For Each wpl In cmpDef.WorkPlanes
				If (wpl.Name = "YZ 평면") or (wpl.Name = "XZ 평면") or (wpl.Name = "XY 평면")  Then 
					'txt += wpl.Name + vbCrLf 
					wpl.Visible = False
				End If
			Next
			If repMgr.ActiveDesignViewRepresentation.Name <> initDVR.Name Then repMgr.DesignViewRepresentations(initDVR.Name).Activate
			'MessageBox.Show(txt, "workplane")			
		Catch
			MessageBox.Show("Error processing " , "ilogic")
		End Try
	Next
	invApp.ScreenUpdating = True
	MessageBox.Show("Workplane Off")
End Sub

[손광호]

멋집니다...잘 작동되네요..~

원하는 내용으로~

좋은 소스 감사합니다.~