Why my model output as stl will become smaller 1/10?

[Anonymous]

Why my model output as stl will become smaller 1/10?

I set it as mm unit, I export it as stl for 3D printer, but it become 1/10 size as origin. What should I do?

[Macro.Liu_Autodesk]

Hi George,

Thank you for reporting this issue!

We looked into this issue while didn't reproduce it. Would you please share the files (can reproduce this issue) and the manipulations (any special setting when export to STL, in which method/software you found the difference) you've done? These are helpful for us to do research.

Thank you!

Macro Liu

Fusion QA

[Anonymous]

Hi,

I am design this model with 30mm base diameter and 50mm length.

printmodle01-V3

2

Export stl file as:

printmodle01-V3.stl (260.0KB)

printmodle01

 Fusion 360 Design

When I use netfabb studio to see stl file, it becime 3mm base diameter and 5mm length.

George

[Macro.Liu_Autodesk · Accepted solution]

Hi George,

Thank you very much for your update!

Even though we can't access to the hub you shared, we are still able to find out some clue. When you see this problem, I assume you export to STL via Dashboard.

If that's the case, could you please try to export to STL by right-clicking on the Body/Component node in Browser and choosing 'Save As STL'
? You don't need to change anything, but export with the default settings.

Please also keep the default unit (mm) in Fusion before exporting. Let us know if you can get the expected result.

We really appeciate your help!

Thanks,

Macro Liu

Fusion QA

[Anonymous]

Hi Macro,

I do it as you say, the stl dimension is correctly, through Dashboard it will shrink 1/10.

Regards

George

[Macro.Liu_Autodesk]

Hi George,

It's great to hear that you can get the correct STL by exporting via Browser (Save As STL). We'll share the Dashboard issue with the development team.

Thanks Again! And hope you have a good time with Fusion 360

Macro Liu

Fusion QA

[schneik-adsk · Accepted solution]

All, we understand and have confirmed that the dashboard export is off. We are working on a fix.

For now export from the browser will give you better control and correct size.

[Anonymous]

Garin tipped me to that when he visited me yesterday... I tried it last night and it CLEARLY works! 

Thanks for the FIX guys 🙂

[Anonymous]

Its good to find this issue! I was having the same issue with the same programs trying to accomplish the same thing (3d printing).

I did however export the item from inside the editor while right clicking the component.

But I run in inches.. so I'll just change to mm for now after i've finished designs.

Is it possible to get it looked at such that inches will be correctly exported too?

Mine are very definitely shrunk when pulling the STL into netfabb! or even straight into the object placement of the Repetier Host (similar program for manuevering and orienting 3d objects to prepare for prints).

[Anonymous]

though I must say it seems that netfab and this object placement import straight into MM at the exact inches decimal number that it's supposed to be...

That said, disregard there being an issue with fusion. I just had to go change the import settings of the other programs!

[JorisSteurs1246]

when using Ilogic to export to STL, the files becomes scaled 1/10

this is my line of code

ThisDoc.Document.SaveAs(ThisDoc.ChangeExtension(".stl"), True)

[ekinsb]

Since this is an Inventor question, I'll try and respond.

Using the SaveAs method is the same as using the Save Copy As command in the user interface, except you don't have access to the options and the translator will use some default settings. Often these will be the last settings used when the translator was run interactively but this doesn't appear to be the case with the STL translator.

The other option is to use the API to directly work with the STL translator.  Doing this you have full access to the various options.  Below is some sample VBA code that illustrates this.

Public Sub PublishSTL()
    ' Get the STL translator Add-In.
    Dim STLAddIn As TranslatorAddIn
    Set STLAddIn = ThisApplication.ApplicationAddIns.ItemById( _
                    "{81CA7D27-2DBE-4058-8188-9136F85FC859}")

    'Set a reference to the active document (the document to be published).
    Dim oDocument As Document
    Set oDocument = ThisApplication.ActiveDocument

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    oContext.Type = kFileBrowseIOMechanism

    ' Create a NameValueMap object
    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap

    ' Create a DataMedium object
    Dim oDataMedium As DataMedium
    Set oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

    ' Check whether the translator has 'SaveCopyAs' options
    If STLAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then
        ' Set various options in the name-value object.
        oOptions.Value("ExportUnits") = 4
        oOptions.Value("OutputFileType") = 1
        oOptions.Value("Resolution") = 0
    
        ' The various names and values for the settings is described below.
        'ExportUnits
        '     2 - Inch
        '     3 - Foot
        '     4 - Centimeter
        '     5 - Millimeter
        '     6 - Meter
        '     7 - Micron
        '
        'AllowMoveMeshNode (True Or False)
        '
        'ExportColor (True or False)  (Only used for Binary output file type)
        '
        'OutputFileType
        '     0 - Binary
        '     1 - ASCII
        'ExportFileStructure (Only used for assemblies)
        '     0 - One file
        '     1 - One file per instance.
        '
        'Resolution
        '     0 - High
        '     1 - Medium
        '     2 - Low
        '     3 - Custom
        '
        '*** The following are only used for “Custom” resolution
        '
        'SurfaceDeviation
        '     0 to 100 for a percentage between values computed
        '     based on the size of the model.
        'NormalDeviation
        '     0 to 40 to indicate values 1 to 41
        'MaxEdgeLength
        '     0 to 100 for a percentage between values computed
        '     based on the size of the model.
        'AspectRatio
        '     0 to 40 for values between 1.5 to 21.5 in 0.5 increments
    End If

    'Set the destination file name
    oDataMedium.filename = "c:\temp\test_cm.stl"

    'Publish document.
    Call STLAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)
End Sub

[bxliu]

Hi,

Just to update this post:

• 'Let' and 'Set' assignment statements are no longer supported as of Inventor 2016 - Just Remove them from the code
• You need to create a Main Sub and call on the export function

Here is the updated code. Cheers

Sub Main()
InventorVb.DocumentUpdate()
PublishSTL()
End Sub

Public Sub PublishSTL()
    ' Get the STL translator Add-In.
    Dim STLAddIn As TranslatorAddIn
    STLAddIn = ThisApplication.ApplicationAddIns.ItemById( _
                    "{81CA7D27-2DBE-4058-8188-9136F85FC859}")

    'Set a reference to the active document (the document to be published).
    Dim oDocument As Document
    oDocument = ThisApplication.ActiveDocument

    Dim oContext As TranslationContext
    oContext = ThisApplication.TransientObjects.CreateTranslationContext
    oContext.Type = kFileBrowseIOMechanism

    ' Create a NameValueMap object
    Dim oOptions As NameValueMap
    oOptions = ThisApplication.TransientObjects.CreateNameValueMap

    ' Create a DataMedium object
    Dim oDataMedium As DataMedium
    oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

    ' Check whether the translator has 'SaveCopyAs' options
    If STLAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then
        ' Set various options in the name-value object.
        oOptions.Value("ExportUnits") = 5
        oOptions.Value("OutputFileType") = 1
        oOptions.Value("Resolution") = 0
    
        ' The various names and values for the settings is described below.
        'ExportUnits
        '     2 - Inch
        '     3 - Foot
        '     4 - Centimeter
        '     5 - Millimeter
        '     6 - Meter
        '     7 - Micron
        '
        'AllowMoveMeshNode (True Or False)
        '
        'ExportColor (True or False)  (Only used for Binary output file type)
        '
        'OutputFileType
        '     0 - Binary
        '     1 - ASCII
        'ExportFileStructure (Only used for assemblies)
        '     0 - One file
        '     1 - One file per instance.
        '
        'Resolution
        '     0 - High
        '     1 - Medium
        '     2 - Low
        '     3 - Custom
        '
        '*** The following are only used for “Custom” resolution
        '
        'SurfaceDeviation
        '     0 to 100 for a percentage between values computed
        '     based on the size of the model.
        'NormalDeviation
        '     0 to 40 to indicate values 1 to 41
        'MaxEdgeLength
        '     0 to 100 for a percentage between values computed
        '     based on the size of the model.
        'AspectRatio
        '     0 to 40 for values between 1.5 to 21.5 in 0.5 increments
    End If

    'Set the destination file name (save on desktopn with current document name)
    oDataMedium.FileName = "C:\Users\username\Desktop\" & ThisDoc.FileName(False) & ".stl"

    'Publish document.
    Call STLAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)
End Sub

[gilcolaboradormultiorthos]

Hello,
Did someone give you the answer to this question?
could not understand where is the answer is there your initial question?

[gilcolaboradormultiorthos]

Can anyone help?
I made a DXF recording of a 2D drawing in millimeters.
The recording is made in fusion360 , example of a straight with 30 millimeters. When I open it in autocad, the drawing opens with 3 mm.
Does anyone know what the problem is?

[g-andresen]

Hi,

If you open the DXF of a Fusion drawing in an external application and dimension the elements there, you will get  the drawing length. In your case this is the object lenght multiplied by the  drawing scale (e.g. 1:10 =0,1).

This is an expected behavior.

günther

[gilcolaboradormultiorthos]

Thanks for the answer.
But it doesn't help when I send the drawing to another individual and he doesn't know about that detail. So how do I draw 53mm instead of 5.3mm on my fusion360?

[g-andresen]

Hi,

In addition to the dimensions, the drawing also includes the scale(s) used.
The manufacturer thus has all the information for production.
The drawing lengths are not important for the production, but they can be used to calculate the real length with the help of the scale.
However, this is a more than unusual method.
If a length of 53 mm is specified in the drawing, this length must be realized on the object.

günther

[gilcolaboradormultiorthos]

Thanks for the answer
I need a more concrete answer to my problem.
The problem is that the producer when opening the file in autocad is on the scale 1/10 (in unit of meters). It's strange that software from the same company is not 100 percent compatible. I draw in fusion in mm and should open in autocad in mm but it opens in a scale of 1/10 - example: 100mm corresponds to 10mm. How can I change this in my software because my producer cannot do this.