Help with CSV Cogo export script

[carl3ZPF6]

I am trying to edit a script that I have to also write the COGO custom property from below:

Here is my code. everything works except for the (setq bearing (vlax-get-property cogo 'Bearing)) line. Is there a way to export these custom properties in LISP?

(defun c:cogoExport ( / ss fileName f n)
  (setq ss (ssget '(( 0 . "AECC_COGO_POINT"))))
  (setq fileName (getfiled "Export to" "" "csv" 1))
  (if (and ss fileName)
    (progn
      (setq f (open fileName "w"))
	  
      (setq n 0)
	  (setq line "CAD Index, x, y, z, ," )
	  (write-line line f)
      (repeat (sslength ss)
	 
	(setq cogo (vlax-ename->vla-object (ssname ss n)))
	
	(setq line (cogo:pntToString cogo))
	(write-line line f)
	(setq n (+ n 1))
	)
      (close f)
      (princ (strcat "\nPoints have been exported. Quantity: " (itoa n)))
      )
    (princ "\nCommand Canceled.")
    )
  (princ)
  )

(defun cogo:pntToString (cogo / num northing easting elev rawDesc layer)
  (setq num (vlax-get-property cogo 'Number))
  (setq easting (rtos (vlax-get-property cogo 'Easting) 2 3))
  (setq northing (rtos (vlax-get-property cogo 'Northing) 2 3))
  (setq elev (rtos (vlax-get-property cogo 'Elevation) 2 3))
  (setq rawDesc (vlax-get-property cogo 'RawDescription))
  (setq layer (vlax-get-property cogo 'Layer))
  (setq bearing (vlax-get-property cogo 'Bearing))
  (strcat (itoa num) "," easting  "," northing "," elev "," rawDesc "," layer "," bearing)
  )

[tcorey]

'Bearing is not a property of a COGO Point. You might need to use an angle function to calculate the angle between points. What is it you're going for with Bearing?

[carl3ZPF6]

This is a custom property, I am looking for the text string that was assigned to the Bearing property in the image above, not rotation.

[Jeff_M]

@carl3ZPF6 is the Bearing property a UserDefinedProperty? Can you post a drawing with a few of these points in it?

[carl3ZPF6]

Yes user defined. See attached drawing.

[Jeff_M · Accepted solution]

Ok, 2 things need to be done. First, you must assign the Classification to a PointGroup the points are in...in this drawing's case, the "_All Points" group (note that older releases of C3D did not allow assigning the classification to this group). If the points are not in a group with the Classification set you will get an error.

Second, change the line to get the Bearing to this:

(setq bearing (vlax-invoke cogo 'getuserdefinedpropertyvalue "Bearing"))

Note that if you want to get other UDP values the UDPs are case sensitive. This fact has caused others much frustration in the past.

[carl3ZPF6]

Thank you Sir!