Not showing same updates\extensions\add-ins as before

[tatminglee]

After Autodesk Access is installed and Autodesk Desktop App is replaced, the same updates\extensions\add-ins that were shown on Autodesk Desktop App are not shown on Autodesk Access anymore but advising the product is up to date on some computer making the updates routine a nightmare...This is not right.

[lucdelrue]

I do install my own software, so I guess have admin rights, but no updates are showing. Via the website it works ( via products and services) but that slows everything down, taking a lot more time than before and so costing more money to my employer.....

What is wrong with quickly selecting some updates just before lunch break via the app and let it run? Why not simply providing an update tool, so you can let the whole thing work while you do something else. this would save a lot of money and time.

[danny.polkinhorn]

@lyaneff , Most of the items in your first screenshot are not updates, but extensions.  We are focusing first on the Update experience in Access and will add these in a different location in a later version of Access.  You can get these in Account by clicking on the product you want extensions for.

In the second screenshot, you are not logged in, so you'll need to do that to see your product updates.

[vandoren.david]

Is there any update to if/when updates can be installed without elevated (admin) rights?  Our IT department has our workstations locked down pretty hard and no one has anything more than basic user rights.  None of my users can install updates without requiring IT to grant temporary elevated privileges, a waste of their time and ours.  Already I'm hearing reports that most users arent updating because its too much of a pain or they dont have time to get IT involved, not until it breaks their workflow and they are forced.  

[Simon_Weel]

If users can't install updates (which IMO is a good thing), then the IT department has to do it.  We use the Windows Domain shutdown script to install updates. That script runs under the System account and so has permission to install software. 

[pendean]

@vandoren.david Autodesk will never EVER give a corporate user the sort of OS-override installs access that 95% of corporate IT departments strictly prohibit users from performing. Sorry.

Your issue needs to be resolved internally with you, your bosses and IT working hand-in-hand together to come to an agreement about software updates.

[vandoren.david]

@pendean I can understand your logic here, I'm just not sure the best way of dealing with it.  What is the expected update process?  I cant imagine an IT dept remote signing in to every workstation to open and run updates from the access app.  Then maybe scripts?  OK, IT pushes a script to the workstations, how is this script to be written?  Do we have to update and push a script for every new update?  What about users have a different autodesk product installed?  

[pendean]

@vandoren.david Your specific how-to questiona are for @Simon_Weel who discussed that.

In general there are two types of IT departments:
1) Nothing happens to any user PC or software after initial install or pre-scheduled intervals of update (if one exists) determined somehow somewhere with little regard to day-to-day operations of the business lines.

2) A proactive pro-business-line IT that regularly is in touch with leadership from all levels to advance the corporate agenda and goals. They know about and knowledgeably address versions, variants, departmental needs, user needs as approved by their managers and so much more. It is their sole focus outside of general IT tasks of protecting intellectual properties on the corporate networks.

Sorry if #1 is your situation.

[Simon_Weel]

---

I'm just not sure the best way of dealing with it.  What is the expected update process?  I cant imagine an IT dept remote signing in to every workstation to open and run updates from the access app.  Then maybe scripts?  OK, IT pushes a script to the workstations, how is this script to be written?  Do we have to update and push a script for every new update?  What about users have a different autodesk product installed?  

---

I wouldn't bother on how updates get installed - that's the IT-departments problem. I guess they use a method or tools like Intune or SCCM to roll out applications. The same method / tools can be used to roll out updates.

We are a small company and I happen to be the IT-department as well as a user. The way we install updates is, as said earlier, by using the Domains Shutdown script. That script is a simple cmd scipt with basic error checking, but it gets the job done - most of the time. You could do a much better job with Powershell, but I like the simplicity of cmd. Below is a piece of the Revit shutdown script (Dutch language) to install updates and apps for Revit 2022.

@Anonymous off
echo:
echo Shutdown script Revit

rem ********************************************************************************
rem ***                                                                          ***
rem *** Shortcuts voor verschillende commando's                                  ***
rem ***                                                                          ***
rem ********************************************************************************

set nircmd=<sharename>\ClientApps\Tools\NirSoft\nircmd.exe
set capps=<sharename>\ClientApps\
set pad_algemeen=<sharename>\ClientApps\Revit\
set appsbronpad=%capps%Autodesk\Revit_Apps\

goto hoofd

rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
rem = =                                                                   = =
rem = =              Sub Controle versienummer                            = =
rem = =                                                                   = =
rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =

:versieno

rem Routine met max. 3 argumenten:
rem		1 - UNC pad + bestandsnaam
rem 		2 - versienummer - wordt hieronder als 'regular expression' gebruikt om een exacte zoekopdracht te krijgen.
rem		3 - indien niet leeg EN versienummer klopt niet, dan melding sturen
rem Het versienummer is te vinden op de site van Autodesk of door het onderstaande commando uit te voeren:
rem wmic datafile where name='%doelpad:\=\\%%programma%' get version /format:list

if (%1)==() EXIT /B
set update=0
set temppad=%1
rem if not exist %temppad:\\=\% goto pad_fout
wmic datafile where name=%1 get version | findstr /R "\<%2\>" >nul
if not (%errorlevel%)==(0) set update=1
if not (%update%)==(0) (if not [%3]==[] (call "%capps%Scripts\e-mail.cmd" "[Probleem] Autodesk - Revit update %computername%" %3 "")) >nul
set temppad=
EXIT /B

:pad_fout
set temppad=%~1
call "%capps%Scripts\e-mail.cmd" "[Probleem] Autodesk - Revit update %computername%" "Het opgegeven pad is niet gevonden: %temppad:\\=\%" ""
set temppad=
EXIT /B

:hoofd

rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
rem = =                                                                   = =
rem = =      Testen of de pc opnieuw gestart moet worden                  = =
rem = =                                                                   = =
rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =

rem Als onderstaande registersleutels beide bestaan, dan moet de pc opnieuw worden gestart.
rem Installeren van updates lukt in die gevallen meestal niet.

set test=0
reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\RebootPending" >nul 2>nul
if (%errorlevel%)==(0) set /a test=+1
reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update\RebootRequired" >nul 2>nul
if (%errorlevel%)==(0) set /a test=+1

if %test%==2 goto sluiten

rem ********************************************************************************
rem ***                                                                          ***
rem *** Updates voor Revit installeren.                                          ***
rem ***                                                                          ***
rem ********************************************************************************

rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
rem = =                                                                   = =
rem = =              Revit 2022                                           = =
rem = =                                                                   = =
rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =

echo:
echo ---------------------------------------------------------------
echo Revit 2022

rem Paden t.b.v. updates instellen.
set bronpad=%capps%Autodesk\2022\Revit\Updates\
set doelpad=c:\program files\Autodesk\Revit 2022\
set programdatapad=%ProgramData%\Autodesk\RVT 2022\UserDataCache\
set programma=Revit.exe

if not exist "%bronpad%*.*" goto Revit_2022_einde
if not exist "%doelpad%*.*" goto Revit_2022_einde

:Revit_2022_Update_01

rem Controlebestand instellen.
set text=KB_Revit_2022_Revit_ini 29-09-2021.txt

rem De versie van Revit.ini in de Userdatacache wordt gebruikt als de gebruiker nog geen Revit.ini heeft.
rem Indien de Userdatacache-versie niet goed is, dan krijgt de gebruiker elke keer bij het starten van
rem Revit de melding "Default Family Template File Invalid"

if exist "%programdatapad%%text%" goto Revit_2022_Update_02

echo %text% > "%programdatapad%%text%"

xcopy "%bronpad%revit.ini" "%programdatapad%" /r /y >>"%programdatapad%%text%"

:Revit_2022_Update_02

rem Controleren of het versienummer klopt, zoniet, dan update uitvoeren.
rem Klopt het versienummer daarna nog niet, dan een bericht sturen.

set versie="22.1.40.58"
set updateno=1.4

call :versieno "%doelpad:\=\\%%programma%" %versie%
if not (%update%)==(1) goto Revit_2022_Update_03

echo Installatie Update %updateno%...

rem Het pad naar de installatie directory in het register klopt niet. Recht zetten met dit reg bestand.
reg import "%bronpad%Revit 2022.reg"
Start "" /B /wait "%bronpad%Revit_2022_1_4.exe" -q

call :versieno "%doelpad:\=\\%%programma%" %versie% "[Probleem] Autodesk - Revit 2022 update %updateno% - versienummer %versie:"=% komt niet overeen."

:Revit_2022_Update_03

rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
rem Revit 2022 apps
rem = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =

echo:
echo ---------------------------------------------------------------
echo Revit 2022 apps

rem Paden t.b.v. apps instellen.
set bronpad=%capps%Autodesk\2022\Revit\Apps\
set doelpad=%ProgramData%\Autodesk\Revit\Addins\2022\

:Revit_2022_Apps_01

rem Controlebestand t.b.v. Installatie BCF Manager
set text=KB_Revit_2022_App_BCF Manager 5.5 build 83 RVT2022_13-04-2022.txt
if exist "%doelpad%%text%" goto Revit_2022_Apps_02
echo Installeren BCFManager 5.5
"%bronpad%BCF Manager 5.5 build 83 RVT2022.exe" /exenoui /quiet

echo %text% > "%doelpad%%text%"
 
:Revit_2022_Apps_02
 
rem IFC Exporter
set doelpad=%ProgramData%\Autodesk\ApplicationPlugins\IFC 2022.bundle\Contents\2022\
set programma=Revit.IFC.Export.dll
set versie="22.6.2.0"

rem Controleren of het versienummer klopt, zoniet, dan update uitvoeren.
rem Klopt het versienummer daarna nog niet, dan een bericht sturen.
call :versieno "%doelpad:\=\\%%programma%" %versie%
if not (%update%)==(1) goto Revit_2022_Apps_03

echo Installeren IFCExporter %versie:"=%
"%bronpad%IFC.for.Revit.2022.6.2.0.msi" /passive

call :versieno "%doelpad:\=\\%%programma%" %versie% "[Probleem] Autodesk - IFCExporter 2022 - versienummer %versie:"=% komt niet overeen."

:Revit_2022_Apps_03
 
:Revit_2022_einde

:Revit_2022_Snelkoppellingen

if exist "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Autodesk\Revit 2022\*" rd /s /q "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Autodesk\Revit 2022"

[mmermel]

The CAD team want the access and ability to install software.  The IT team is looking after the security of the system, which, which may preclude giving the CAD users admin rights. Security trumps wishes.

[pendean]

---

@mmermel wrote:

The CAD team want the access and ability to install software.  The IT team is looking after the security of the system, which, which may preclude giving the CAD users admin rights. Security trumps wishes.

---

The latest version of ACCESS has more "cad manager" controls that may or may not help with your wishlist: you'll have to update ACCESS fist though (I know, catch 22 huh).