Hello
+1 avec Gilles
Ce que j'ai compris : Desires tu une detection des Intersections entre les "Bounding Box" (Rectangles englobants) de tous les Blocs de la selection classique AutoCAD avec Insertion automatique d'un nouveau Bloc specifique au centre (Centroid des N Bounding Box en Intersections) !?
Ce nouveau Bloc dispose d'un attribut qui va s'incrementer automatiquement ...
Apres on traite en Manuel (si necessaire) ... en voyant OU sont ces nouveaux Blocs "de detection" ...
Regards, Patrice
Patrice ( Supporting Troops ) - Autodesk Expert Elite
If you are happy with my answer please mark "Accept as Solution" and if very happy please give me a Kudos (Felicitations) - Thanks
If you are happy with my answer please mark "Accept as Solution" and if very happy please give me a Kudos (Felicitations) - Thanks
Patrice BRAUD
Salut,
La problématique dépasse le niveau débutant en LISP, ne serait-ce que pour récupérer les coordonnées de la ligne contenue dan le bloc.
Comme je trouvais le problème rigolo, j'ai essayé de faire un truc.
Le LISP fonctionne avec un bloc nommé "INTERS" qui a un attribut. Tu peux utiliser le dwg attaché. Tu peux aussi te faire ton propre bloc et au besoin renommer le bloc cans le LISP.
(defun c:BLKINTERS (/ ss n blk line vert horiz dia req echo pt)
(if (setq ss (ssget "_X" '((0 . "INSERT") (2 . "`*U*,bande_6inchs_centered") (410 . "Model"))))
(progn
(repeat (setq n (sslength ss))
(setq blk (ssname ss (setq n (1- n))))
(if (= (getpropertyvalue (getpropertyvalue blk "BlockTableRecord") "Name")
"bande_6inchs_centered"
)
(progn
(setq line (list (getpropertyvalue blk "Position")
(polar (getpropertyvalue blk "Position")
(- (getpropertyvalue blk "Rotation") (* pi 0.5))
(getpropertyvalue blk "AcDbDynBlockPropertyDistance1")
)
)
)
(if (equal (caar line) (caadr line) 1e-8)
(setq horiz (cons line horiz))
(setq vert (cons line vert))
)
)
)
)
)
(setq ih 64
iv 0
horiz (mapcar '(lambda (l) (cons (chr (setq ih (1+ ih))) l))
(vl-sort horiz '(lambda (p1 p2) (< (caar p1) (caar p2))))
)
vert (mapcar '(lambda (l) (cons (itoa (setq iv (1+ iv))) l))
(vl-sort vert '(lambda (p1 p2) (> (cadar p1) (cadar p2))))
)
dia (getvar 'attdia)
req (getvar 'attreq)
echo (getvar 'cmdecho)
)
(setvar 'attdia 0)
(setvar 'attreq 1)
(setvar 'cmdecho 0)
(vl-catch-all-apply
'(lambda ()
(command "_.undo" "_begin")
(foreach h horiz
(foreach v vert
(if (setq pt (inters (cadr h) (caddr h) (cadr v) (caddr v) T))
(command "_.insert" "inters" pt 1.0 1.0 0.0 (strcat (car h) (car v))) ; changer le nom du bloc
)
)
)
)
)
(command "_.undo" "_end")
(setvar 'attdia dia)
(setvar 'attreq req)
(setvar 'cmdecho echo)
)
(princ)
)
Le LISP ci dessus présente des dysfonctionnements dans l'affecttion des indices de colonne et rangée.
Utilise celui-ci qui comporte aussi quelques optimisations et des commentaires
(defun c:BLKINTERS (/ *error* dia req echo os ss n blk line vert horiz ih iv hy vx pt)
;; substitution locale de la fonction *error*
(defun *error* (msg)
(and msg
(/= msg "Fonction annulée")
(princ (strcat "erreur: " msg))
)
(command-s "_.undo" "_end")
;; restauration des valeurs initiales
(setvar 'attdia dia)
(setvar 'attreq req)
(setvar 'osmode os)
(setvar 'cmdecho echo)
(princ)
)
;; valeurs initiales des variables système
(setq dia (getvar 'attdia)
req (getvar 'attreq)
echo (getvar 'cmdecho)
os (getvar 'osmode)
)
;; sélection des blocs "bande_6inchs_centered" et des blocs anonymes
(if (setq ss (ssget "_X" '((0 . "INSERT") (2 . "`*U*,bande_6inchs_centered") (410 . "Model"))))
(progn
;; traitement de la sélection
(repeat (setq n (sslength ss))
(setq blk (ssname ss (setq n (1- n))))
;; contrôle du nom du bloc (blocs anonymes)
(if (= (getpropertyvalue (getpropertyvalue blk "BlockTableRecord") "Name")
"bande_6inchs_centered"
)
(progn
;; constitution d'une liste avec les points de départ et de fin de la ligne
(setq line (list (getpropertyvalue blk "Position")
(polar (getpropertyvalue blk "Position")
(- (getpropertyvalue blk "Rotation") (* pi 0.5))
(getpropertyvalue blk "AcDbDynBlockPropertyDistance1")
)
)
)
;; ajout de la sous-liste à la liste des lignes horizontales ou verticales
(if (equal (caar line) (caadr line) 1e-6)
(setq vert (cons line vert))
(setq horiz (cons line horiz))
)
)
)
)
;; tri de la liste des lignes horizontales par Y décroissant
;; et de la liste des lignes vetrticales par X croissant
(setq horiz (vl-sort horiz '(lambda (p1 p2) (> (cadar p1) (cadar p2))))
vert (vl-sort vert '(lambda (p1 p2) (< (caar p1) (caar p2))))
iv 65 ; index de départ des colonnes (ascii "A")
ih 1 ; index de départ des rangées
hy (cadaar horiz) ; Y maximum
vx (caaar vert) ; X minimum
;; ajout de l'index aux lignes horizontales
horiz (mapcar '(lambda (l)
(cons
(if (equal hy (setq hy (cadar l)) 1e-6)
(itoa ih)
(itoa (setq ih (1+ ih)))
)
l
)
)
horiz
)
;; ajout de l'index aux lignes verticales
vert (mapcar '(lambda (l)
(cons
(if (equal vx (setq vx (caar l)) 1e-6)
(chr iv)
(chr (setq iv (1+ iv)))
)
l
)
)
vert
)
)
(command-s "_.undo" "_begin")
;; affectation des variables système
(setvar 'cmdecho 0)
(setvar 'osmode 0)
(setvar 'attdia 0)
(setvar 'attreq 1)
;; pour chaque ligne verticale
(foreach v vert
;; pour chaque ligne horizontale
(foreach h horiz
;; insertion du bloc s'il y a intersection
;; affectation de la valeur de l'attribut avec les indices des lignes
(if (setq pt (inters (cadr h) (caddr h) (cadr v) (caddr v) T))
(command-s "_.insert" "inters" pt 1.0 1.0 0.0 (strcat (car v) (car h)))
)
)
)
)
)
(*error* nil)
)
Solution acceptée
Pas testé mais ça devrait marcher (j'ai ajouté quelques commentaires)
(defun c:BLKINTERS (/ *error* dia req echo os ss
n blk line vert horiz ih iv hy
vx pt num
)
;; substitution locale de la fonction *error*
(defun *error* (msg)
(and msg
(/= msg "Fonction annulée")
(princ (strcat "erreur: " msg))
)
(command-s "_.undo" "_end")
;; restauration des valeurs initiales
(setvar 'attdia dia)
(setvar 'attreq req)
(setvar 'osmode os)
(setvar 'cmdecho echo)
(princ)
)
;; valeurs initiales des variables système
(setq dia (getvar 'attdia)
req (getvar 'attreq)
echo (getvar 'cmdecho)
os (getvar 'osmode)
)
(setq num 1) ; nombre a incrémenter
;; sélection des blocs "bande_6inchs_centered" et des blocs anonymes
(if (setq ss (ssget "_X"
'((0 . "INSERT")
(2 . "`*U*,bande_6inchs_centered")
(410 . "Model")
)
)
)
(progn
;; traitement de la sélection
(repeat (setq n (sslength ss))
(setq blk (ssname ss (setq n (1- n))))
;; contrôle du nom du bloc (blocs anonymes)
(if (= (getpropertyvalue
(getpropertyvalue blk "BlockTableRecord")
"Name"
)
"bande_6inchs_centered"
)
(progn
;; constitution d'une liste avec les points de départ et de fin de la ligne
(setq line
(list
(getpropertyvalue blk "Position")
(polar
(getpropertyvalue blk "Position")
(- (getpropertyvalue blk "Rotation") (* pi 0.5))
(getpropertyvalue
blk
"AcDbDynBlockPropertyDistance1"
)
)
)
)
;; ajout de la sous-liste à la liste des lignes horizontales ou verticales
(if (equal (caar line) (caadr line) 1e-6)
(setq vert (cons line vert))
(setq horiz (cons line horiz))
)
)
)
)
;; tri de la liste des lignes horizontales par Y décroissant
;; et de la liste des lignes vetrticales par X croissant
(setq horiz (vl-sort horiz
'(lambda (p1 p2) (> (cadar p1) (cadar p2)))
)
vert (vl-sort vert '(lambda (p1 p2) (< (caar p1) (caar p2))))
iv 65 ; index de départ des colonnes (ascii "A")
ih 1 ; index de départ des rangées
hy (cadaar horiz) ; Y maximum
vx (caaar vert) ; X minimum
;; ajout de l'index aux lignes horizontales
horiz (mapcar '(lambda (l)
(cons
(if (equal hy (setq hy (cadar l)) 1e-6)
(itoa ih)
(itoa (setq ih (1+ ih)))
)
l
)
)
horiz
)
;; ajout de l'index aux lignes verticales
vert (mapcar '(lambda (l)
(cons
(if (equal vx (setq vx (caar l)) 1e-6)
(chr iv)
(chr (setq iv (1+ iv)))
)
l
)
)
vert
)
)
(command-s "_.undo" "_begin")
;; affectation des variables système
(setvar 'cmdecho 0)
(setvar 'osmode 0)
(setvar 'attdia 0)
(setvar 'attreq 1)
;; pour chaque ligne verticale
(foreach v vert
;; pour chaque ligne horizontale
(foreach h horiz
;; insertion du bloc s'il y a intersection
;; affectation de la valeur de l'attribut avec les indices des lignes
(if
(setq pt (inters (cadr h) (caddr h) (cadr v) (caddr v) T))
(progn
(command-s "_.insert"
"inters" ; nom du bloc
pt ; point d'insertion
1.0 ; échelle X
1.0 ; échelle Y
0.0 ; rotation
(strcat (car v) (car h)) ; premier attribut
(itoa num) ; second attribut
)
(setq num (1+ num)) ; incrémentation de l'attribut
)
)
)
)
)
)
(*error* nil)
)
Bonjour,
Si une des réponses à votre question résout votre problème, ou contribue significativement à sa résolution, voulez vous avoir l'amabilité de cliquer sur le bouton "Accepter comme solution" en bas de la réponse? Merci.
Patrick Emin animateur de la communauté francophone
Vous avez trouvé un message utile? Alors donnez un "J'aime" à ce message!
Votre question a eu une réponse satisfaisante? Voulez vous avoir l'amabilité de cliquer sur le bouton APPROUVER LA SOLUTION en bas de la réponse qui apporte une solution?
Signez notre Livre d'Or
Solution acceptée
zminWZ7PT a écrit :
Bonjour Patrick,
Je n'ai pas encore de solution à proprement parler, d'où mon non clic. Mais c'est en effet la dernière étape à mon sens pour une solution bien adaptée. Dès lors que ce sera résolu, je cliquerais bien entendu sur le lien approprié.
Exigeant avec ça...
Ils me semblent que les solutions que je t'ai gracieusement fournies répondaient à chaque fois à ce que tu avais demandé mais tu as, à chaque fois, ajouté une nouvelle requête.
Je te réponds une dernière fois et tant pis si tu ne trouve pas cette solution suffisamment adaptée...
(defun c:BLKINTERS (/ *error* dia req echo os ss n blk line vert horiz ih iv hy vx pt num pts)
;; substitution locale de la fonction *error*
(defun *error* (msg)
(and msg
(/= msg "Fonction annulée")
(princ (strcat "erreur: " msg))
)
(command-s "_.undo" "_end")
;; restauration des valeurs initiales
(setvar 'attdia dia)
(setvar 'attreq req)
(setvar 'osmode os)
(setvar 'cmdecho echo)
(princ)
)
;; valeurs initiales des variables système
(setq dia (getvar 'attdia)
req (getvar 'attreq)
echo (getvar 'cmdecho)
os (getvar 'osmode)
)
(setq num 1) ; nombre a incrémenter
;; sélection des blocs "bande_6inchs_centered" et des blocs anonymes
(if (setq ss (ssget "_X"
'((0 . "INSERT")
(2 . "`*U*,bande_6inchs_centered")
(410 . "Model")
)
)
)
(progn
;; traitement de la sélection
(repeat (setq n (sslength ss))
(setq blk (ssname ss (setq n (1- n))))
;; contrôle du nom du bloc (blocs anonymes)
(if (= (getpropertyvalue
(getpropertyvalue blk "BlockTableRecord")
"Name"
)
"bande_6inchs_centered"
)
(progn
;; constitution d'une liste avec les points de départ et de fin de la ligne
(setq line
(list
(getpropertyvalue blk "Position")
(polar
(getpropertyvalue blk "Position")
(- (getpropertyvalue blk "Rotation") (* pi 0.5))
(getpropertyvalue
blk
"AcDbDynBlockPropertyDistance1"
)
)
)
)
;; ajout de la sous-liste à la liste des lignes horizontales ou verticales
(if (equal (caar line) (caadr line) 1e-6)
(setq vert (cons line vert))
(setq horiz (cons line horiz))
)
)
)
)
;; tri de la liste des lignes horizontales par Y décroissant
;; et de la liste des lignes verticales par X croissant
(setq horiz (vl-sort horiz
'(lambda (p1 p2) (> (cadar p1) (cadar p2)))
)
vert (vl-sort vert '(lambda (p1 p2) (< (caar p1) (caar p2))))
iv 65 ; index de départ des colonnes (ascii "A")
ih 1 ; index de départ des rangées
hy (cadaar horiz) ; Y maximum
vx (caaar vert) ; X minimum
;; ajout de l'index aux lignes horizontales
horiz (mapcar '(lambda (l)
(cons
(if (equal hy (setq hy (cadar l)) 1e-6)
(itoa ih)
(itoa (setq ih (1+ ih)))
)
l
)
)
horiz
)
;; ajout de l'index aux lignes verticales
vert (mapcar '(lambda (l)
(cons
(if (equal vx (setq vx (caar l)) 1e-6)
(chr iv)
(chr (setq iv (1+ iv)))
)
l
)
)
vert
)
)
(command-s "_.undo" "_begin")
;; affectation des variables système
(setvar 'cmdecho 0)
(setvar 'osmode 0)
(setvar 'attdia 0)
(setvar 'attreq 1)
;; pour chaque ligne verticale
(foreach v vert
;; pour chaque ligne horizontale
(foreach h horiz
;; insertion du bloc s'il y a intersection
;; affectation de la valeur de l'attribut avec les indices des lignes
(if
(and
(setq pt (inters (cadr h) (caddr h) (cadr v) (caddr v) T))
(not (vl-member-if '(lambda (p) (equal pt p 1e-8)) pts))
)
(progn
(command-s "_.insert"
"inters" ; nom du bloc
pt ; point d'insertion
1.0 ; échelle X
1.0 ; échelle Y
0.0 ; rotation
(strcat (car v) (car h)) ; premier attribut
(itoa num) ; second attribut
)
(setq num (1+ num) ; incrémentation de l'attribut
pts (cons pt pts) ; ajout du point à la liste
)
)
)
)
)
)
)
(*error* nil)
)
Bonjour, non, marquer une réponse comme solution acceptée n'entraine pas le blocage des réponses, comme c'est le cas, vous avez raison, sur d'autres forums. La clôture d'un sujet et donc le blocage des réponses résulte d'une action manuelle d'un administrateur.
Patrick Emin animateur de la communauté francophone
Vous avez trouvé un message utile? Alors donnez un "J'aime" à ce message!
Votre question a eu une réponse satisfaisante? Voulez vous avoir l'amabilité de cliquer sur le bouton APPROUVER LA SOLUTION en bas de la réponse qui apporte une solution?
Signez notre Livre d'Or