SURF x coeff
Bonjour,
si tu disposes de MAP3D ou Civil3D (et pas un simple AutoCAD) on est typiquement dans une problématique SIG (ou cartographique).
On associe la densité (et éventuellement de type de plantes) sous forme de données d'objet sur chaque polyligne.
A partir de là on peut coloriser et/ou choisir son type de hachure selon la densité ou le type de plante
Et une étiquette à partir d'un gabarit d'annotation qui calcule la surface*coef permettrait d'afficher la valeur souhaitée en un seul clic et ce de manière "dynamique" si une donnée change.
Olivier
Olivier Eckmann
Dessines-tu en cm ? Cela n'est pas clair.
Tu peux utiliser ce petit lisp à lancer avec POSEU
(defun c:poseU( / ent aire pins rep)
(or *densite*(setq *densite* 1))
(setq ent(car(entsel"\nSelectionner l'objet")))
(cond((=(cdr(assoc 0(entget ent)))"LWPOLYLINE")
(setq aire(/(vla-get-area (vlax-ename->vla-object ent))10000.0))
(setq pins(getpoint"\nPoint d'insertion :"))
(setq rep(getreal (strcat"\nCoefficient <"(rtos *densite* 2 2)"> :")))
(setq *densite*(cond(rep)(*densite*)))
(command "_TEXT" pins 5 0 (strcat (rtos(* aire *densite*)2 2)" & "(rtos aire 2 2)" m²"))
)
)
)
Désolé pour les possesseurs de LT. Il faudrait alors des manipulations d'échelles avant de récupérer une aire.
Bonjour,
voilà un bout de code qui devrait faire l'affaire :
(defun C:ETIQU ( / dEchelle dHauteur oPoly oPolyLst PT dAire iNombre)
(setq dEchelle (getreal "\nFacteur d'échelle des surfaces : "))
(setq dHauteur (getdist "\nHauteur des textes : "))
(while (and (setq oPoly (car (entsel "\nSélectionner le contour : ")))
(setq oPolyLst (entget oPoly))
(= "LWPOLYLINE" (cdr (assoc 0 oPolyLst)))
(setq dDens (cdr (assoc 39 oPolyLst)))
(> dDens 0)
(setq PT (getpoint "\nPosition de l'étiquette : "))
(setq PT (trans PT 1 0))
)
(setq dAire (* dEchelle (vla-get-area (vlax-ename->vla-object oPoly))))
(setq iNombre (fix (* dAire dDens)))
(entmakex (list (cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 8 (getvar "CLAYER"))
(cons 100 "AcDbText")
(cons 10 PT)
(cons 40 dHauteur)
(cons 1 (itoa iNombre))
(cons 7 (getvar "TEXTSTYLE"))
(cons 50 0.0)
(cons 100 "AcDbText")
)
)
)
)
Ce lisp lit la densité dans la propriété Epaisseur de la polyligne (section générale depuis l'OPM)
La formule utilise "facteur d'échelle des surfaces" * "Aire de la polyligne" * "Densité"
Olivier
Olivier Eckmann
GENIALLLLLL Tramber 
!!!! Ca marche, vous êtes mon sauveur !!!!
Seulement éventuellement un tout petit détail à perfectionner, serait-il possible de faire afficher seulement
- Soit La densité avec l’unité - toujours « u » (ex : 25 u) sans la surface en m2
- ou encore mieux la densité + unité (u) + indice du nom de la plante (ex : 25 u de Q . pub) - indice qui pourrait être entré comme le coeff. dans votre lisp
je ne me rends pas du tout compte mais cela vous semble-t-il possible de le rendre également lié et adaptatif à la surface, c'est à dire que si je modifie ma surface que mon étiquette se mette à jour ?
Mais d’ores et déjà un GRAND merci et un grand bravo pour votre maîtrise.
Chaleureusement,
Joan
(defun c:poseU( / ent aire pins rep)
(or *densite*(setq *densite* 1))
(or *nomcourant*(setq *nomcourant* "Q .pub"))
(setq ent(car(entsel"\nSelectionner l'objet")))
(cond((=(cdr(assoc 0(entget ent)))"LWPOLYLINE")
(setq aire(/(vla-get-area (vlax-ename->vla-object ent))10000.0))
(setq pins(getpoint"\nPoint d'insertion :"))
(setq rep(getreal (strcat"\nCoefficient <"(rtos *densite* 2 2)"> :")))
(setq *densite*(cond(rep)(*densite*)))
(setq rep(getstring (strcat"\nNom <" *nomcourant* "> :")))
(setq *nomcourant*(cond((and rep(not(= rep "")))rep)(*nomcourant*)))
(command "_TEXT" pins 5 0 (strcat (rtos(* aire *densite*)2 2)" u de "*nomcourant*))
)
)
)
De rien, c'est facile et pas très long. Si ca plait vraiment, marquer mon message comme solution n’arrêtera pas la conversation.
Ici un code avec deux variables.
Si les noms et la densité sont associés, on peut faire mieux avec une liste facile à mettre à jour pour vous. Je le ferai.
Oui, on peut faire adaptatif mais cela coûte plus cher : il faut utiliser les réacteurs et c'est compliqué ou encore les champs personnalisés je suppose car on peut les programmer, malheureusement je ne sais plus très bien ni n'ai le temps (mais libre à chacun de modifier mon code) de fouiller le net aujourd'hui.
Dans mon programme rapide, le texte ne se souvient pas de la polyligne. Tu comprends ?
Toujours sans gestion des erreurs, une version qui utilise une liste à tenir à jour toi-même.
Avec le code, la densité (tu peux mettre un chiffre réel) et le nom entre guillemets
Il suffit de spécifier le code, cette fois-ci.
(defun c:poseU( / ent aire pins rep listop *densite* *nomcourant*)
(or *num*(setq *num* 0))
(setq ent(car(entsel"\nSelectionner l'objet")))
(setq listop '((0 1 "Truc")
(1 2 "Truc2")
(2 3 "Truc3")
(3 4 "Truc4")
(4 5 "Q .pub")))
(cond((=(cdr(assoc 0(entget ent)))"LWPOLYLINE")
(setq aire(/(vla-get-area (vlax-ename->vla-object ent))10000.0))
(setq pins(getpoint"\nPoint d'insertion :"))
(princ)
(princ(apply 'strcat (mapcar (function(lambda(x)(strcat (itoa(car x))"="(rtos(cadr x)2 2)" "(caddr x)"\t"))) listop)))
(setq rep(getint (strcat"\nNuméro <"(itoa *num*)"> :")))
(setq *num*(cond(rep)(*num*)))
(setq *densite*(cadr(nth *num* listop)))
(setq *nomcourant*(caddr(nth *num* listop)))
(command "_TEXT" pins 5 0 (strcat (rtos(* aire *densite*)2 2)" u de "*nomcourant*))
)
)
)
Tu peux charger cette routine écrite à la suite (ou mieux avant) la routine livrée :
(defun gc:round (num prec)
(if (zerop (setq prec (abs prec)))
num
(* prec
(fix ((if (minusp num)
-
+
)
(/ num prec)
0.5
)
)
)
)
)
Cette routine de @_gile va traiter l'arrondi.
Pour se faire, tu remplaces :
(rtos(* aire *densite*)2 2)
par :
(rtos(gc:round(* aire *densite*)1)2 0)
Attention aux parenthèses !
gc:round est chargé de faire ton arrondi et non pas de tronquer, ce qui est bien pour avoir un peu plus de plantes vertes et sauver l'humanité.
rtos, lui, convertit le nombre obtenu en chaine de caractères. Le 0 permet de ne plus mettre de chiffres derrière la virgule.
