XDATA to OBJECTDATA OR Shape File

[shil143]

Please Help me to convert attached file to Obectdata or shape

[parkr4st]

I tried.  Your file crashed AD Map3d 2018 latest update for some reason.  AEC objects maybe?

Opened in Vanilla CAD and copy and pasted in to Map3D and saved XDATA_2.dwg

There is no data on the objects that showed up so not sure of what you are looking for.

I sent all the data to a sdf file and selected properties that are in the data table.

Send more detail of what program and version you are using, and what data you expect to attach.

dave

[CADaSchtroumpf · Accepted solution]

Your file crash also my autocadmap 2014.

I have insert the file in explode mode in new drawing for can openned it.

Then i can apply this (copy-paste in command line) for transfert xdata to Object Data.

NB: Can be long, Autocad seem no respond but it make the job: Don't killing it

((lambda ( / js count n target_obj elist xd_list tbl fldnamelist fldtypelist e_data lst_tbl pos)
  (setq js (ssget '((-3 ("*")))) count 0 lst_tbl nil)
  (cond
    (js
      (repeat (setq n (sslength js))
        (setq
          target_obj (ssname js (setq n (1- n)))
          elist (entget target_obj (list "*"))
          xd_list (cdr (assoc -3 elist))
          tbl "XD_to_OD"
          fldnamelist (mapcar 'car xd_list)
          fldtypelist (mapcar 'caadr xd_list)
          e_data (mapcar 'cdadr xd_list)
        )
        (if (null (ade_odtabledefn tbl))
          (progn
            (setq lst_tbl (cons (cons tbl (list fldnamelist)) lst_tbl))
            (ade_oddefinetab 
              (list
                (cons "Tablename" tbl)
                (cons "TableDesc" "")
                (append
                  '("Columns")
                  (mapcar
                    '(lambda (x y / )
                      (list
                        (cons "ColName" x)
                        (cons "ColDesc" "")
                        (cons "ColType"
                          (cond
                            ((eq y 1040) "Real")
                            ((eq y 1070) "Integer")
                            ((eq y 1010) "Point")
                            ((eq y 1000) "Character")
                          )
                        )
                        (cons "DefaultVal"
                          (cond
                            ((eq y 1040) 0.0)
                            ((eq y 1070) 0)
                            ((eq y 1010) '(0.0 0.0 0.0))
                            ((eq y 1000) "")
                          )
                        )
                      )
                    )
                    fldnamelist
                    fldtypelist
                  )
                )
              )
            )
          )
          (progn
            (if (not (equal fldnamelist (car (mapcar 'cadr lst_tbl))))
              (setq lst_tbl (cons (cons (strcat tbl (itoa (setq count (1+ count)))) (list fldnamelist)) lst_tbl))
            )
            (if
              (numberp (setq pos (vl-position T (mapcar '(lambda (x) (equal (mapcar 'cdar (cdaddr (ade_odtabledefn tbl))) x)) (mapcar 'cadr (reverse lst_tbl))))))
              (if (null (ade_odtabledefn (setq tbl (car (nth pos lst_tbl)))))
                (ade_oddefinetab 
                  (list
                    (cons "Tablename" tbl)
                    (cons "TableDesc" "")
                    (append
                      '("Columns")
                      (mapcar
                        '(lambda (x y / )
                          (list
                            (cons "ColName" x)
                            (cons "ColDesc" "")
                            (cons "ColType"
                              (cond
                                ((eq y 1040) "Real")
                                ((eq y 1070) "Integer")
                                ((eq y 1010) "Point")
                                ((eq y 1000) "Character")
                              )
                            )
                            (cons "DefaultVal"
                              (cond
                                ((eq y 1040) 0.0)
                                ((eq y 1070) 0)
                                ((eq y 1010) '(0.0 0.0 0.0))
                                ((eq y 1000) "")
                              )
                            )
                          )
                        )
                        fldnamelist
                        fldtypelist
                      )
                    )
                  )
                )
              )
            )
          )
        )
        (ade_odaddrecord target_obj tbl)
        (mapcar
          '(lambda (x y) (ade_odsetfield target_obj tbl x 0 y))
          fldnamelist
          e_data
        )
      )
    )
  )
  (prin1)
))

[shil143]

Thanks...........