Not sure if you can modify the deployment to include / modify acad.lsp. I create a deployment for AutoCAD using the Account-deployment tool with as little customisation as possible. Then download the image to a local share. We don't deploy customizations to clients but have them stored on a network share. For example, we use modified menu's and LISP applications stored on that share. There's also a default AutoCAD profile on the same share.
A command script (cmd) is used to install AutoCAD on the clients, and I have that script to copy a modified 'acad.lsp' to the clients Support folder. When a user runs AutoCAD for the first time, it uses the OOTB support paths and it will find that modified acad.lsp, load and execute it. This acad.lsp sets the support paths to point to the network share and restarts AutoCAD. Then AutoCAD will pick up the corporate acad.lsp on the network share, execute it and it will modify several settings.
This is the acad.lsp I copy to the client at install time (text is in Dutch):
;;******************************************************************************
;;******************************************************************************
;;** **
;;** De lokale versie van Acad.lsp wordt bij het starten van AutoCAD **
;;** geladen als de paden in het profiel niet goed zijn ingesteld. **
;;** Deze routine wijzigt de supportpaden en geeft een boodschap. **
;;** **
;;******************************************************************************
;;******************************************************************************
(setvar "cmdecho" 0)
(princ "Lokale versie ACAD.LSP verwerken...")
;;------------------------------------------------------------------------------
;;-- Visual LISP --
;;------------------------------------------------------------------------------
(vl-load-com)
;;------------------------------------------------------------------------------
;;-- Opties instellen onder tab 'Files' --
;;------------------------------------------------------------------------------
(setq acadsuppad "L:\\AutoCAD\\"
userprofilepad (getvar "RoamableRootPrefix")
paden (vla-get-files (vla-get-preferences (vlax-get-acad-object)))
oldsuppad (vla-get-supportpath paden)
)
(if (not (wcmatch (strcase oldsuppad) "*L:\\AutoCAD\\apps*"))
(progn
(vla-put-supportpath paden (strcat "L:\\AutoCAD\\apps;" oldsuppad ))
(setvar "TrustedPaths" (strcat acadsuppad "apps\\...;" acadsuppad "cot\\...;" acadsuppad "support\\...;" userprofilepad "support\\..."))
(alert "AutoCAD gebruikt niet de juiste configuratie.\n\nKlik op OK om AutoCAD af te sluiten en start het opnieuw.\nDe configuratie wordt dan aangepast.")
(command "quit")
)) ;_ end of if
;;------------------------------------------------------------------------------
;;-- Einde acad.lsp --
;;------------------------------------------------------------------------------
(princ "\nACAD.LSP lokaal is verwerkt.")
The network share holding the corporate acad.lsp is "L:\\AutoCAD\\".
In short what this routine does. It gets the current support path (vla-get-supportpath) and assign it to variable oldsuppad. Then it looks if this path contains the corporate path (wcmatch (strcase oldsuppad) "*L:\\AutoCAD\\apps*"). If true, the correct support path is already there and the routine exits. If false, change the support path to add the new location as first in the list (vla-put-supportpath paden (strcat "L:\\AutoCAD\\apps;" oldsuppad ) and display a message to restart AutoCAD.
You also have to change the TrustedPaths, if you happen to use them, otherwise AutoCAD won't load the corporate acad.lsp off of the network share.
In your case, the ACAD2024.lsp is the corporate acad.lsp and has to be stored on a network share - S:\Acad\Support I guess.
Any modifications needed after deploying AutoCAD that cannot be done from within AutoCAD, like copying the 'local' version of acad.lsp to the clients, can be done using a Windows Domain Startup script. That's a whole other can of worms 🙂
As always - there's more ways to skin a cat. If you happen to have SCCM, Intune and / or extensive knowledge about PowerShell, things can probably be done in a more streamlined fashion....
