Attribute Dialog Box

[Anonymous]

Is it possible to turn on/off the attribute dialog box by block?  In other words when I build the block can I set a variable that turns the pop window off for one block and on in another?  I want to be able to insert one block and have the dialog box pop up and insert another block that the box does not pop up.

[Anonymous]

Not that I know of....the dialog box appearing or not depends on the system variable ATTDIA.

Area Object Link | Attribute Modifier | Dwg Setup |Feet-Inch Calculator
Layer Apps | List on Steroids | VP Zoom Scales | Exchange App Store

[cadffm]

Learn more about attributdefinition/ATTDEF properties.

The property you are searching for is PRESET

[imadHabash]

Hi,

>> Is it possible to turn on/off the attribute dialog box by block?

NO you can not . 🙂

[cadffm]

Looks like a translation problem,

Acad can, Imad can't

😆

[Moshe-A]

@Anonymous  hi,

here is a lisp command (RNI) to do what you want. it's data list is built from the following dotted pair items:

the number in the dotted pair is the value of attdia to be before insert

(setq blockData^ '(("blk101" . 0) ("blk102" . 1) ("blk103" . 0) ("blk104" . 1))

replace each "blnnn" with your blocks

enjoy

moshe

; Robert Noha Insert

(defun c:RNI (/ insert_block ; local function
	        blockData^ blkName savAttdia)

 (defun insert_block ()
  (if (setq item (assoc blkName blockData^))
   (setvar "attdia" (cdr item))
  )
  (command-s "insert" blkName) 
 ); insert_block

  
 ; here start c:RNI
 (setq blockData^ '(("blk101" . 0) ("blk102" . 1) ("blk103" . 0) ("blk104" . 1)))

 (if (/= (setq blkName (getstring "\nEnter block name: ")) "")
  (progn
   (setq savAttdia (getvar "attdia"))
   
   (cond
    ((tblsearch "block" blkName)
     (insert_block)
    ); case 
    ((findfile (strcat blkName ".dwg"))
     (insert_block)
    ); case
    ( t
     (vlr-beep-reaction) 
     (prompt (strcat "\nblock " (strcase blkName) " is not found."))
    )
   ); cond

   (setvar "attdia" savAttdia) 
  ); progn
 ); if

 (princ)  
)