How to declare a function in MaxScript

[YASUSHI_EMOTO]

I have created the following simple code
When I run this, I get an error.

Since the testB function is defined before the testA function, the testA function cannot be called inside the testB function.　Is there a solution to these problems?

fn testB =
(
      testA()
)
fn testA =
(
      messagebox "test!" title:"OK"
)

testB()

The error message is as follows

-- Error occurred in anonymous codeblock; filename: ; position: 25; line: 3
-- Type error: Call needs function or class, got: undefined
-- MAXScript callstack:
--	thread data: threadID:35944
--	------------------------------------------------------
--	[stack level: 0]
--	In testB(); filename: ; position: 26; line: 3
--		Locals:
--			testA: undefined
--		Externals:
--			owner: undefined
--	------------------------------------------------------
--	[stack level: 1]
--	called from top-level

[denisT.MaxDoctor · Accepted solution]

there are several ways to do it in MXS...

the most used are:

--1:
(
	local functionB
	
	fn functionA = (functionB())
	fn functionB = (print #A)
	
	functionA()
)		

--2:
(
	struct structFN
	(
		fn functionA = (this.functionB()),
		fn functionB = (print #AA)	
	)

	str = structFN()
	str.functionA()
)

of course the same technique can be used in #global scope too:

global print_val

fn print_a = 
(
	print_val #a
)
fn print_val val = (print val)

print_a() ​

but you should be aware that defining custom functions or methods in the global scope is not good practice and should be avoided whenever possible.