How do i customize menue entries?

[K.W.J.P.]

Hi together,

I would like to change e.g. the degree amount in snap rotate from default "5" to "15" Degree.

How is that possible?

same to the Curve Editor, where under -> VIEW ->  INTERACTIVE UPDATE the setting is always off, which I find very annoying since that thing it totally outdated. in 99,99 % I switch it ON so that I do what I do... I like to change the default value from that.

thanks all and please Autodesk - from the bottom of your heart, pleeeease change this!

I really wish, that these settings - at least-  are taking place in the global preferences.

cheers!

[Serejah]

---

@K.W.J.P.  написал (-а):

Hi together,

I would like to change e.g. the degree amount in snap rotate from default "5" to "15" Degree.

How is that possible?

(dotNetClass "Autodesk.Max.GlobalInterface").Instance.CoreInterface14.SnapAngle_ = 15.0

same to the Curve Editor, where under -> VIEW ->  INTERACTIVE UPDATE the setting is always off, which I find very annoying since that thing it totally outdated. in 99,99 % I switch it ON so that I do what I do... I like to change the default value from that.

macroScript LaunchFCurveEditorInteractiveEnabled
category:"Track View"
tooltip:"Launch Curve Editor with Interactive Enabled"
(
	on execute do
	(
		macros.run "Track View" "LaunchFCurveEditor"
		trackviews.currenttrackview.interactiveupdate = true
		trackviews.currenttrackview.syncTime = false
	)	
)

---

with this you can make a startup script that would change angle snap to a preferred value

and also a new macro to open curve editor with interactive update enabled

[K.W.J.P.]

thank you Serejah for your Help! 

(it´s absolutely great on one hand, that here people are helping together.

On the other hand is this a kind of evidence, that Autodesk finds no need to make things better. )

I am going to try that. I really wish I could do that by my own...

+like!  😃

[denisT.MaxDoctor]

... or make a macrobutton in main toolbar:

macroScript TrackViewInteractiveUpdate
	category:"Track View"
	buttontext:"INTERACTIVE"
	tooltip:"Toggle Track View Interactive Update"
(
	local tv = tv
	fn enabled = ((tv = trackviews.currenttrackview) != undefined)
	on isenabled do enabled()
	on ischecked do (enabled() and tv.interactiveupdate)  
	on execute do if (enabled()) do
	(
		tv.interactiveupdate = not tv.interactiveupdate 
	)	
)